feat: dashboard show on hover, media and weather tabs added

2026-09-30 14:22:22 +02:00
parent d259c6ffbe
commit 2c90339c77
97 changed files with 4480 additions and 990 deletions
@@ -0,0 +1,79 @@
+import QtQuick
+import QtQuick.Layouts
+import Quickshell
+import Quickshell.Services.Mpris
+import ZShell.Config
+import qs.Components
+import qs.Helpers
+import qs.Services
+
+Item {
+	ColumnLayout {
+		id: layout
+
+		anchors.fill: parent
+		anchors.leftMargin: Tokens.padding.medium
+		spacing: Tokens.spacing.medium
+
+		RowLayout {
+			Layout.bottomMargin: -Tokens.spacing.medium
+			spacing: Tokens.spacing.medium
+			z: 1
+
+			MaterialIcon {
+				Layout.topMargin: Math.round(fontInfo.pointSize * 0.12)
+				text: "lyrics"
+				font.pointSize: Tokens.font.size.large
+			}
+
+			CustomText {
+				Layout.fillWidth: true
+				text: qsTr("Lyrics")
+				font.pointSize: Tokens.font.size.large
+			}
+
+			LyricsInfo {}
+		}
+
+		LyricList {
+			Layout.fillWidth: true
+			Layout.fillHeight: true
+		}
+
+		SplitButton {
+			Layout.alignment: Qt.AlignHCenter
+
+			type: SplitButton.Tonal
+			enabled: Players.list.length
+			active: menuItems.find(m => m.modelData === Players.active) ?? menuItems[0] ?? null
+			menu.onItemSelected: item => Players.manualActive = (item as PlayerItem).modelData
+
+			menuItems: playerList.instances
+			fallbackIcon: "music_off"
+			fallbackText: qsTr("No players", "no media players active")
+
+			minLeftWidth: layout.width - expandBtn.implicitWidth - spacing
+			label.Layout.maximumWidth: minLeftWidth - iconLabel.implicitWidth - textRow.spacing - textRow.anchors.horizontalCenterOffset / 2 - horizontalPadding * 2
+			label.elide: Text.ElideRight
+
+			stateLayer.enabled: true
+			menuOnTop: true
+
+			Variants {
+				id: playerList
+
+				model: Players.list
+
+				PlayerItem {}
+			}
+		}
+	}
+
+	component PlayerItem: MenuItem {
+		required property MprisPlayer modelData
+
+		icon: modelData === Players.active ? "check" : ""
+		text: Players.getIdentity(modelData)
+		activeIcon: "animated_images"
+	}
+}