feat: import M3Shapes, M3 loading indicator and weather + resources + media revamp in lockscreen

2026-07-08 22:53:19 +02:00
parent e3b2d33a11
commit 672cb07547
14 changed files with 733 additions and 439 deletions
@@ -0,0 +1,114 @@
+import QtQuick
+import Quickshell
+import M3Shapes
+import qs.Config
+
+MaterialShape {
+	id: root
+
+	property bool animated: true
+	property real cRotation
+	property bool containsIcon
+	property real dampingRatio: 0.6
+	property real lRotation
+	property int morphAnimRotation: 60
+	property real morphScale: 0.14
+	property alias rotateAnimDuration: rotateAnim.duration
+	property int shapeIndex
+	property list<int> shapes: {
+		if (containsIcon)
+			return [MaterialShape.SoftBurst, MaterialShape.Cookie9Sided, MaterialShape.Pill, MaterialShape.Sunny, MaterialShape.Cookie4Sided, MaterialShape.Oval];
+		return [MaterialShape.SoftBurst, MaterialShape.Cookie9Sided, MaterialShape.Pentagon, MaterialShape.Pill, MaterialShape.Sunny, MaterialShape.Cookie4Sided, MaterialShape.Oval];
+	}
+	readonly property real springDuration: {
+		const wn = Math.sqrt(stiffness);
+		const r = -dampingRatio * wn;
+		const c = 1 / Math.sqrt(1 - dampingRatio * dampingRatio);
+		return Math.log(visibilityThreshold / c) / r;
+	}
+	readonly property real springMaxVelocity: {
+		const wn = Math.sqrt(stiffness);
+		const factor = Math.exp(-z * Math.acos(z) / Math.sqrt(1 - z * z));
+		return wn * factor;
+	}
+	property bool springSettled: true
+	property real stiffness: 180
+	property real thisLRotation
+	property real visibilityThreshold: 0.075
+
+	function spring(t: real): var {
+		const wn = Math.sqrt(stiffness);
+		const za = dampingRatio * wn;
+
+		const wd = wn * Math.sqrt(1 - dampingRatio * dampingRatio);
+		const r = za / wd;
+		const pos = 1 - Math.exp(-za * t) * (Math.cos(wd * t) + r * Math.sin(wd * t));
+		const vel = Math.exp(-za * t) * (wn * wn / wd) * Math.sin(wd * t);
+
+		return [pos, vel];
+	}
+
+	color: DynamicColors.palette.m3primary
+	implicitSize: 38
+	toShape: shapes[0]
+
+	RotationAnimation on cRotation {
+		id: rotateAnim
+
+		duration: 4666
+		easing.type: Easing.Linear
+		from: 0
+		loops: Animation.Infinite
+		running: root.animated
+		to: 360
+	}
+	Behavior on color {
+		CAnim {
+		}
+	}
+
+	ElapsedTimer {
+		id: timer
+	}
+
+	FrameAnimation {
+		running: root.animated && !root.springSettled
+
+		onTriggered: {
+			const t = timer.elapsed();
+
+			if (t >= root.springDuration) {
+				root.springSettled = true;
+			} else {
+				const [pos, vel] = root.spring(t);
+				root.morphProgress = Math.min(1, pos); // Overshooting the morph looks weird
+				root.thisLRotation = pos * root.morphAnimRotation;
+				root.scale = 1 + vel * root.morphScale / root.springMaxVelocity;
+			}
+		}
+	}
+
+	Timer {
+		interval: 650
+		repeat: true
+		running: root.animated
+		triggeredOnStart: true
+
+		onTriggered: {
+			root.beginBatchUpdate();
+			root.fromShape = root.toShape;
+			root.shapeIndex = (root.shapeIndex + 1) % root.shapes.length;
+			root.toShape = root.shapes[root.shapeIndex];
+			root.morphProgress = 0;
+
+			root.rotation = root.rotation;
+			root.lRotation = (root.lRotation + root.thisLRotation) % 360;
+			root.thisLRotation = 0;
+			root.rotation = Qt.binding(() => root.cRotation + root.lRotation + root.thisLRotation);
+
+			root.springSettled = false;
+			timer.restart();
+			root.endBatchUpdate();
+		}
+	}
+}
@@ -6,25 +6,55 @@ import qs.Effects
 CustomListView {
 	id: root

-	property real bottomFadeOpacity: fadeShouldBeActive(false) ? 0 : 1
+	property real endFadeOpacity: fadeShouldBeActive(false) ? 0 : 1
 	property real fadeAmount: 0.1
-	property real topFadeOpacity: fadeShouldBeActive(true) ? 0 : 1
+	readonly property bool horizontal: orientation === ListView.Horizontal
+	property real startFadeOpacity: fadeShouldBeActive(true) ? 0 : 1

-	function fadeShouldBeActive(isStart: bool): bool {
-		// When content is smaller than flickable size, hide fade when rebound starts
-		if (contentHeight + topMargin + bottomMargin < height && rebound.running && ((isStart ? verticalOvershoot > 0 : verticalOvershoot < 0)))
-			return false;
-
-		if (isStart)
-			return visibleArea.yPosition > 0;
-		return visibleArea.yPosition + visibleArea.heightRatio < 1;
+	function contentSize(): real {
+		return horizontal ? contentWidth : contentHeight;
 	}

-	flickableDirection: Flickable.VerticalFlick
-	layer.enabled: true
-	orientation: ListView.Vertical
+	function fadeShouldBeActive(isStart: bool): bool {
+		// When content is smaller than flickable size, hide fade when rebound starts.
+		if (contentSize() + marginStart() + marginEnd() < viewportSize() && rebound.running && ((isStart ? overshootStart() > 0 : overshootStart() < 0))) {
+			return false;
+		}

-	Behavior on bottomFadeOpacity {
+		if (isStart)
+			return visibleStart() > 0;
+
+		return visibleStart() + visibleRatio() < 1;
+	}
+
+	function marginEnd(): real {
+		return horizontal ? rightMargin : bottomMargin;
+	}
+
+	function marginStart(): real {
+		return horizontal ? leftMargin : topMargin;
+	}
+
+	function overshootStart(): real {
+		return horizontal ? horizontalOvershoot : verticalOvershoot;
+	}
+
+	function viewportSize(): real {
+		return horizontal ? width : height;
+	}
+
+	function visibleRatio(): real {
+		return horizontal ? visibleArea.widthRatio : visibleArea.heightRatio;
+	}
+
+	function visibleStart(): real {
+		return horizontal ? visibleArea.xPosition : visibleArea.yPosition;
+	}
+
+	flickableDirection: horizontal ? Flickable.HorizontalFlick : Flickable.VerticalFlick
+	layer.enabled: true
+
+	Behavior on endFadeOpacity {
 		Anim {
 			type: Anim.SlowEffects
 		}
@@ -40,10 +70,10 @@ CustomListView {
 			visible: false

 			gradient: Gradient {
-				orientation: Gradient.Vertical
+				orientation: root.horizontal ? Gradient.Horizontal : Gradient.Vertical

 				GradientStop {
-					color: Qt.rgba(0, 0, 0, root.topFadeOpacity)
+					color: Qt.rgba(0, 0, 0, root.startFadeOpacity)
 					position: 0
 				}

@@ -58,13 +88,13 @@ CustomListView {
 				}

 				GradientStop {
-					color: Qt.rgba(0, 0, 0, root.bottomFadeOpacity)
+					color: Qt.rgba(0, 0, 0, root.endFadeOpacity)
 					position: 1
 				}
 			}
 		}
 	}
-	Behavior on topFadeOpacity {
+	Behavior on startFadeOpacity {
 		Anim {
 			type: Anim.SlowEffects
 		}
@@ -0,0 +1,46 @@
+import QtQuick
+import QtQuick.Shapes
+import qs.Config
+
+Shape {
+	id: root
+
+	property real amplitude: 3
+	property color color: DynamicColors.palette.m3surfaceContainer
+	readonly property real waveHeight: amplitude * 2
+	property int waves: 4
+
+	asynchronous: true
+	preferredRendererType: Shape.CurveRenderer
+
+	ShapePath {
+		fillColor: root.color
+		strokeColor: "transparent"
+		strokeWidth: 0
+
+		Behavior on fillColor {
+			CAnim {
+			}
+		}
+
+		PathSvg {
+			path: {
+				const w = root.width;
+				const h = root.height;
+				const a = root.amplitude;
+				const n = Math.max(1, root.waves);
+				const wl = w / n;
+				const half = wl / 2;
+
+				let d = `M 0,${a} `;
+				for (let i = 0; i < n; ++i) {
+					const x = i * wl;
+					d += `Q ${x + half / 2},${-a} ${x + half},${a} `;
+					d += `Q ${x + half + half / 2},${3 * a} ${x + wl},${a} `;
+				}
+				d += `L ${w},${h} L 0,${h} Z`;
+				return d;
+			}
+		}
+	}
+}