Evernight & Caelestia

components/Anim.qml

@@ -0,0 +1,8 @@
+import qs.config
+import QtQuick
+
+NumberAnimation {
+    duration: Appearance.anim.durations.normal
+    easing.type: Easing.BezierSpline
+    easing.bezierCurve: Appearance.anim.curves.standard
+}

components/CAnim.qml

@@ -0,0 +1,8 @@
+import qs.config
+import QtQuick
+
+ColorAnimation {
+    duration: Appearance.anim.durations.normal
+    easing.type: Easing.BezierSpline
+    easing.bezierCurve: Appearance.anim.curves.standard
+}

components/MaterialIcon.qml

@@ -0,0 +1,16 @@
+import qs.services
+import qs.config
+
+StyledText {
+    property real fill
+    property int grade: Colours.light ? 0 : -25
+
+    font.family: Appearance.font.family.material
+    font.pointSize: Appearance.font.size.larger
+    font.variableAxes: ({
+            FILL: fill.toFixed(1),
+            GRAD: grade,
+            opsz: fontInfo.pixelSize,
+            wght: fontInfo.weight
+        })
+}

components/StateLayer.qml

@@ -0,0 +1,94 @@
+import qs.services
+import qs.config
+import QtQuick
+
+MouseArea {
+    id: root
+
+    property bool disabled
+    property color color: Colours.palette.m3onSurface
+    property real radius: parent?.radius ?? 0
+    property alias rect: hoverLayer
+
+    function onClicked(): void {
+    }
+
+    anchors.fill: parent
+
+    enabled: !disabled
+    cursorShape: disabled ? undefined : Qt.PointingHandCursor
+    hoverEnabled: true
+
+    onPressed: event => {
+        if (disabled)
+            return;
+
+        rippleAnim.x = event.x;
+        rippleAnim.y = event.y;
+
+        const dist = (ox, oy) => ox * ox + oy * oy;
+        rippleAnim.radius = Math.sqrt(Math.max(dist(event.x, event.y), dist(event.x, height - event.y), dist(width - event.x, event.y), dist(width - event.x, height - event.y)));
+
+        rippleAnim.restart();
+    }
+
+    onClicked: event => !disabled && onClicked(event)
+
+    SequentialAnimation {
+        id: rippleAnim
+
+        property real x
+        property real y
+        property real radius
+
+        PropertyAction {
+            target: ripple
+            property: "x"
+            value: rippleAnim.x
+        }
+        PropertyAction {
+            target: ripple
+            property: "y"
+            value: rippleAnim.y
+        }
+        PropertyAction {
+            target: ripple
+            property: "opacity"
+            value: 0.08
+        }
+        Anim {
+            target: ripple
+            properties: "implicitWidth,implicitHeight"
+            from: 0
+            to: rippleAnim.radius * 2
+            easing.bezierCurve: Appearance.anim.curves.standardDecel
+        }
+        Anim {
+            target: ripple
+            property: "opacity"
+            to: 0
+        }
+    }
+
+    StyledClippingRect {
+        id: hoverLayer
+
+        anchors.fill: parent
+
+        color: Qt.alpha(root.color, root.disabled ? 0 : root.pressed ? 0.1 : root.containsMouse ? 0.08 : 0)
+        radius: root.radius
+
+        StyledRect {
+            id: ripple
+
+            radius: Appearance.rounding.full
+            color: root.color
+            opacity: 0
+
+            transform: Translate {
+                x: -ripple.width / 2
+                y: -ripple.height / 2
+            }
+        }
+    }
+}

components/StyledClippingRect.qml

@@ -0,0 +1,12 @@
+import Quickshell.Widgets
+import QtQuick
+
+ClippingRectangle {
+    id: root
+
+    color: "transparent"
+
+    Behavior on color {
+        CAnim {}
+    }
+}

components/StyledRect.qml

@@ -0,0 +1,11 @@
+import QtQuick
+
+Rectangle {
+    id: root
+
+    color: "transparent"
+
+    Behavior on color {
+        CAnim {}
+    }
+}

components/StyledText.qml

@@ -0,0 +1,48 @@
+pragma ComponentBehavior: Bound
+
+import qs.services
+import qs.config
+import QtQuick
+
+Text {
+    id: root
+
+    property bool animate: false
+    property string animateProp: "scale"
+    property real animateFrom: 0
+    property real animateTo: 1
+    property int animateDuration: Appearance.anim.durations.normal
+
+    renderType: Text.NativeRendering
+    textFormat: Text.PlainText
+    color: Colours.palette.m3onSurface
+    font.family: Appearance.font.family.sans
+    font.pointSize: Appearance.font.size.smaller
+
+    Behavior on color {
+        CAnim {}
+    }
+
+    Behavior on text {
+        enabled: root.animate
+
+        SequentialAnimation {
+            Anim {
+                to: root.animateFrom
+                easing.bezierCurve: Appearance.anim.curves.standardAccel
+            }
+            PropertyAction {}
+            Anim {
+                to: root.animateTo
+                easing.bezierCurve: Appearance.anim.curves.standardDecel
+            }
+        }
+    }
+
+    component Anim: NumberAnimation {
+        target: root
+        property: root.animateProp
+        duration: root.animateDuration / 2
+        easing.type: Easing.BezierSpline
+    }
+}

components/containers/StyledFlickable.qml

@@ -0,0 +1,14 @@
+import ".."
+import QtQuick
+
+Flickable {
+    id: root
+
+    maximumFlickVelocity: 3000
+
+    rebound: Transition {
+        Anim {
+            properties: "x,y"
+        }
+    }
+}

components/containers/StyledListView.qml

@@ -0,0 +1,14 @@
+import ".."
+import QtQuick
+
+ListView {
+    id: root
+
+    maximumFlickVelocity: 3000
+
+    rebound: Transition {
+        Anim {
+            properties: "x,y"
+        }
+    }
+}

components/containers/StyledWindow.qml

@@ -0,0 +1,9 @@
+import Quickshell
+import Quickshell.Wayland
+
+PanelWindow {
+    required property string name
+
+    WlrLayershell.namespace: `caelestia-${name}`
+    color: "transparent"
+}

components/controls/CircularIndicator.qml

@@ -0,0 +1,108 @@
+import ".."
+import qs.services
+import qs.config
+import Caelestia.Internal
+import QtQuick
+import QtQuick.Templates
+
+BusyIndicator {
+    id: root
+
+    enum AnimType {
+        Advance = 0,
+        Retreat
+    }
+
+    enum AnimState {
+        Stopped,
+        Running,
+        Completing
+    }
+
+    property real implicitSize: Appearance.font.size.normal * 3
+    property real strokeWidth: Appearance.padding.small * 0.8
+    property color fgColour: Colours.palette.m3primary
+    property color bgColour: Colours.palette.m3secondaryContainer
+
+    property alias type: manager.indeterminateAnimationType
+    readonly property alias progress: manager.progress
+
+    property real internalStrokeWidth: strokeWidth
+    property int animState
+
+    padding: 0
+    implicitWidth: implicitSize
+    implicitHeight: implicitSize
+
+    Component.onCompleted: {
+        if (running) {
+            running = false;
+            running = true;
+        }
+    }
+
+    onRunningChanged: {
+        if (running) {
+            manager.completeEndProgress = 0;
+            animState = CircularIndicator.Running;
+        } else {
+            if (animState == CircularIndicator.Running)
+                animState = CircularIndicator.Completing;
+        }
+    }
+
+    states: State {
+        name: "stopped"
+        when: !root.running
+
+        PropertyChanges {
+            root.opacity: 0
+            root.internalStrokeWidth: root.strokeWidth / 3
+        }
+    }
+
+    transitions: Transition {
+        Anim {
+            properties: "opacity,internalStrokeWidth"
+            duration: manager.completeEndDuration * Appearance.anim.durations.scale
+        }
+    }
+
+    contentItem: CircularProgress {
+        anchors.fill: parent
+        strokeWidth: root.internalStrokeWidth
+        fgColour: root.fgColour
+        bgColour: root.bgColour
+        padding: root.padding
+        rotation: manager.rotation
+        startAngle: manager.startFraction * 360
+        value: manager.endFraction - manager.startFraction
+    }
+
+    CircularIndicatorManager {
+        id: manager
+    }
+
+    NumberAnimation {
+        running: root.animState !== CircularIndicator.Stopped
+        loops: Animation.Infinite
+        target: manager
+        property: "progress"
+        from: 0
+        to: 1
+        duration: manager.duration * Appearance.anim.durations.scale
+    }
+
+    NumberAnimation {
+        running: root.animState === CircularIndicator.Completing
+        target: manager
+        property: "completeEndProgress"
+        from: 0
+        to: 1
+        duration: manager.completeEndDuration * Appearance.anim.durations.scale
+        onFinished: {
+            if (root.animState === CircularIndicator.Completing)
+                root.animState = CircularIndicator.Stopped;
+        }
+    }
+}

components/controls/CircularProgress.qml

