overview tests, non-functional

2026-01-20 16:59:16 +01:00
parent 7ddb103767
commit 03427bfa64
12 changed files with 844 additions and 0 deletions
@@ -0,0 +1,23 @@
+import QtQuick
+import QtQuick.Controls
+import qs.Components
+
+ToolTip {
+    id: root
+    property bool extraVisibleCondition: true
+    property bool alternativeVisibleCondition: false
+    readonly property bool internalVisibleCondition: (extraVisibleCondition && (parent.hovered === undefined || parent?.hovered)) || alternativeVisibleCondition
+    verticalPadding: 5
+    horizontalPadding: 10
+    background: null
+
+    visible: internalVisibleCondition
+    
+    contentItem: CustomTooltipContent {
+        id: contentItem
+        text: root.text
+        shown: root.internalVisibleCondition
+        horizontalPadding: root.horizontalPadding
+        verticalPadding: root.verticalPadding
+    }
+}
@@ -0,0 +1,48 @@
+import QtQuick
+import qs.Components
+import qs.Modules
+import qs.Config
+
+Item {
+    id: root
+    required property string text
+    property bool shown: false
+    property real horizontalPadding: 10
+    property real verticalPadding: 5
+    implicitWidth: tooltipTextObject.implicitWidth + 2 * root.horizontalPadding
+    implicitHeight: tooltipTextObject.implicitHeight + 2 * root.verticalPadding
+
+    property bool isVisible: backgroundRectangle.implicitHeight > 0
+
+    Rectangle {
+        id: backgroundRectangle
+        anchors {
+            bottom: root.bottom
+            horizontalCenter: root.horizontalCenter
+        }
+        color: DynamicColors.tPalette.m3inverseSurface ?? "#3C4043"
+        radius: 8
+        opacity: shown ? 1 : 0
+        implicitWidth: shown ? (tooltipTextObject.implicitWidth + 2 * root.horizontalPadding) : 0
+        implicitHeight: shown ? (tooltipTextObject.implicitHeight + 2 * root.verticalPadding) : 0
+        clip: true
+
+        Behavior on implicitWidth {
+            Anim {}
+        }
+        Behavior on implicitHeight {
+            Anim {}
+        }
+        Behavior on opacity {
+            Anim {}
+        }
+
+        CustomText {
+            id: tooltipTextObject
+            anchors.centerIn: parent
+            text: root.text
+            color: DynamicColors.palette.m3inverseOnSurface ?? "#FFFFFF"
+            wrapMode: Text.Wrap
+        }
+    }   
+}