screenshot utility

2025-11-18 13:47:12 +01:00
parent 77800d1779
commit 5b069bf4c2
19 changed files with 1610 additions and 8 deletions
@@ -0,0 +1,69 @@
+pragma ComponentBehavior: Bound
+
+import Quickshell
+import Quickshell.Wayland
+import Quickshell.Io
+import Quickshell.Hyprland
+import ZShell
+
+Scope {
+    LazyLoader {
+        id: root
+
+        property bool freeze
+        property bool closing
+
+        Variants {
+            model: Quickshell.screens
+            PanelWindow {
+                id: win
+                color: "transparent"
+
+                required property ShellScreen modelData
+
+                screen: modelData
+                WlrLayershell.namespace: "areapicker"
+                WlrLayershell.exclusionMode: ExclusionMode.Ignore
+                WlrLayershell.layer: WlrLayer.Overlay
+                WlrLayershell.keyboardFocus: root.closing ? WlrKeyboardFocus.None : WlrKeyboardFocus.Exclusive
+                mask: root.closing ? empty : null
+
+                anchors {
+                    top: true
+                    bottom: true
+                    left: true
+                    right: true
+                }
+
+                Region {
+                    id: empty
+                }
+
+                Picker {
+                    loader: root
+                    screen: win.modelData
+                }
+            }
+        }
+    }
+
+    GlobalShortcut {
+        name: "screenshot"
+        appid: "ZShell"
+        onPressed: {
+            root.freeze = false;
+            root.closing = false;
+            root.activeAsync = true;
+        }
+    }
+
+    GlobalShortcut {
+        name: "screenshotFreeze"
+        appid: "ZShell"
+        onPressed: {
+            root.freeze = true;
+            root.closing = false;
+            root.activeAsync = true;
+        }
+    }
+}