@@ -0,0 +1,69 @@
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Shapes
+
+Shape {
+    id: root
+
+    property real value
+    property int startAngle: -90
+    property int strokeWidth: Appearance.padding.smaller
+    property int padding: 0
+    property int spacing: Appearance.spacing.small
+    property color fgColour: Colours.palette.m3primary
+    property color bgColour: Colours.palette.m3secondaryContainer
+
+    readonly property real size: Math.min(width, height)
+    readonly property real arcRadius: (size - padding - strokeWidth) / 2
+    readonly property real vValue: value || 1 / 360
+    readonly property real gapAngle: ((spacing + strokeWidth) / (arcRadius || 1)) * (180 / Math.PI)
+
+    preferredRendererType: Shape.CurveRenderer
+    asynchronous: true
+
+    ShapePath {
+        fillColor: "transparent"
+        strokeColor: root.bgColour
+        strokeWidth: root.strokeWidth
+        capStyle: Appearance.rounding.scale === 0 ? ShapePath.SquareCap : ShapePath.RoundCap
+
+        PathAngleArc {
+            startAngle: root.startAngle + 360 * root.vValue + root.gapAngle
+            sweepAngle: Math.max(-root.gapAngle, 360 * (1 - root.vValue) - root.gapAngle * 2)
+            radiusX: root.arcRadius
+            radiusY: root.arcRadius
+            centerX: root.size / 2
+            centerY: root.size / 2
+        }
+
+        Behavior on strokeColor {
+            CAnim {
+                duration: Appearance.anim.durations.large
+            }
+        }
+    }
+
+    ShapePath {
+        fillColor: "transparent"
+        strokeColor: root.fgColour
+        strokeWidth: root.strokeWidth
+        capStyle: Appearance.rounding.scale === 0 ? ShapePath.SquareCap : ShapePath.RoundCap
+
+        PathAngleArc {
+            startAngle: root.startAngle
+            sweepAngle: 360 * root.vValue
+            radiusX: root.arcRadius
+            radiusY: root.arcRadius
+            centerX: root.size / 2
+            centerY: root.size / 2
+        }
+
+        Behavior on strokeColor {
+            CAnim {
+                duration: Appearance.anim.durations.large
+            }
+        }
+    }
+}

components/controls/CustomMouseArea.qml

@@ -0,0 +1,21 @@
+import QtQuick
+
+MouseArea {
+    property int scrollAccumulatedY: 0
+
+    function onWheel(event: WheelEvent): void {
+    }
+
+    onWheel: event => {
+        // Update accumulated scroll
+        if (Math.sign(event.angleDelta.y) !== Math.sign(scrollAccumulatedY))
+            scrollAccumulatedY = 0;
+        scrollAccumulatedY += event.angleDelta.y;
+
+        // Trigger handler and reset if above threshold
+        if (Math.abs(scrollAccumulatedY) >= 120) {
+            onWheel(event);
+            scrollAccumulatedY = 0;
+        }
+    }
+}

components/controls/CustomSpinBox.qml

@@ -0,0 +1,108 @@
+pragma ComponentBehavior: Bound
+
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Layouts
+
+RowLayout {
+    id: root
+
+    property int value
+    property real max: Infinity
+    property real min: -Infinity
+    property alias repeatRate: timer.interval
+
+    signal valueModified(value: int)
+
+    spacing: Appearance.spacing.small
+
+    StyledTextField {
+        inputMethodHints: Qt.ImhFormattedNumbersOnly
+        text: root.value
+        onAccepted: root.valueModified(text)
+
+        padding: Appearance.padding.small
+        leftPadding: Appearance.padding.normal
+        rightPadding: Appearance.padding.normal
+
+        background: StyledRect {
+            implicitWidth: 100
+            radius: Appearance.rounding.small
+            color: Colours.tPalette.m3surfaceContainerHigh
+        }
+    }
+
+    StyledRect {
+        radius: Appearance.rounding.small
+        color: Colours.palette.m3primary
+
+        implicitWidth: implicitHeight
+        implicitHeight: upIcon.implicitHeight + Appearance.padding.small * 2
+
+        StateLayer {
+            id: upState
+
+            color: Colours.palette.m3onPrimary
+
+            onPressAndHold: timer.start()
+            onReleased: timer.stop()
+
+            function onClicked(): void {
+                root.valueModified(Math.min(root.max, root.value + 1));
+            }
+        }
+
+        MaterialIcon {
+            id: upIcon
+
+            anchors.centerIn: parent
+            text: "keyboard_arrow_up"
+            color: Colours.palette.m3onPrimary
+        }
+    }
+
+    StyledRect {
+        radius: Appearance.rounding.small
+        color: Colours.palette.m3primary
+
+        implicitWidth: implicitHeight
+        implicitHeight: downIcon.implicitHeight + Appearance.padding.small * 2
+
+        StateLayer {
+            id: downState
+
+            color: Colours.palette.m3onPrimary
+
+            onPressAndHold: timer.start()
+            onReleased: timer.stop()
+
+            function onClicked(): void {
+                root.valueModified(Math.max(root.min, root.value - 1));
+            }
+        }
+
+        MaterialIcon {
+            id: downIcon
+
+            anchors.centerIn: parent
+            text: "keyboard_arrow_down"
+            color: Colours.palette.m3onPrimary
+        }
+    }
+
+    Timer {
+        id: timer
+
+        interval: 100
+        repeat: true
+        triggeredOnStart: true
+        onTriggered: {
+            if (upState.pressed)
+                upState.onClicked();
+            else if (downState.pressed)
+                downState.onClicked();
+        }
+    }
+}

components/controls/FilledSlider.qml

@@ -0,0 +1,146 @@
+import ".."
+import "../effects"
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Templates
+
+Slider {
+    id: root
+
+    required property string icon
+    property real oldValue
+    property bool initialized
+
+    orientation: Qt.Vertical
+
+    background: StyledRect {
+        color: Colours.tPalette.m3surfaceContainer
+        radius: Appearance.rounding.full
+
+        StyledRect {
+            anchors.left: parent.left
+            anchors.right: parent.right
+
+            y: root.handle.y
+            implicitHeight: parent.height - y
+
+            color: Colours.palette.m3secondary
+            radius: parent.radius
+        }
+    }
+
+    handle: Item {
+        id: handle
+
+        property alias moving: icon.moving
+
+        y: root.visualPosition * (root.availableHeight - height)
+        implicitWidth: root.width
+        implicitHeight: root.width
+
+        Elevation {
+            anchors.fill: parent
+            radius: rect.radius
+            level: handleInteraction.containsMouse ? 2 : 1
+        }
+
+        StyledRect {
+            id: rect
+
+            anchors.fill: parent
+
+            color: Colours.palette.m3inverseSurface
+            radius: Appearance.rounding.full
+
+            MouseArea {
+                id: handleInteraction
+
+                anchors.fill: parent
+                hoverEnabled: true
+                cursorShape: Qt.PointingHandCursor
+                acceptedButtons: Qt.NoButton
+            }
+
+            MaterialIcon {
+                id: icon
+
+                property bool moving
+
+                function update(): void {
+                    animate = !moving;
+                    binding.when = moving;
+                    font.pointSize = moving ? Appearance.font.size.small : Appearance.font.size.larger;
+                    font.family = moving ? Appearance.font.family.sans : Appearance.font.family.material;
+                }
+
+                text: root.icon
+                color: Colours.palette.m3inverseOnSurface
+                anchors.centerIn: parent
+
+                onMovingChanged: anim.restart()
+
+                Binding {
+                    id: binding
+
+                    target: icon
+                    property: "text"
+                    value: Math.round(root.value * 100)
+                    when: false
+                }
+
+                SequentialAnimation {
+                    id: anim
+
+                    Anim {
+                        target: icon
+                        property: "scale"
+                        to: 0
+                        duration: Appearance.anim.durations.normal / 2
+                        easing.bezierCurve: Appearance.anim.curves.standardAccel
+                    }
+                    ScriptAction {
+                        script: icon.update()
+                    }
+                    Anim {
+                        target: icon
+                        property: "scale"
+                        to: 1
+                        duration: Appearance.anim.durations.normal / 2
+                        easing.bezierCurve: Appearance.anim.curves.standardDecel
+                    }
+                }
+            }
+        }
+    }
+
+    onPressedChanged: handle.moving = pressed
+
+    onValueChanged: {
+        if (!initialized) {
+            initialized = true;
+            return;
+        }
+        if (Math.abs(value - oldValue) < 0.01)
+            return;
+        oldValue = value;
+        handle.moving = true;
+        stateChangeDelay.restart();
+    }
+
+    Timer {
+        id: stateChangeDelay
+
+        interval: 500
+        onTriggered: {
+            if (!root.pressed)
+                handle.moving = false;
+        }
+    }
+
+    Behavior on value {
+        Anim {
+            duration: Appearance.anim.durations.large
+        }
+    }
+}

components/controls/IconButton.qml

@@ -0,0 +1,83 @@
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+
+StyledRect {
+    id: root
+
+    enum Type {
+        Filled,
+        Tonal,
+        Text
+    }
+
+    property alias icon: label.text
+    property bool checked
+    property bool toggle
+    property real padding: type === IconButton.Text ? Appearance.padding.small / 2 : Appearance.padding.smaller
+    property alias font: label.font
+    property int type: IconButton.Filled
+    property bool disabled
+
+    property alias stateLayer: stateLayer
+    property alias label: label
+    property alias radiusAnim: radiusAnim
+
+    property bool internalChecked
+    property color activeColour: type === IconButton.Filled ? Colours.palette.m3primary : Colours.palette.m3secondary
+    property color inactiveColour: {
+        if (!toggle && type === IconButton.Filled)
+            return Colours.palette.m3primary;
+        return type === IconButton.Filled ? Colours.tPalette.m3surfaceContainer : Colours.palette.m3secondaryContainer;
+    }
+    property color activeOnColour: type === IconButton.Filled ? Colours.palette.m3onPrimary : type === IconButton.Tonal ? Colours.palette.m3onSecondary : Colours.palette.m3primary
+    property color inactiveOnColour: {
+        if (!toggle && type === IconButton.Filled)
+            return Colours.palette.m3onPrimary;
+        return type === IconButton.Tonal ? Colours.palette.m3onSecondaryContainer : Colours.palette.m3onSurfaceVariant;
+    }
+    property color disabledColour: Qt.alpha(Colours.palette.m3onSurface, 0.1)
+    property color disabledOnColour: Qt.alpha(Colours.palette.m3onSurface, 0.38)
+
+    signal clicked
+
+    onCheckedChanged: internalChecked = checked
+
+    radius: internalChecked ? Appearance.rounding.small : implicitHeight / 2
+    color: type === IconButton.Text ? "transparent" : disabled ? disabledColour : internalChecked ? activeColour : inactiveColour
+
+    implicitWidth: implicitHeight
+    implicitHeight: label.implicitHeight + padding * 2
+
+    StateLayer {
+        id: stateLayer
+
+        color: root.internalChecked ? root.activeOnColour : root.inactiveOnColour
+        disabled: root.disabled
+
+        function onClicked(): void {
+            if (root.toggle)
+                root.internalChecked = !root.internalChecked;
+            root.clicked();
+        }
+    }
+
+    MaterialIcon {
+        id: label
+
+        anchors.centerIn: parent
+        color: root.disabled ? root.disabledOnColour : root.internalChecked ? root.activeOnColour : root.inactiveOnColour
+        fill: !root.toggle || root.internalChecked ? 1 : 0
+
+        Behavior on fill {
+            Anim {}
+        }
+    }
+
+    Behavior on radius {
+        Anim {
+            id: radiusAnim
+        }
+    }
+}

components/controls/IconTextButton.qml

@@ -0,0 +1,85 @@
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+
+StyledRect {
+    id: root
+
+    enum Type {
+        Filled,
+        Tonal,
+        Text
+    }
+
+    property alias icon: iconLabel.text
+    property alias text: label.text
+    property bool checked
+    property bool toggle
+    property real horizontalPadding: Appearance.padding.normal
+    property real verticalPadding: Appearance.padding.smaller
+    property alias font: label.font
+    property int type: IconTextButton.Filled
+
+    property alias stateLayer: stateLayer
+    property alias iconLabel: iconLabel
+    property alias label: label
+
+    property bool internalChecked
+    property color activeColour: type === IconTextButton.Filled ? Colours.palette.m3primary : Colours.palette.m3secondary
+    property color inactiveColour: type === IconTextButton.Filled ? Colours.tPalette.m3surfaceContainer : Colours.palette.m3secondaryContainer
+    property color activeOnColour: type === IconTextButton.Filled ? Colours.palette.m3onPrimary : Colours.palette.m3onSecondary
+    property color inactiveOnColour: type === IconTextButton.Filled ? Colours.palette.m3onSurface : Colours.palette.m3onSecondaryContainer
+
+    signal clicked
+
+    onCheckedChanged: internalChecked = checked
+
+    radius: internalChecked ? Appearance.rounding.small : implicitHeight / 2
+    color: type === IconTextButton.Text ? "transparent" : internalChecked ? activeColour : inactiveColour
+
+    implicitWidth: row.implicitWidth + horizontalPadding * 2
+    implicitHeight: row.implicitHeight + verticalPadding * 2
+
+    StateLayer {
+        id: stateLayer
+
+        color: root.internalChecked ? root.activeOnColour : root.inactiveOnColour
+
+        function onClicked(): void {
+            if (root.toggle)
+                root.internalChecked = !root.internalChecked;
+            root.clicked();
+        }
+    }
+
+    Row {
+        id: row
+
+        anchors.centerIn: parent
+        spacing: Appearance.spacing.small
+
+        MaterialIcon {
+            id: iconLabel
+
+            anchors.verticalCenter: parent.verticalCenter
+            color: root.internalChecked ? root.activeOnColour : root.inactiveOnColour
+            fill: root.internalChecked ? 1 : 0
+
+            Behavior on fill {
+                Anim {}
+            }
+        }
+
+        StyledText {
+            id: label
+
+            anchors.verticalCenter: parent.verticalCenter
+            color: root.internalChecked ? root.activeOnColour : root.inactiveOnColour
+        }
+    }
+
+    Behavior on radius {
+        Anim {}
+    }
+}

components/controls/Menu.qml

@@ -0,0 +1,113 @@
+pragma ComponentBehavior: Bound
+
+import ".."
+import "../effects"
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Layouts
+
+Elevation {
+    id: root
+
+    property list<MenuItem> items
+    property MenuItem active: items[0] ?? null
+    property bool expanded
+
+    signal itemSelected(item: MenuItem)
+
+    radius: Appearance.rounding.small / 2
+    level: 2
+
+    implicitWidth: Math.max(200, column.implicitWidth)
+    implicitHeight: root.expanded ? column.implicitHeight : 0
+    opacity: root.expanded ? 1 : 0
+
+    StyledClippingRect {
+        anchors.fill: parent
+        radius: parent.radius
+        color: Colours.palette.m3surfaceContainer
+
+        ColumnLayout {
+            id: column
+
+            anchors.left: parent.left
+            anchors.right: parent.right
+            spacing: 0
+
+            Repeater {
+                model: root.items
+
+                StyledRect {
+                    id: item
+
+                    required property int index
+                    required property MenuItem modelData
+                    readonly property bool active: modelData === root.active
+
+                    Layout.fillWidth: true
+                    implicitWidth: menuOptionRow.implicitWidth + Appearance.padding.normal * 2
+                    implicitHeight: menuOptionRow.implicitHeight + Appearance.padding.normal * 2
+
+                    color: Qt.alpha(Colours.palette.m3secondaryContainer, active ? 1 : 0)
+
+                    StateLayer {
+                        color: item.active ? Colours.palette.m3onSecondaryContainer : Colours.palette.m3onSurface
+                        disabled: !root.expanded
+
+                        function onClicked(): void {
+                            root.itemSelected(item.modelData);
+                            root.active = item.modelData;
+                            root.expanded = false;
+                        }
+                    }
+
+                    RowLayout {
+                        id: menuOptionRow
+
+                        anchors.fill: parent
+                        anchors.margins: Appearance.padding.normal
+                        spacing: Appearance.spacing.small
+
+                        MaterialIcon {
+                            Layout.alignment: Qt.AlignVCenter
+                            text: item.modelData.icon
+                            color: item.active ? Colours.palette.m3onSecondaryContainer : Colours.palette.m3onSurfaceVariant
+                        }
+
+                        StyledText {
+                            Layout.alignment: Qt.AlignVCenter
+                            Layout.fillWidth: true
+                            text: item.modelData.text
+                            color: item.active ? Colours.palette.m3onSecondaryContainer : Colours.palette.m3onSurface
+                        }
+
+                        Loader {
+                            Layout.alignment: Qt.AlignVCenter
+                            active: item.modelData.trailingIcon.length > 0
+                            visible: active
+
+                            sourceComponent: MaterialIcon {
+                                text: item.modelData.trailingIcon
+                                color: item.active ? Colours.palette.m3onSecondaryContainer : Colours.palette.m3onSurface
+                            }
+                        }
+                    }
+                }
+            }
+        }
+    }
+
+    Behavior on opacity {
+        Anim {
+            duration: Appearance.anim.durations.expressiveDefaultSpatial
+        }
+    }
+
+    Behavior on implicitHeight {
+        Anim {
+            duration: Appearance.anim.durations.expressiveDefaultSpatial
+            easing.bezierCurve: Appearance.anim.curves.expressiveDefaultSpatial
+        }
+    }
+}

components/controls/MenuItem.qml

@@ -0,0 +1,11 @@
+import QtQuick
+
+QtObject {
+    required property string text
+    property string icon
+    property string trailingIcon
+    property string activeIcon: icon
+    property string activeText: text
+
+    signal clicked
+}

components/controls/SplitButton.qml

@@ -0,0 +1,164 @@
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Layouts
+
+Row {
+    id: root
+
+    enum Type {
+        Filled,
+        Tonal
+    }
+
+    property real horizontalPadding: Appearance.padding.normal
+    property real verticalPadding: Appearance.padding.smaller
+    property int type: SplitButton.Filled
+    property bool disabled
+    property bool menuOnTop
+    property string fallbackIcon
+    property string fallbackText
+
+    property alias menuItems: menu.items
+    property alias active: menu.active
+    property alias expanded: menu.expanded
+    property alias menu: menu
+    property alias iconLabel: iconLabel
+    property alias label: label
+    property alias stateLayer: stateLayer
+
+    property color colour: type == SplitButton.Filled ? Colours.palette.m3primary : Colours.palette.m3secondaryContainer
+    property color textColour: type == SplitButton.Filled ? Colours.palette.m3onPrimary : Colours.palette.m3onSecondaryContainer
+    property color disabledColour: Qt.alpha(Colours.palette.m3onSurface, 0.1)
+    property color disabledTextColour: Qt.alpha(Colours.palette.m3onSurface, 0.38)
+
+    spacing: Math.floor(Appearance.spacing.small / 2)
+
+    StyledRect {
+        radius: implicitHeight / 2
+        topRightRadius: Appearance.rounding.small / 2
+        bottomRightRadius: Appearance.rounding.small / 2
+        color: root.disabled ? root.disabledColour : root.colour
+
+        implicitWidth: textRow.implicitWidth + root.horizontalPadding * 2
+        implicitHeight: expandBtn.implicitHeight
+
+        StateLayer {
+            id: stateLayer
+
+            rect.topRightRadius: parent.topRightRadius
+            rect.bottomRightRadius: parent.bottomRightRadius
+            color: root.textColour
+            disabled: root.disabled
+
+            function onClicked(): void {
+                root.active?.clicked();
+            }
+        }
+
+        RowLayout {
+            id: textRow
+
+            anchors.centerIn: parent
+            anchors.horizontalCenterOffset: Math.floor(root.verticalPadding / 4)
+            spacing: Appearance.spacing.small
+
+            MaterialIcon {
+                id: iconLabel
+
+                Layout.alignment: Qt.AlignVCenter
+                animate: true
+                text: root.active?.activeIcon ?? root.fallbackIcon
+                color: root.disabled ? root.disabledTextColour : root.textColour
+                fill: 1
+            }
+
+            StyledText {
+                id: label
+
+                Layout.alignment: Qt.AlignVCenter
+                Layout.preferredWidth: implicitWidth
+                animate: true
+                text: root.active?.activeText ?? root.fallbackText
+                color: root.disabled ? root.disabledTextColour : root.textColour
+                clip: true
+
+                Behavior on Layout.preferredWidth {
+                    Anim {
+                        easing.bezierCurve: Appearance.anim.curves.emphasized
+                    }
+                }
+            }
+        }
+    }
+
+    StyledRect {
+        id: expandBtn
+
+        property real rad: root.expanded ? implicitHeight / 2 : Appearance.rounding.small / 2
+
+        radius: implicitHeight / 2
+        topLeftRadius: rad
+        bottomLeftRadius: rad
+        color: root.disabled ? root.disabledColour : root.colour
+
+        implicitWidth: implicitHeight
+        implicitHeight: expandIcon.implicitHeight + root.verticalPadding * 2
+
+        StateLayer {
+            id: expandStateLayer
+
+            rect.topLeftRadius: parent.topLeftRadius
+            rect.bottomLeftRadius: parent.bottomLeftRadius
+            color: root.textColour
+            disabled: root.disabled
+
+            function onClicked(): void {
+                root.expanded = !root.expanded;
+            }
+        }
+
+        MaterialIcon {
+            id: expandIcon
+
+            anchors.centerIn: parent
+            anchors.horizontalCenterOffset: root.expanded ? 0 : -Math.floor(root.verticalPadding / 4)
+
+            text: "expand_more"
+            color: root.disabled ? root.disabledTextColour : root.textColour
+            rotation: root.expanded ? 180 : 0
+
+            Behavior on anchors.horizontalCenterOffset {
+                Anim {}
+            }
+
+            Behavior on rotation {
+                Anim {}
+            }
+        }
+
+        Behavior on rad {
+            Anim {}
+        }
+
+        Menu {
+            id: menu
+
+            states: State {
+                when: root.menuOnTop
+
+                AnchorChanges {
+                    target: menu
+                    anchors.top: undefined
+                    anchors.bottom: expandBtn.top
+                }
+            }
+
+            anchors.top: parent.bottom
+            anchors.right: parent.right
+            anchors.topMargin: Appearance.spacing.small
+            anchors.bottomMargin: Appearance.spacing.small
+        }
+    }
+}

components/controls/StyledRadioButton.qml

@@ -0,0 +1,57 @@
+import qs.components
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Templates
+
+RadioButton {
+    id: root
+
+    font.pointSize: Appearance.font.size.smaller
+
+    implicitWidth: implicitIndicatorWidth + implicitContentWidth + contentItem.anchors.leftMargin
+    implicitHeight: Math.max(implicitIndicatorHeight, implicitContentHeight)
+
+    indicator: Rectangle {
+        id: outerCircle
+
+        implicitWidth: 20
+        implicitHeight: 20
+        radius: Appearance.rounding.full
+        color: "transparent"
+        border.color: root.checked ? Colours.palette.m3primary : Colours.palette.m3onSurfaceVariant
+        border.width: 2
+        anchors.verticalCenter: parent.verticalCenter
+
+        StateLayer {
+            anchors.margins: -Appearance.padding.smaller
+            color: root.checked ? Colours.palette.m3onSurface : Colours.palette.m3primary
+            z: -1
+
+            function onClicked(): void {
+                root.click();
+            }
+        }
+
+        StyledRect {
+            anchors.centerIn: parent
+            implicitWidth: 8
+            implicitHeight: 8
+
+            radius: Appearance.rounding.full
+            color: Qt.alpha(Colours.palette.m3primary, root.checked ? 1 : 0)
+        }
+
+        Behavior on border.color {
+            CAnim {}
+        }
+    }
+
+    contentItem: StyledText {
+        text: root.text
+        font.pointSize: root.font.pointSize
+        anchors.verticalCenter: parent.verticalCenter
+        anchors.left: outerCircle.right
+        anchors.leftMargin: Appearance.spacing.smaller
+    }
+}

components/controls/StyledScrollBar.qml

@@ -0,0 +1,108 @@
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Templates
+
+ScrollBar {
+    id: root
+
+    required property Flickable flickable
+    property bool shouldBeActive
+    property real nonAnimPosition
+    property bool animating
+
+    onHoveredChanged: {
+        if (hovered)
+            shouldBeActive = true;
+        else
+            shouldBeActive = flickable.moving;
+    }
+
+    onPositionChanged: {
+        if (position === nonAnimPosition)
+            animating = false;
+        else if (!animating)
+            nonAnimPosition = position;
+    }
+
+    position: nonAnimPosition
+    implicitWidth: Appearance.padding.small
+
+    contentItem: StyledRect {
+        anchors.left: parent.left
+        anchors.right: parent.right
+        opacity: {
+            if (root.size === 1)
+                return 0;
+            if (fullMouse.pressed)
+                return 1;
+            if (mouse.containsMouse)
+                return 0.8;
+            if (root.policy === ScrollBar.AlwaysOn || root.shouldBeActive)
+                return 0.6;
+            return 0;
+        }
+        radius: Appearance.rounding.full
+        color: Colours.palette.m3secondary
+
+        MouseArea {
+            id: mouse
+
+            anchors.fill: parent
+            cursorShape: Qt.PointingHandCursor
+            hoverEnabled: true
+            acceptedButtons: Qt.NoButton
+        }
+
+        Behavior on opacity {
+            Anim {}
+        }
+    }
+
+    Connections {
+        target: root.flickable
+
+        function onMovingChanged(): void {
+            if (root.flickable.moving)
+                root.shouldBeActive = true;
+            else
+                hideDelay.restart();
+        }
+    }
+
+    Timer {
+        id: hideDelay
+
+        interval: 600
+        onTriggered: root.shouldBeActive = root.flickable.moving || root.hovered
+    }
+
+    CustomMouseArea {
+        id: fullMouse
+
+        anchors.fill: parent
+        preventStealing: true
+
+        onPressed: event => {
+            root.animating = true;
+            root.nonAnimPosition = Math.max(0, Math.min(1 - root.size, event.y / root.height - root.size / 2));
+        }
+
+        onPositionChanged: event => root.nonAnimPosition = Math.max(0, Math.min(1 - root.size, event.y / root.height - root.size / 2))
+
+        function onWheel(event: WheelEvent): void {
+            root.animating = true;
+            if (event.angleDelta.y > 0)
+                root.nonAnimPosition = Math.max(0, root.nonAnimPosition - 0.1);
+            else if (event.angleDelta.y < 0)
+                root.nonAnimPosition = Math.min(1 - root.size, root.nonAnimPosition + 0.1);
+        }
+    }
+
+    Behavior on position {
+        enabled: !fullMouse.pressed
+
+        Anim {}
+    }
+}

components/controls/StyledSlider.qml

@@ -0,0 +1,57 @@
+import qs.components
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Templates
+
+Slider {
+    id: root
+
+    background: Item {
+        StyledRect {
+            anchors.top: parent.top
+            anchors.bottom: parent.bottom
+            anchors.left: parent.left
+            anchors.topMargin: root.implicitHeight / 3
+            anchors.bottomMargin: root.implicitHeight / 3
+
+            implicitWidth: root.handle.x - root.implicitHeight / 6
+
+            color: Colours.palette.m3primary
+            radius: Appearance.rounding.full
+            topRightRadius: root.implicitHeight / 15
+            bottomRightRadius: root.implicitHeight / 15
+        }
+
+        StyledRect {
+            anchors.top: parent.top
+            anchors.bottom: parent.bottom
+            anchors.right: parent.right
+            anchors.topMargin: root.implicitHeight / 3
+            anchors.bottomMargin: root.implicitHeight / 3
+
+            implicitWidth: parent.width - root.handle.x - root.handle.implicitWidth - root.implicitHeight / 6
+
+            color: Colours.tPalette.m3surfaceContainer
+            radius: Appearance.rounding.full
+            topLeftRadius: root.implicitHeight / 15
+            bottomLeftRadius: root.implicitHeight / 15
+        }
+    }
+
+    handle: StyledRect {
+        x: root.visualPosition * root.availableWidth - implicitWidth / 2
+
+        implicitWidth: root.implicitHeight / 4.5
+        implicitHeight: root.implicitHeight
+
+        color: Colours.palette.m3primary
+        radius: Appearance.rounding.full
+
+        MouseArea {
+            anchors.fill: parent
+            acceptedButtons: Qt.NoButton
+            cursorShape: Qt.PointingHandCursor
+        }
+    }
+}

components/controls/StyledSwitch.qml

@@ -0,0 +1,152 @@
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Templates
+import QtQuick.Shapes
+
+Switch {
+    id: root
+
+    property int cLayer: 1
+
+    implicitWidth: implicitIndicatorWidth
+    implicitHeight: implicitIndicatorHeight
+
+    indicator: StyledRect {
+        radius: Appearance.rounding.full
+        color: root.checked ? Colours.palette.m3primary : Colours.layer(Colours.palette.m3surfaceContainerHighest, root.cLayer)
+
+        implicitWidth: implicitHeight * 1.7
+        implicitHeight: Appearance.font.size.normal + Appearance.padding.smaller * 2
+
+        StyledRect {
+            readonly property real nonAnimWidth: root.pressed ? implicitHeight * 1.3 : implicitHeight
+
+            radius: Appearance.rounding.full
+            color: root.checked ? Colours.palette.m3onPrimary : Colours.layer(Colours.palette.m3outline, root.cLayer + 1)
+
+            x: root.checked ? parent.implicitWidth - nonAnimWidth - Appearance.padding.small / 2 : Appearance.padding.small / 2
+            implicitWidth: nonAnimWidth
+            implicitHeight: parent.implicitHeight - Appearance.padding.small
+            anchors.verticalCenter: parent.verticalCenter
+
+            StyledRect {
+                anchors.fill: parent
+                radius: parent.radius
+
+                color: root.checked ? Colours.palette.m3primary : Colours.palette.m3onSurface
+                opacity: root.pressed ? 0.1 : root.hovered ? 0.08 : 0
+
+                Behavior on opacity {
+                    Anim {}
+                }
+            }
+
+            Shape {
+                id: icon
+
+                property point start1: {
+                    if (root.pressed)
+                        return Qt.point(width * 0.2, height / 2);
+                    if (root.checked)
+                        return Qt.point(width * 0.15, height / 2);
+                    return Qt.point(width * 0.15, height * 0.15);
+                }
+                property point end1: {
+                    if (root.pressed) {
+                        if (root.checked)
+                            return Qt.point(width * 0.4, height / 2);
+                        return Qt.point(width * 0.8, height / 2);
+                    }
+                    if (root.checked)
+                        return Qt.point(width * 0.4, height * 0.7);
+                    return Qt.point(width * 0.85, height * 0.85);
+                }
+                property point start2: {
+                    if (root.pressed) {
+                        if (root.checked)
+                            return Qt.point(width * 0.4, height / 2);
+                        return Qt.point(width * 0.2, height / 2);
+                    }
+                    if (root.checked)
+                        return Qt.point(width * 0.4, height * 0.7);
+                    return Qt.point(width * 0.15, height * 0.85);
+                }
+                property point end2: {
+                    if (root.pressed)
+                        return Qt.point(width * 0.8, height / 2);
+                    if (root.checked)
+                        return Qt.point(width * 0.85, height * 0.2);
+                    return Qt.point(width * 0.85, height * 0.15);
+                }
+
+                anchors.centerIn: parent
+                width: height
+                height: parent.implicitHeight - Appearance.padding.small * 2
+                preferredRendererType: Shape.CurveRenderer
+                asynchronous: true
+
+                ShapePath {
+                    strokeWidth: Appearance.font.size.larger * 0.15
+                    strokeColor: root.checked ? Colours.palette.m3primary : Colours.palette.m3surfaceContainerHighest
+                    fillColor: "transparent"
+                    capStyle: Appearance.rounding.scale === 0 ? ShapePath.SquareCap : ShapePath.RoundCap
+
+                    startX: icon.start1.x
+                    startY: icon.start1.y
+
+                    PathLine {
+                        x: icon.end1.x
+                        y: icon.end1.y
+                    }
+                    PathMove {
+                        x: icon.start2.x
+                        y: icon.start2.y
+                    }
+                    PathLine {
+                        x: icon.end2.x
+                        y: icon.end2.y
+                    }
+
+                    Behavior on strokeColor {
+                        CAnim {}
+                    }
+                }
+
+                Behavior on start1 {
+                    PropAnim {}
+                }
+                Behavior on end1 {
+                    PropAnim {}
+                }
+                Behavior on start2 {
+                    PropAnim {}
+                }
+                Behavior on end2 {
+                    PropAnim {}
+                }
+            }
+
+            Behavior on x {
+                Anim {}
+            }
+
+            Behavior on implicitWidth {
+                Anim {}
+            }
+        }
+    }
+
+    MouseArea {
+        anchors.fill: parent
+        cursorShape: Qt.PointingHandCursor
+        enabled: false
+    }
+
+    component PropAnim: PropertyAnimation {
+        duration: Appearance.anim.durations.normal
+        easing.type: Easing.BezierSpline
+        easing.bezierCurve: Appearance.anim.curves.standard
+    }
+}

components/controls/StyledTextField.qml

@@ -0,0 +1,76 @@
+pragma ComponentBehavior: Bound
+
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Controls
+
+TextField {
+    id: root
+
+    color: Colours.palette.m3onSurface
+    placeholderTextColor: Colours.palette.m3outline
+    font.family: Appearance.font.family.sans
+    font.pointSize: Appearance.font.size.smaller
+    renderType: TextField.NativeRendering
+    cursorVisible: !readOnly
+
+    background: null
+
+    cursorDelegate: StyledRect {
+        id: cursor
+
+        property bool disableBlink
+
+        implicitWidth: 2
+        color: Colours.palette.m3primary
+        radius: Appearance.rounding.normal
+
+        Connections {
+            target: root
+
+            function onCursorPositionChanged(): void {
+                if (root.activeFocus && root.cursorVisible) {
+                    cursor.opacity = 1;
+                    cursor.disableBlink = true;
+                    enableBlink.restart();
+                }
+            }
+        }
+
+        Timer {
+            id: enableBlink
+
+            interval: 100
+            onTriggered: cursor.disableBlink = false
+        }
+
+        Timer {
+            running: root.activeFocus && root.cursorVisible && !cursor.disableBlink
+            repeat: true
+            triggeredOnStart: true
+            interval: 500
+            onTriggered: parent.opacity = parent.opacity === 1 ? 0 : 1
+        }
+
+        Binding {
+            when: !root.activeFocus || !root.cursorVisible
+            cursor.opacity: 0
+        }
+
+        Behavior on opacity {
+            Anim {
+                duration: Appearance.anim.durations.small
+            }
+        }
+    }
+
+    Behavior on color {
+        CAnim {}
+    }
+
+    Behavior on placeholderTextColor {
+        CAnim {}
+    }
+}

components/controls/TextButton.qml

@@ -0,0 +1,78 @@
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+
+StyledRect {
+    id: root
+
+    enum Type {
+        Filled,
+        Tonal,
+        Text
+    }
+
+    property alias text: label.text
+    property bool checked
+    property bool toggle
+    property real horizontalPadding: Appearance.padding.normal
+    property real verticalPadding: Appearance.padding.smaller
+    property alias font: label.font
+    property int type: TextButton.Filled
+
+    property alias stateLayer: stateLayer
+    property alias label: label
+
+    property bool internalChecked
+    property color activeColour: type === TextButton.Filled ? Colours.palette.m3primary : Colours.palette.m3secondary
+    property color inactiveColour: {
+        if (!toggle && type === TextButton.Filled)
+            return Colours.palette.m3primary;
+        return type === TextButton.Filled ? Colours.tPalette.m3surfaceContainer : Colours.palette.m3secondaryContainer;
+    }
+    property color activeOnColour: {
+        if (type === TextButton.Text)
+            return Colours.palette.m3primary;
+        return type === TextButton.Filled ? Colours.palette.m3onPrimary : Colours.palette.m3onSecondary;
+    }
+    property color inactiveOnColour: {
+        if (!toggle && type === TextButton.Filled)
+            return Colours.palette.m3onPrimary;
+        if (type === TextButton.Text)
+            return Colours.palette.m3primary;
+        return type === TextButton.Filled ? Colours.palette.m3onSurface : Colours.palette.m3onSecondaryContainer;
+    }
+
+    signal clicked
+
+    onCheckedChanged: internalChecked = checked
+
+    radius: internalChecked ? Appearance.rounding.small : implicitHeight / 2
+    color: type === TextButton.Text ? "transparent" : internalChecked ? activeColour : inactiveColour
+
+    implicitWidth: label.implicitWidth + horizontalPadding * 2
+    implicitHeight: label.implicitHeight + verticalPadding * 2
+
+    StateLayer {
+        id: stateLayer
+
+        color: root.internalChecked ? root.activeOnColour : root.inactiveOnColour
+
+        function onClicked(): void {
+            if (root.toggle)
+                root.internalChecked = !root.internalChecked;
+            root.clicked();
+        }
+    }
+
+    StyledText {
+        id: label
+
+        anchors.centerIn: parent
+        color: root.internalChecked ? root.activeOnColour : root.inactiveOnColour
+    }
+
+    Behavior on radius {
+        Anim {}
+    }
+}

components/effects/ColouredIcon.qml

@@ -0,0 +1,35 @@
+pragma ComponentBehavior: Bound
+
+import Caelestia
+import Quickshell.Widgets
+import QtQuick
+
+IconImage {
+    id: root
+
+    required property color colour
+
+    asynchronous: true
+
+    layer.enabled: true
+    layer.effect: Colouriser {
+        sourceColor: analyser.dominantColour
+        colorizationColor: root.colour
+    }
+
+    layer.onEnabledChanged: {
+        if (layer.enabled && status === Image.Ready)
+            analyser.requestUpdate();
+    }
+
+    onStatusChanged: {
+        if (layer.enabled && status === Image.Ready)
+            analyser.requestUpdate();
+    }
+
+    ImageAnalyser {
+        id: analyser
+
+        sourceItem: root
+    }
+}

components/effects/Colouriser.qml

@@ -0,0 +1,14 @@
+import ".."
+import QtQuick
+import QtQuick.Effects
+
+MultiEffect {
+    property color sourceColor: "black"
+
+    colorization: 1
+    brightness: 1 - sourceColor.hslLightness
+
+    Behavior on colorizationColor {
+        CAnim {}
+    }
+}

components/effects/Elevation.qml

@@ -0,0 +1,18 @@
+import ".."
+import qs.services
+import QtQuick
+import QtQuick.Effects
+
+RectangularShadow {
+    property int level
+    property real dp: [0, 1, 3, 6, 8, 12][level]
+
+    color: Qt.alpha(Colours.palette.m3shadow, 0.7)
+    blur: (dp * 5) ** 0.7
+    spread: -dp * 0.3 + (dp * 0.1) ** 2
+    offset.y: dp / 2
+
+    Behavior on dp {
+        Anim {}
+    }
+}

components/effects/InnerBorder.qml

@@ -0,0 +1,44 @@
+pragma ComponentBehavior: Bound
+
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Effects
+
+StyledRect {
+    property alias innerRadius: maskInner.radius
+    property alias thickness: maskInner.anchors.margins
+    property alias leftThickness: maskInner.anchors.leftMargin
+    property alias topThickness: maskInner.anchors.topMargin
+    property alias rightThickness: maskInner.anchors.rightMargin
+    property alias bottomThickness: maskInner.anchors.bottomMargin
+
+    anchors.fill: parent
+    color: Colours.tPalette.m3surfaceContainer
+
+    layer.enabled: true
+    layer.effect: MultiEffect {
+        maskSource: mask
+        maskEnabled: true
+        maskInverted: true
+        maskThresholdMin: 0.5
+        maskSpreadAtMin: 1
+    }
+
+    Item {
+        id: mask
+
+        anchors.fill: parent
+        layer.enabled: true
+        visible: false
+
+        Rectangle {
+            id: maskInner
+
+            anchors.fill: parent
+            anchors.margins: Appearance.padding.normal
+            radius: Appearance.rounding.small
+        }
+    }
+}

components/effects/OpacityMask.qml

@@ -0,0 +1,9 @@
+import Quickshell
+import QtQuick
+
+ShaderEffect {
+    required property Item source
+    required property Item maskSource
+
+    fragmentShader: Qt.resolvedUrl(`${Quickshell.shellDir}/assets/shaders/opacitymask.frag.qsb`)
+}

components/filedialog/CurrentItem.qml

@@ -0,0 +1,102 @@
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Shapes
+
+Item {
+    id: root
+
+    required property var currentItem
+
+    implicitWidth: content.implicitWidth + Appearance.padding.larger + content.anchors.rightMargin
+    implicitHeight: currentItem ? content.implicitHeight + Appearance.padding.normal + content.anchors.bottomMargin : 0
+
+    Shape {
+        preferredRendererType: Shape.CurveRenderer
+
+        ShapePath {
+            id: path
+
+            readonly property real rounding: Appearance.rounding.small
+            readonly property bool flatten: root.implicitHeight < rounding * 2
+            readonly property real roundingY: flatten ? root.implicitHeight / 2 : rounding
+
+            strokeWidth: -1
+            fillColor: Colours.tPalette.m3surfaceContainer
+
+            startX: root.implicitWidth
+            startY: root.implicitHeight
+
+            PathLine {
+                relativeX: -(root.implicitWidth + path.rounding)
+                relativeY: 0
+            }
+            PathArc {
+                relativeX: path.rounding
+                relativeY: -path.roundingY
+                radiusX: path.rounding
+                radiusY: Math.min(path.rounding, root.implicitHeight)
+                direction: PathArc.Counterclockwise
+            }
+            PathLine {
+                relativeX: 0
+                relativeY: -(root.implicitHeight - path.roundingY * 2)
+            }
+            PathArc {
+                relativeX: path.rounding
+                relativeY: -path.roundingY
+                radiusX: path.rounding
+                radiusY: Math.min(path.rounding, root.implicitHeight)
+            }
+            PathLine {
+                relativeX: root.implicitHeight > 0 ? root.implicitWidth - path.rounding * 2 : root.implicitWidth
+                relativeY: 0
+            }
+            PathArc {
+                relativeX: path.rounding
+                relativeY: -path.rounding
+                radiusX: path.rounding
+                radiusY: path.rounding
+                direction: PathArc.Counterclockwise
+            }
+
+            Behavior on fillColor {
+                CAnim {}
+            }
+        }
+    }
+
+    Item {
+        anchors.fill: parent
+        clip: true
+
+        StyledText {
+            id: content
+
+            anchors.right: parent.right
+            anchors.bottom: parent.bottom
+            anchors.rightMargin: Appearance.padding.larger - Appearance.padding.small
+            anchors.bottomMargin: Appearance.padding.normal - Appearance.padding.small
+
+            Connections {
+                target: root
+
+                function onCurrentItemChanged(): void {
+                    if (root.currentItem)
+                        content.text = qsTr(`"%1" selected`).arg(root.currentItem.modelData.name);
+                }
+            }
+        }
+    }
+
+    Behavior on implicitWidth {
+        enabled: !!root.currentItem
+
+        Anim {}
+    }
+
+    Behavior on implicitHeight {
+        Anim {}
+    }
+}

components/filedialog/DialogButtons.qml

@@ -0,0 +1,93 @@
+import ".."
+import qs.services
+import qs.config
+import QtQuick.Layouts
+
+StyledRect {
+    id: root
+
+    required property var dialog
+    required property FolderContents folder
+
+    implicitHeight: inner.implicitHeight + Appearance.padding.normal * 2
+
+    color: Colours.tPalette.m3surfaceContainer
+
+    RowLayout {
+        id: inner
+
+        anchors.fill: parent
+        anchors.margins: Appearance.padding.normal
+
+        spacing: Appearance.spacing.small
+
+        StyledText {
+            text: qsTr("Filter:")
+        }
+
+        StyledRect {
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+            Layout.rightMargin: Appearance.spacing.normal
+
+            color: Colours.tPalette.m3surfaceContainerHigh
+            radius: Appearance.rounding.small
+
+            StyledText {
+                anchors.fill: parent
+                anchors.margins: Appearance.padding.normal
+
+                text: `${root.dialog.filterLabel} (${root.dialog.filters.map(f => `*.${f}`).join(", ")})`
+            }
+        }
+
+        StyledRect {
+            color: Colours.tPalette.m3surfaceContainerHigh
+            radius: Appearance.rounding.small
+
+            implicitWidth: cancelText.implicitWidth + Appearance.padding.normal * 2
+            implicitHeight: cancelText.implicitHeight + Appearance.padding.normal * 2
+
+            StateLayer {
+                disabled: !root.dialog.selectionValid
+
+                function onClicked(): void {
+                    root.dialog.accepted(root.folder.currentItem.modelData.path);
+                }
+            }
+
+            StyledText {
+                id: selectText
+
+                anchors.centerIn: parent
+                anchors.margins: Appearance.padding.normal
+
+                text: qsTr("Select")
+                color: root.dialog.selectionValid ? Colours.palette.m3onSurface : Colours.palette.m3outline
+            }
+        }
+
+        StyledRect {
+            color: Colours.tPalette.m3surfaceContainerHigh
+            radius: Appearance.rounding.small
+
+            implicitWidth: cancelText.implicitWidth + Appearance.padding.normal * 2
+            implicitHeight: cancelText.implicitHeight + Appearance.padding.normal * 2
+
+            StateLayer {
+                function onClicked(): void {
+                    root.dialog.rejected();
+                }
+            }
+
+            StyledText {
+                id: cancelText
+
+                anchors.centerIn: parent
+                anchors.margins: Appearance.padding.normal
+
+                text: qsTr("Cancel")
+            }
+        }
+    }
+}

components/filedialog/FileDialog.qml

@@ -0,0 +1,102 @@
+pragma ComponentBehavior: Bound
+
+import qs.components
+import qs.services
+import Quickshell
+import QtQuick
+import QtQuick.Layouts
+
+LazyLoader {
+    id: loader
+
+    property list<string> cwd: ["Home"]
+    property string filterLabel: "All files"
+    property list<string> filters: ["*"]
+    property string title: qsTr("Select a file")
+
+    signal accepted(path: string)
+    signal rejected
+
+    function open(): void {
+        activeAsync = true;
+    }
+
+    function close(): void {
+        rejected();
+    }
+
+    onAccepted: activeAsync = false
+    onRejected: activeAsync = false
+
+    FloatingWindow {
+        id: root
+
+        property list<string> cwd: loader.cwd
+        property string filterLabel: loader.filterLabel
+        property list<string> filters: loader.filters
+
+        readonly property bool selectionValid: {
+            const file = folderContents.currentItem?.modelData;
+            return (file && !file.isDir && (filters.includes("*") || filters.includes(file.suffix))) ?? false;
+        }
+
+        function accepted(path: string): void {
+            loader.accepted(path);
+        }
+
+        function rejected(): void {
+            loader.rejected();
+        }
+
+        implicitWidth: 1000
+        implicitHeight: 600
+        color: Colours.tPalette.m3surface
+        title: loader.title
+
+        onVisibleChanged: {
+            if (!visible)
+                rejected();
+        }
+
+        RowLayout {
+            anchors.fill: parent
+
+            spacing: 0
+
+            Sidebar {
+                Layout.fillHeight: true
+                dialog: root
+            }
+
+            ColumnLayout {
+                Layout.fillWidth: true
+                Layout.fillHeight: true
+
+                spacing: 0
+
+                HeaderBar {
+                    Layout.fillWidth: true
+                    dialog: root
+                }
+
+                FolderContents {
+                    id: folderContents
+
+                    Layout.fillWidth: true
+                    Layout.fillHeight: true
+                    dialog: root
+                }
+
+                DialogButtons {
+                    Layout.fillWidth: true
+                    dialog: root
+                    folder: folderContents
+                }
+            }
+        }
+
+        Behavior on color {
+            CAnim {}
+        }
+    }
+}

components/filedialog/FolderContents.qml

@@ -0,0 +1,229 @@
+pragma ComponentBehavior: Bound
+
+import ".."
+import "../controls"
+import "../images"
+import qs.services
+import qs.config
+import qs.utils
+import Caelestia.Models
+import Quickshell
+import QtQuick
+import QtQuick.Layouts
+import QtQuick.Effects
+
+Item {
+    id: root
+
+    required property var dialog
+    property alias currentItem: view.currentItem
+
+    StyledRect {
+        anchors.fill: parent
+        color: Colours.tPalette.m3surfaceContainer
+
+        layer.enabled: true
+        layer.effect: MultiEffect {
+            maskSource: mask
+            maskEnabled: true
+            maskInverted: true
+            maskThresholdMin: 0.5
+            maskSpreadAtMin: 1
+        }
+    }
+
+    Item {
+        id: mask
+
+        anchors.fill: parent
+        layer.enabled: true
+        visible: false
+
+        Rectangle {
+            anchors.fill: parent
+            anchors.margins: Appearance.padding.small
+            radius: Appearance.rounding.small
+        }
+    }
+
+    Loader {
+        anchors.centerIn: parent
+
+        opacity: view.count === 0 ? 1 : 0
+        active: opacity > 0
+        asynchronous: true
+
+        sourceComponent: ColumnLayout {
+            MaterialIcon {
+                Layout.alignment: Qt.AlignHCenter
+                text: "scan_delete"
+                color: Colours.palette.m3outline
+                font.pointSize: Appearance.font.size.extraLarge * 2
+                font.weight: 500
+            }
+
+            StyledText {
+                text: qsTr("This folder is empty")
+                color: Colours.palette.m3outline
+                font.pointSize: Appearance.font.size.large
+                font.weight: 500
+            }
+        }
+
+        Behavior on opacity {
+            Anim {}
+        }
+    }
+
+    GridView {
+        id: view
+
+        anchors.fill: parent
+        anchors.margins: Appearance.padding.small + Appearance.padding.normal
+
+        cellWidth: Sizes.itemWidth + Appearance.spacing.small
+        cellHeight: Sizes.itemWidth + Appearance.spacing.small * 2 + Appearance.padding.normal * 2 + 1
+
+        clip: true
+        focus: true
+        currentIndex: -1
+        Keys.onEscapePressed: currentIndex = -1
+
+        Keys.onReturnPressed: {
+            if (root.dialog.selectionValid)
+                root.dialog.accepted(currentItem.modelData.path);
+        }
+        Keys.onEnterPressed: {
+            if (root.dialog.selectionValid)
+                root.dialog.accepted(currentItem.modelData.path);
+        }
+
+        StyledScrollBar.vertical: StyledScrollBar {
+            flickable: view
+        }
+
+        model: FileSystemModel {
+            path: {
+                if (root.dialog.cwd[0] === "Home")
+                    return `${Paths.home}/${root.dialog.cwd.slice(1).join("/")}`;
+                else
+                    return root.dialog.cwd.join("/");
+            }
+            onPathChanged: view.currentIndex = -1
+        }
+
+        delegate: StyledRect {
+            id: item
+
+            required property int index
+            required property FileSystemEntry modelData
+
+            readonly property real nonAnimHeight: icon.implicitHeight + name.anchors.topMargin + name.implicitHeight + Appearance.padding.normal * 2
+
+            implicitWidth: Sizes.itemWidth
+            implicitHeight: nonAnimHeight
+
+            radius: Appearance.rounding.normal
+            color: Qt.alpha(Colours.tPalette.m3surfaceContainerHighest, GridView.isCurrentItem ? Colours.tPalette.m3surfaceContainerHighest.a : 0)
+            z: GridView.isCurrentItem || implicitHeight !== nonAnimHeight ? 1 : 0
+            clip: true
+
+            StateLayer {
+                onDoubleClicked: {
+                    if (item.modelData.isDir)
+                        root.dialog.cwd.push(item.modelData.name);
+                    else if (root.dialog.selectionValid)
+                        root.dialog.accepted(item.modelData.path);
+                }
+
+                function onClicked(): void {
+                    view.currentIndex = item.index;
+                }
+            }
+
+            CachingIconImage {
+                id: icon
+
+                anchors.horizontalCenter: parent.horizontalCenter
+                anchors.top: parent.top
+                anchors.topMargin: Appearance.padding.normal
+
+                implicitSize: Sizes.itemWidth - Appearance.padding.normal * 2
+
+                Component.onCompleted: {
+                    const file = item.modelData;
+                    if (file.isImage)
+                        source = Qt.resolvedUrl(file.path);
+                    else if (!file.isDir)
+                        source = Quickshell.iconPath(file.mimeType.replace("/", "-"), "application-x-zerosize");
+                    else if (root.dialog.cwd.length === 1 && ["Desktop", "Documents", "Downloads", "Music", "Pictures", "Public", "Templates", "Videos"].includes(file.name))
+                        source = Quickshell.iconPath(`folder-${file.name.toLowerCase()}`);
+                    else
+                        source = Quickshell.iconPath("inode-directory");
+                }
+            }
+
+            StyledText {
+                id: name
+
+                anchors.left: parent.left
+                anchors.right: parent.right
+                anchors.top: icon.bottom
+                anchors.topMargin: Appearance.spacing.small
+                anchors.margins: Appearance.padding.normal
+
+                horizontalAlignment: Text.AlignHCenter
+                elide: item.GridView.isCurrentItem ? Text.ElideNone : Text.ElideRight
+                wrapMode: item.GridView.isCurrentItem ? Text.WrapAtWordBoundaryOrAnywhere : Text.NoWrap
+
+                Component.onCompleted: text = item.modelData.name
+            }
+
+            Behavior on implicitHeight {
+                Anim {}
+            }
+        }
+
+        add: Transition {
+            Anim {
+                properties: "opacity,scale"
+                from: 0
+                to: 1
+                duration: Appearance.anim.durations.expressiveDefaultSpatial
+                easing.bezierCurve: Appearance.anim.curves.expressiveDefaultSpatial
+            }
+        }
+
+        remove: Transition {
+            Anim {
+                property: "opacity"
+                to: 0
+            }
+            Anim {
+                property: "scale"
+                to: 0.5
+            }
+        }
+
+        displaced: Transition {
+            Anim {
+                properties: "opacity,scale"
+                to: 1
+                easing.bezierCurve: Appearance.anim.curves.standardDecel
+            }
+            Anim {
+                properties: "x,y"
+                duration: Appearance.anim.durations.expressiveDefaultSpatial
+                easing.bezierCurve: Appearance.anim.curves.expressiveDefaultSpatial
+            }
+        }
+    }
+
+    CurrentItem {
+        anchors.right: parent.right
+        anchors.bottom: parent.bottom
+        anchors.margins: Appearance.padding.small
+
+        currentItem: view.currentItem
+    }
+}

components/filedialog/HeaderBar.qml

@@ -0,0 +1,142 @@
+pragma ComponentBehavior: Bound
+
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Layouts
+
+StyledRect {
+    id: root
+
+    required property var dialog
+
+    implicitWidth: inner.implicitWidth + Appearance.padding.normal * 2
+    implicitHeight: inner.implicitHeight + Appearance.padding.normal * 2
+
+    color: Colours.tPalette.m3surfaceContainer
+
+    RowLayout {
+        id: inner
+
+        anchors.fill: parent
+        anchors.margins: Appearance.padding.normal
+        spacing: Appearance.spacing.small
+
+        Item {
+            implicitWidth: implicitHeight
+            implicitHeight: upIcon.implicitHeight + Appearance.padding.small * 2
+
+            StateLayer {
+                radius: Appearance.rounding.small
+                disabled: root.dialog.cwd.length === 1
+
+                function onClicked(): void {
+                    root.dialog.cwd.pop();
+                }
+            }
+
+            MaterialIcon {
+                id: upIcon
+
+                anchors.centerIn: parent
+                text: "drive_folder_upload"
+                color: root.dialog.cwd.length === 1 ? Colours.palette.m3outline : Colours.palette.m3onSurface
+                grade: 200
+            }
+        }
+
+        StyledRect {
+            Layout.fillWidth: true
+
+            radius: Appearance.rounding.small
+            color: Colours.tPalette.m3surfaceContainerHigh
+
+            implicitHeight: pathComponents.implicitHeight + pathComponents.anchors.margins * 2
+
+            RowLayout {
+                id: pathComponents
+
+                anchors.fill: parent
+                anchors.margins: Appearance.padding.small / 2
+                anchors.leftMargin: 0
+
+                spacing: Appearance.spacing.small
+
+                Repeater {
+                    model: root.dialog.cwd
+
+                    RowLayout {
+                        id: folder
+
+                        required property string modelData
+                        required property int index
+
+                        spacing: 0
+
+                        Loader {
+                            Layout.rightMargin: Appearance.spacing.small
+                            active: folder.index > 0
+                            asynchronous: true
+                            sourceComponent: StyledText {
+                                text: "/"
+                                color: Colours.palette.m3onSurfaceVariant
+                                font.bold: true
+                            }
+                        }
+
+                        Item {
+                            implicitWidth: homeIcon.implicitWidth + (homeIcon.active ? Appearance.padding.small : 0) + folderName.implicitWidth + Appearance.padding.normal * 2
+                            implicitHeight: folderName.implicitHeight + Appearance.padding.small * 2
+
+                            Loader {
+                                anchors.fill: parent
+                                active: folder.index < root.dialog.cwd.length - 1
+                                asynchronous: true
+                                sourceComponent: StateLayer {
+                                    radius: Appearance.rounding.small
+
+                                    function onClicked(): void {
+                                        root.dialog.cwd = root.dialog.cwd.slice(0, folder.index + 1);
+                                    }
+                                }
+                            }
+
+                            Loader {
+                                id: homeIcon
+
+                                anchors.left: parent.left
+                                anchors.verticalCenter: parent.verticalCenter
+                                anchors.leftMargin: Appearance.padding.normal
+
+                                active: folder.index === 0 && folder.modelData === "Home"
+                                asynchronous: true
+                                sourceComponent: MaterialIcon {
+                                    text: "home"
+                                    color: root.dialog.cwd.length === 1 ? Colours.palette.m3onSurface : Colours.palette.m3onSurfaceVariant
+                                    fill: 1
+                                }
+                            }
+
+                            StyledText {
+                                id: folderName
+
+                                anchors.left: homeIcon.right
+                                anchors.verticalCenter: parent.verticalCenter
+                                anchors.leftMargin: homeIcon.active ? Appearance.padding.small : 0
+
+                                text: folder.modelData
+                                color: folder.index < root.dialog.cwd.length - 1 ? Colours.palette.m3onSurfaceVariant : Colours.palette.m3onSurface
+                                font.bold: true
+                            }
+                        }
+                    }
+                }
+
+                Item {
+                    Layout.fillWidth: true
+                }
+            }
+        }
+    }
+}

components/filedialog/Sidebar.qml

@@ -0,0 +1,113 @@
+pragma ComponentBehavior: Bound
+
+import ".."
+import qs.services
+import qs.config
+import QtQuick
+import QtQuick.Layouts
+
+StyledRect {
+    id: root
+
+    required property var dialog
+
+    implicitWidth: Sizes.sidebarWidth
+    implicitHeight: inner.implicitHeight + Appearance.padding.normal * 2
+
+    color: Colours.tPalette.m3surfaceContainer
+
+    ColumnLayout {
+        id: inner
+
+        anchors.left: parent.left
+        anchors.right: parent.right
+        anchors.top: parent.top
+        anchors.margins: Appearance.padding.normal
+        spacing: Appearance.spacing.small / 2
+
+        StyledText {
+            Layout.alignment: Qt.AlignHCenter
+            Layout.topMargin: Appearance.padding.small / 2
+            Layout.bottomMargin: Appearance.spacing.normal
+            text: qsTr("Files")
+            color: Colours.palette.m3onSurface
+            font.pointSize: Appearance.font.size.larger
+            font.bold: true
+        }
+
+        Repeater {
+            model: ["Home", "Downloads", "Desktop", "Documents", "Music", "Pictures", "Videos"]
+
+            StyledRect {
+                id: place
+
+                required property string modelData
+                readonly property bool selected: modelData === root.dialog.cwd[root.dialog.cwd.length - 1]
+
+                Layout.fillWidth: true
+                implicitHeight: placeInner.implicitHeight + Appearance.padding.normal * 2
+
+                radius: Appearance.rounding.full
+                color: Qt.alpha(Colours.palette.m3secondaryContainer, selected ? 1 : 0)
+
+                StateLayer {
+                    color: place.selected ? Colours.palette.m3onSecondaryContainer : Colours.palette.m3onSurface
+
+                    function onClicked(): void {
+                        if (place.modelData === "Home")
+                            root.dialog.cwd = ["Home"];
+                        else
+                            root.dialog.cwd = ["Home", place.modelData];
+                    }
+                }
+
+                RowLayout {
+                    id: placeInner
+
+                    anchors.fill: parent
+                    anchors.margins: Appearance.padding.normal
+                    anchors.leftMargin: Appearance.padding.large
+                    anchors.rightMargin: Appearance.padding.large
+
+                    spacing: Appearance.spacing.normal
+
+                    MaterialIcon {
+                        text: {
+                            const p = place.modelData;
+                            if (p === "Home")
+                                return "home";
+                            if (p === "Downloads")
+                                return "file_download";
+                            if (p === "Desktop")
+                                return "desktop_windows";
+                            if (p === "Documents")
+                                return "description";
+                            if (p === "Music")
+                                return "music_note";
+                            if (p === "Pictures")
+                                return "image";
+                            if (p === "Videos")
+                                return "video_library";
+                            return "folder";
+                        }
+                        color: place.selected ? Colours.palette.m3onSecondaryContainer : Colours.palette.m3onSurface
+                        font.pointSize: Appearance.font.size.large
+                        fill: place.selected ? 1 : 0
+
+                        Behavior on fill {
+                            Anim {}
+                        }
+                    }
+
+                    StyledText {
+                        Layout.fillWidth: true
+                        text: place.modelData
+                        color: place.selected ? Colours.palette.m3onSecondaryContainer : Colours.palette.m3onSurface
+                        font.pointSize: Appearance.font.size.normal
+                        elide: Text.ElideRight
+                    }
+                }
+            }
+        }
+    }
+}

components/filedialog/Sizes.qml

@@ -0,0 +1,8 @@
+pragma Singleton
+
+import Quickshell
+
+Singleton {
+    property int itemWidth: 103
+    property int sidebarWidth: 200
+}

components/images/CachingIconImage.qml

@@ -0,0 +1,42 @@
+pragma ComponentBehavior: Bound
+
+import qs.utils
+import Quickshell.Widgets
+import QtQuick
+
+Item {
+    id: root
+
+    readonly property int status: loader.item?.status ?? Image.Null
+    readonly property real actualSize: Math.min(width, height)
+    property real implicitSize
+    property url source
+
+    implicitWidth: implicitSize
+    implicitHeight: implicitSize
+
+    Loader {
+        id: loader
+
+        anchors.fill: parent
+        sourceComponent: root.source ? root.source.toString().startsWith("image://icon/") ? iconImage : cachingImage : null
+    }
+
+    Component {
+        id: cachingImage
+
+        CachingImage {
+            path: Paths.toLocalFile(root.source)
+            fillMode: Image.PreserveAspectFit
+        }
+    }
+
+    Component {
+        id: iconImage
+
+        IconImage {
+            source: root.source
+            asynchronous: true
+        }
+    }
+}

components/images/CachingImage.qml

@@ -0,0 +1,28 @@
+import qs.utils
+import Caelestia.Internal
+import Quickshell
+import QtQuick
+
+Image {
+    id: root
+
+    property alias path: manager.path
+
+    asynchronous: true
+    fillMode: Image.PreserveAspectCrop
+
+    Connections {
+        target: QsWindow.window
+
+        function onDevicePixelRatioChanged(): void {
+            manager.updateSource();
+        }
+    }
+
+    CachingImageManager {
+        id: manager
+
+        item: root
+        cacheDir: Qt.resolvedUrl(Paths.imagecache)
+    }
+}

components/misc/CustomShortcut.qml

@@ -0,0 +1,5 @@
+import Quickshell.Hyprland
+
+GlobalShortcut {
+    appid: "caelestia"
+}

components/misc/Ref.qml

@@ -0,0 +1,8 @@
+import QtQuick
+
+QtObject {
+    required property var service
+
+    Component.onCompleted: service.refCount++
+    Component.onDestruction: service.refCount--
+}

components/widgets/ExtraIndicator.qml

@@ -0,0 +1,51 @@
+import ".."
+import "../effects"
+import qs.services
+import qs.config
+import QtQuick
+
+StyledRect {
+    required property int extra
+
+    anchors.right: parent.right
+    anchors.margins: Appearance.padding.normal
+
+    color: Colours.palette.m3tertiary
+    radius: Appearance.rounding.small
+
+    implicitWidth: count.implicitWidth + Appearance.padding.normal * 2
+    implicitHeight: count.implicitHeight + Appearance.padding.small * 2
+
+    opacity: extra > 0 ? 1 : 0
+    scale: extra > 0 ? 1 : 0.5
+
+    Elevation {
+        anchors.fill: parent
+        radius: parent.radius
+        opacity: parent.opacity
+        z: -1
+        level: 2
+    }
+
+    StyledText {
+        id: count
+
+        anchors.centerIn: parent
+        animate: parent.opacity > 0
+        text: qsTr("+%1").arg(parent.extra)
+        color: Colours.palette.m3onTertiary
+    }
+
+    Behavior on opacity {
+        Anim {
+            duration: Appearance.anim.durations.expressiveFastSpatial
+        }
+    }
+
+    Behavior on scale {
+        Anim {
+            duration: Appearance.anim.durations.expressiveFastSpatial
+            easing.bezierCurve: Appearance.anim.curves.expressiveFastSpatial
+        }
+    }
+}