greeter test

Greeter/Components/Anim.qml

@@ -0,0 +1,8 @@
+import QtQuick
+import qs.Config
+
+NumberAnimation {
+	duration: MaterialEasing.standardTime
+	easing.bezierCurve: MaterialEasing.standard
+	easing.type: Easing.BezierSpline
+}

Greeter/Components/AnimatedTabIndexPair.qml

@@ -0,0 +1,24 @@
+import QtQuick
+
+QtObject {
+	id: root
+
+	property real idx1: index
+	property int idx1Duration: 100
+	property real idx2: index
+	property int idx2Duration: 300
+	required property int index
+
+	Behavior on idx1 {
+		NumberAnimation {
+			duration: root.idx1Duration
+			easing.type: Easing.OutSine
+		}
+	}
+	Behavior on idx2 {
+		NumberAnimation {
+			duration: root.idx2Duration
+			easing.type: Easing.OutSine
+		}
+	}
+}

Greeter/Components/BaseStyledSlider.qml

@@ -0,0 +1,165 @@
+import QtQuick
+import QtQuick.Templates
+import qs.Config
+
+Slider {
+	id: root
+
+	property color color: DynamicColors.palette.m3secondary
+	required property string icon
+	property bool initialized: false
+	readonly property bool isHorizontal: orientation === Qt.Horizontal
+	readonly property bool isVertical: orientation === Qt.Vertical
+	property real multiplier: 100
+	property real oldValue
+
+	// Wrapper components can inject their own track visuals here.
+	property Component trackContent
+
+	// Keep current behavior for existing usages.
+	orientation: Qt.Vertical
+
+	background: CustomRect {
+		id: groove
+
+		color: DynamicColors.layer(DynamicColors.palette.m3surfaceContainer, 2)
+		height: root.availableHeight
+		radius: Appearance.rounding.full
+		width: root.availableWidth
+		x: root.leftPadding
+		y: root.topPadding
+
+		Loader {
+			id: trackLoader
+
+			anchors.fill: parent
+			sourceComponent: root.trackContent
+
+			onLoaded: {
+				if (!item)
+					return;
+
+				item.rootSlider = root;
+				item.groove = groove;
+				item.handleItem = handle;
+			}
+		}
+	}
+	handle: Item {
+		id: handle
+
+		property alias moving: icon.moving
+
+		implicitHeight: Math.min(root.width, root.height)
+		implicitWidth: Math.min(root.width, root.height)
+		x: root.isHorizontal ? root.leftPadding + root.visualPosition * (root.availableWidth - width) : root.leftPadding + (root.availableWidth - width) / 2
+		y: root.isVertical ? root.topPadding + root.visualPosition * (root.availableHeight - height) : root.topPadding + (root.availableHeight - height) / 2
+
+		Elevation {
+			anchors.fill: parent
+			level: handleInteraction.containsMouse ? 2 : 1
+			radius: rect.radius
+		}
+
+		CustomRect {
+			id: rect
+
+			anchors.fill: parent
+			color: DynamicColors.palette.m3inverseSurface
+			radius: Appearance.rounding.full
+
+			MouseArea {
+				id: handleInteraction
+
+				acceptedButtons: Qt.NoButton
+				anchors.fill: parent
+				cursorShape: Qt.PointingHandCursor
+				hoverEnabled: true
+			}
+
+			MaterialIcon {
+				id: icon
+
+				property bool moving
+
+				function update(): void {
+					animate = !moving;
+					binding.when = moving;
+					font.pointSize = moving ? Appearance.font.size.small : Appearance.font.size.larger;
+					font.family = moving ? Appearance.font.family.sans : Appearance.font.family.material;
+				}
+
+				anchors.centerIn: parent
+				color: DynamicColors.palette.m3inverseOnSurface
+				text: root.icon
+
+				onMovingChanged: anim.restart()
+
+				Binding {
+					id: binding
+
+					property: "text"
+					target: icon
+					value: Math.round(root.value * root.multiplier)
+					when: false
+				}
+
+				SequentialAnimation {
+					id: anim
+
+					Anim {
+						duration: Appearance.anim.durations.normal / 2
+						easing.bezierCurve: Appearance.anim.curves.standardAccel
+						property: "scale"
+						target: icon
+						to: 0
+					}
+
+					ScriptAction {
+						script: icon.update()
+					}
+
+					Anim {
+						duration: Appearance.anim.durations.normal / 2
+						easing.bezierCurve: Appearance.anim.curves.standardDecel
+						property: "scale"
+						target: icon
+						to: 1
+					}
+				}
+			}
+		}
+	}
+	Behavior on value {
+		Anim {
+			duration: Appearance.anim.durations.large
+		}
+	}
+
+	onPressedChanged: handle.moving = pressed
+	onValueChanged: {
+		if (!initialized) {
+			initialized = true;
+			oldValue = value;
+			return;
+		}
+
+		if (Math.abs(value - oldValue) < 0.01)
+			return;
+
+		oldValue = value;
+		handle.moving = true;
+		stateChangeDelay.restart();
+	}
+
+	Timer {
+		id: stateChangeDelay
+
+		interval: 500
+
+		onTriggered: {
+			if (!root.pressed)
+				handle.moving = false;
+		}
+	}
+}

Greeter/Components/CAnim.qml

@@ -0,0 +1,8 @@
+import QtQuick
+import qs.Config
+
+ColorAnimation {
+	duration: MaterialEasing.standardTime
+	easing.bezierCurve: MaterialEasing.standard
+	easing.type: Easing.BezierSpline
+}

Greeter/Components/CircularIndicator.qml

@@ -0,0 +1,102 @@
+import qs.Config
+import ZShell.Internal
+import QtQuick
+import QtQuick.Templates
+
+BusyIndicator {
+	id: root
+
+	enum AnimState {
+		Stopped,
+		Running,
+		Completing
+	}
+	enum AnimType {
+		Advance = 0,
+		Retreat
+	}
+
+	property int animState
+	property color bgColour: DynamicColors.palette.m3secondaryContainer
+	property color fgColour: DynamicColors.palette.m3primary
+	property real implicitSize: Appearance.font.size.normal * 3
+	property real internalStrokeWidth: strokeWidth
+	readonly property alias progress: manager.progress
+	property real strokeWidth: Appearance.padding.small * 0.8
+	property alias type: manager.indeterminateAnimationType
+
+	implicitHeight: implicitSize
+	implicitWidth: implicitSize
+	padding: 0
+
+	contentItem: CircularProgress {
+		anchors.fill: parent
+		bgColour: root.bgColour
+		fgColour: root.fgColour
+		padding: root.padding
+		rotation: manager.rotation
+		startAngle: manager.startFraction * 360
+		strokeWidth: root.internalStrokeWidth
+		value: manager.endFraction - manager.startFraction
+	}
+	states: State {
+		name: "stopped"
+		when: !root.running
+
+		PropertyChanges {
+			root.internalStrokeWidth: root.strokeWidth / 3
+			root.opacity: 0
+		}
+	}
+	transitions: Transition {
+		Anim {
+			duration: manager.completeEndDuration * Appearance.anim.durations.scale
+			properties: "opacity,internalStrokeWidth"
+		}
+	}
+
+	Component.onCompleted: {
+		if (running) {
+			running = false;
+			running = true;
+		}
+	}
+	onRunningChanged: {
+		if (running) {
+			manager.completeEndProgress = 0;
+			animState = CircularIndicator.Running;
+		} else {
+			if (animState == CircularIndicator.Running)
+				animState = CircularIndicator.Completing;
+		}
+	}
+
+	CircularIndicatorManager {
+		id: manager
+
+	}
+
+	NumberAnimation {
+		duration: manager.duration * Appearance.anim.durations.scale
+		from: 0
+		loops: Animation.Infinite
+		property: "progress"
+		running: root.animState !== CircularIndicator.Stopped
+		target: manager
+		to: 1
+	}
+
+	NumberAnimation {
+		duration: manager.completeEndDuration * Appearance.anim.durations.scale
+		from: 0
+		property: "completeEndProgress"
+		running: root.animState === CircularIndicator.Completing
+		target: manager
+		to: 1
+
+		onFinished: {
+			if (root.animState === CircularIndicator.Completing)
+				root.animState = CircularIndicator.Stopped;
+		}
+	}
+}

Greeter/Components/CircularProgress.qml

@@ -0,0 +1,66 @@
+import QtQuick
+import QtQuick.Shapes
+import qs.Config
+
+Shape {
+	id: root
+
+	readonly property real arcRadius: (size - padding - strokeWidth) / 2
+	property color bgColour: DynamicColors.palette.m3secondaryContainer
+	property color fgColour: DynamicColors.palette.m3primary
+	readonly property real gapAngle: ((spacing + strokeWidth) / (arcRadius || 1)) * (180 / Math.PI)
+	property int padding: 0
+	readonly property real size: Math.min(width, height)
+	property int spacing: Appearance.spacing.small
+	property int startAngle: -90
+	property int strokeWidth: Appearance.padding.smaller
+	readonly property real vValue: value || 1 / 360
+	property real value
+
+	asynchronous: true
+	preferredRendererType: Shape.CurveRenderer
+
+	ShapePath {
+		capStyle: Appearance.rounding.scale === 0 ? ShapePath.SquareCap : ShapePath.RoundCap
+		fillColor: "transparent"
+		strokeColor: root.bgColour
+		strokeWidth: root.strokeWidth
+
+		Behavior on strokeColor {
+			CAnim {
+				duration: Appearance.anim.durations.large
+			}
+		}
+
+		PathAngleArc {
+			centerX: root.size / 2
+			centerY: root.size / 2
+			radiusX: root.arcRadius
+			radiusY: root.arcRadius
+			startAngle: root.startAngle + 360 * root.vValue + root.gapAngle
+			sweepAngle: Math.max(-root.gapAngle, 360 * (1 - root.vValue) - root.gapAngle * 2)
+		}
+	}
+
+	ShapePath {
+		capStyle: Appearance.rounding.scale === 0 ? ShapePath.SquareCap : ShapePath.RoundCap
+		fillColor: "transparent"
+		strokeColor: root.fgColour
+		strokeWidth: root.strokeWidth
+
+		Behavior on strokeColor {
+			CAnim {
+				duration: Appearance.anim.durations.large
+			}
+		}
+
+		PathAngleArc {
+			centerX: root.size / 2
+			centerY: root.size / 2
+			radiusX: root.arcRadius
+			radiusY: root.arcRadius
+			startAngle: root.startAngle
+			sweepAngle: 360 * root.vValue
+		}
+	}
+}

Greeter/Components/CollapsibleSection.qml

@@ -0,0 +1,135 @@
+import QtQuick
+import QtQuick.Layouts
+import qs.Config
+
+ColumnLayout {
+	id: root
+
+	default property alias content: contentColumn.data
+	property string description: ""
+	property bool expanded: false
+	property bool nested: false
+	property bool showBackground: false
+	required property string title
+
+	signal toggleRequested
+
+	Layout.fillWidth: true
+	spacing: Appearance.spacing.small
+
+	Item {
+		id: sectionHeaderItem
+
+		Layout.fillWidth: true
+		Layout.preferredHeight: Math.max(titleRow.implicitHeight + Appearance.padding.normal * 2, 48)
+
+		RowLayout {
+			id: titleRow
+
+			anchors.left: parent.left
+			anchors.leftMargin: Appearance.padding.normal
+			anchors.right: parent.right
+			anchors.rightMargin: Appearance.padding.normal
+			anchors.verticalCenter: parent.verticalCenter
+			spacing: Appearance.spacing.normal
+
+			CustomText {
+				font.pointSize: Appearance.font.size.larger
+				font.weight: 500
+				text: root.title
+			}
+
+			Item {
+				Layout.fillWidth: true
+			}
+
+			MaterialIcon {
+				color: DynamicColors.palette.m3onSurfaceVariant
+				font.pointSize: Appearance.font.size.normal
+				rotation: root.expanded ? 180 : 0
+				text: "expand_more"
+
+				Behavior on rotation {
+					Anim {
+						duration: Appearance.anim.durations.small
+						easing.bezierCurve: Appearance.anim.curves.standard
+					}
+				}
+			}
+		}
+
+		StateLayer {
+			function onClicked(): void {
+				root.toggleRequested();
+				root.expanded = !root.expanded;
+			}
+
+			anchors.fill: parent
+			color: DynamicColors.palette.m3onSurface
+			radius: Appearance.rounding.normal
+			showHoverBackground: false
+		}
+	}
+
+	Item {
+		id: contentWrapper
+
+		Layout.fillWidth: true
+		Layout.preferredHeight: root.expanded ? (contentColumn.implicitHeight + Appearance.spacing.small * 2) : 0
+		clip: true
+
+		Behavior on Layout.preferredHeight {
+			Anim {
+				easing.bezierCurve: Appearance.anim.curves.standard
+			}
+		}
+
+		CustomRect {
+			id: backgroundRect
+
+			anchors.fill: parent
+			color: DynamicColors.transparency.enabled ? DynamicColors.layer(DynamicColors.palette.m3surfaceContainer, root.nested ? 3 : 2) : (root.nested ? DynamicColors.palette.m3surfaceContainerHigh : DynamicColors.palette.m3surfaceContainer)
+			opacity: root.showBackground && root.expanded ? 1.0 : 0.0
+			radius: Appearance.rounding.normal
+			visible: root.showBackground
+
+			Behavior on opacity {
+				Anim {
+					easing.bezierCurve: Appearance.anim.curves.standard
+				}
+			}
+		}
+
+		ColumnLayout {
+			id: contentColumn
+
+			anchors.bottomMargin: Appearance.spacing.small
+			anchors.left: parent.left
+			anchors.leftMargin: Appearance.padding.normal
+			anchors.right: parent.right
+			anchors.rightMargin: Appearance.padding.normal
+			opacity: root.expanded ? 1.0 : 0.0
+			spacing: Appearance.spacing.small
+			y: Appearance.spacing.small
+
+			Behavior on opacity {
+				Anim {
+					easing.bezierCurve: Appearance.anim.curves.standard
+				}
+			}
+
+			CustomText {
+				id: descriptionText
+
+				Layout.bottomMargin: root.description !== "" ? Appearance.spacing.small : 0
+				Layout.fillWidth: true
+				Layout.topMargin: root.description !== "" ? Appearance.spacing.smaller : 0
+				color: DynamicColors.palette.m3onSurfaceVariant
+				font.pointSize: Appearance.font.size.small
+				text: root.description
+				visible: root.description !== ""
+				wrapMode: Text.Wrap
+			}
+		}
+	}
+}

Greeter/Components/ColorArcPicker.qml

@@ -0,0 +1,208 @@
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import qs.Config
+
+Item {
+	id: root
+
+	readonly property real arcStartAngle: 0.75 * Math.PI
+	readonly property real arcSweep: 1.5 * Math.PI
+	property real currentHue: 0
+	property bool dragActive: false
+	required property var drawing
+	readonly property real handleAngle: hueToAngle(currentHue)
+	readonly property real handleCenterX: width / 2 + radius * Math.cos(handleAngle)
+	readonly property real handleCenterY: height / 2 + radius * Math.sin(handleAngle)
+	property real handleSize: 32
+	property real lastChromaticHue: 0
+	readonly property real radius: (Math.min(width, height) - handleSize) / 2
+	readonly property int segmentCount: 240
+	readonly property color thumbColor: DynamicColors.palette.m3inverseSurface
+	readonly property color thumbContentColor: DynamicColors.palette.m3inverseOnSurface
+	readonly property color trackColor: DynamicColors.layer(DynamicColors.palette.m3surfaceContainer, 2)
+
+	function hueToAngle(hue) {
+		return arcStartAngle + arcSweep * hue;
+	}
+
+	function normalizeAngle(angle) {
+		const tau = Math.PI * 2;
+		let a = angle % tau;
+		if (a < 0)
+			a += tau;
+		return a;
+	}
+
+	function pointIsOnTrack(x, y) {
+		const cx = width / 2;
+		const cy = height / 2;
+		const dx = x - cx;
+		const dy = y - cy;
+		const distance = Math.sqrt(dx * dx + dy * dy);
+
+		return distance >= radius - handleSize / 2 && distance <= radius + handleSize / 2;
+	}
+
+	function syncFromPenColor() {
+		if (!drawing)
+			return;
+
+		const c = drawing.penColor;
+
+		if (c.hsvSaturation > 0) {
+			currentHue = c.hsvHue;
+			lastChromaticHue = c.hsvHue;
+		} else {
+			currentHue = lastChromaticHue;
+		}
+
+		canvas.requestPaint();
+	}
+
+	function updateHueFromPoint(x, y, force = false) {
+		const cx = width / 2;
+		const cy = height / 2;
+		const dx = x - cx;
+		const dy = y - cy;
+
+		const distance = Math.sqrt(dx * dx + dy * dy);
+
+		if (!force && (distance < radius - handleSize / 2 || distance > radius + handleSize / 2))
+			return;
+
+		const angle = normalizeAngle(Math.atan2(dy, dx));
+		const start = normalizeAngle(arcStartAngle);
+
+		let relative = angle - start;
+		if (relative < 0)
+			relative += Math.PI * 2;
+
+		if (relative > arcSweep) {
+			const gap = Math.PI * 2 - arcSweep;
+			relative = relative < arcSweep + gap / 2 ? arcSweep : 0;
+		}
+
+		currentHue = relative / arcSweep;
+		lastChromaticHue = currentHue;
+		drawing.penColor = Qt.hsva(currentHue, drawing.penColor.hsvSaturation, drawing.penColor.hsvValue, drawing.penColor.a);
+	}
+
+	implicitHeight: 180
+	implicitWidth: 220
+
+	Component.onCompleted: syncFromPenColor()
+	onCurrentHueChanged: canvas.requestPaint()
+	onDrawingChanged: syncFromPenColor()
+	onHandleSizeChanged: canvas.requestPaint()
+	onHeightChanged: canvas.requestPaint()
+	onWidthChanged: canvas.requestPaint()
+
+	Connections {
+		function onPenColorChanged() {
+			root.syncFromPenColor();
+		}
+
+		target: root.drawing
+	}
+
+	Canvas {
+		id: canvas
+
+		anchors.fill: parent
+		renderStrategy: Canvas.Threaded
+		renderTarget: Canvas.Image
+
+		Component.onCompleted: requestPaint()
+		onPaint: {
+			const ctx = getContext("2d");
+			ctx.reset();
+			ctx.clearRect(0, 0, width, height);
+
+			const cx = width / 2;
+			const cy = height / 2;
+			const radius = root.radius;
+			const trackWidth = root.handleSize;
+
+			// Background track: always show the full hue spectrum
+			for (let i = 0; i < root.segmentCount; ++i) {
+				const t1 = i / root.segmentCount;
+				const t2 = (i + 1) / root.segmentCount;
+				const a1 = root.arcStartAngle + root.arcSweep * t1;
+				const a2 = root.arcStartAngle + root.arcSweep * t2;
+
+				ctx.beginPath();
+				ctx.arc(cx, cy, radius, a1, a2);
+				ctx.lineWidth = trackWidth;
+				ctx.lineCap = "round";
+				ctx.strokeStyle = Qt.hsla(t1, 1.0, 0.5, 1.0);
+				ctx.stroke();
+			}
+		}
+	}
+
+	Item {
+		id: handle
+
+		height: root.handleSize
+		width: root.handleSize
+		x: root.handleCenterX - width / 2
+		y: root.handleCenterY - height / 2
+		z: 1
+
+		Elevation {
+			anchors.fill: parent
+			level: handleHover.containsMouse ? 2 : 1
+			radius: rect.radius
+		}
+
+		Rectangle {
+			id: rect
+
+			anchors.fill: parent
+			color: root.thumbColor
+			radius: width / 2
+
+			MouseArea {
+				id: handleHover
+
+				acceptedButtons: Qt.NoButton
+				anchors.fill: parent
+				cursorShape: Qt.PointingHandCursor
+				hoverEnabled: true
+			}
+
+			Rectangle {
+				anchors.centerIn: parent
+				color: root.drawing ? root.drawing.penColor : Qt.hsla(root.currentHue, 1.0, 0.5, 1.0)
+				height: width
+				radius: width / 2
+				width: parent.width - 12
+			}
+		}
+	}
+
+	MouseArea {
+		id: dragArea
+
+		acceptedButtons: Qt.LeftButton
+		anchors.fill: parent
+		hoverEnabled: true
+
+		onCanceled: {
+			root.dragActive = false;
+		}
+		onPositionChanged: mouse => {
+			if ((mouse.buttons & Qt.LeftButton) && root.dragActive)
+				root.updateHueFromPoint(mouse.x, mouse.y, true);
+		}
+		onPressed: mouse => {
+			root.dragActive = root.pointIsOnTrack(mouse.x, mouse.y);
+			if (root.dragActive)
+				root.updateHueFromPoint(mouse.x, mouse.y);
+		}
+		onReleased: {
+			root.dragActive = false;
+		}
+	}
+}

Greeter/Components/ColoredIcon.qml

@@ -0,0 +1,34 @@
+pragma ComponentBehavior: Bound
+
+import ZShell
+import Quickshell.Widgets
+import QtQuick
+
+IconImage {
+	id: root
+
+	required property color color
+
+	asynchronous: true
+	layer.enabled: true
+
+	layer.effect: Coloriser {
+		colorizationColor: root.color
+		sourceColor: analyser.dominantColour
+	}
+
+	layer.onEnabledChanged: {
+		if (layer.enabled && status === Image.Ready)
+			analyser.requestUpdate();
+	}
+	onStatusChanged: {
+		if (layer.enabled && status === Image.Ready)
+			analyser.requestUpdate();
+	}
+
+	ImageAnalyser {
+		id: analyser
+
+		sourceItem: root
+	}
+}

Greeter/Components/Coloriser.qml

@@ -0,0 +1,14 @@
+import QtQuick
+import QtQuick.Effects
+
+MultiEffect {
+	property color sourceColor: "black"
+
+	brightness: 1 - sourceColor.hslLightness
+	colorization: 1
+
+	Behavior on colorizationColor {
+		CAnim {
+		}
+	}
+}

Greeter/Components/CustomAudioSlider.qml

@@ -0,0 +1,70 @@
+import QtQuick
+import QtQuick.Templates
+import qs.Config
+
+Slider {
+	id: root
+
+	property color nonPeakColor: DynamicColors.tPalette.m3primary
+	required property real peak
+	property color peakColor: DynamicColors.palette.m3primary
+
+	background: Item {
+		CustomRect {
+			anchors.bottom: parent.bottom
+			anchors.bottomMargin: root.implicitHeight / 3
+			anchors.left: parent.left
+			anchors.top: parent.top
+			anchors.topMargin: root.implicitHeight / 3
+			bottomRightRadius: root.implicitHeight / 15
+			color: root.nonPeakColor
+			implicitWidth: root.handle.x - root.implicitHeight
+			radius: 1000
+			topRightRadius: root.implicitHeight / 15
+
+			CustomRect {
+				anchors.bottom: parent.bottom
+				anchors.left: parent.left
+				anchors.top: parent.top
+				bottomRightRadius: root.implicitHeight / 15
+				color: root.peakColor
+				implicitWidth: parent.width * root.peak
+				radius: 1000
+				topRightRadius: root.implicitHeight / 15
+
+				Behavior on implicitWidth {
+					Anim {
+						duration: 50
+					}
+				}
+			}
+		}
+
+		CustomRect {
+			anchors.bottom: parent.bottom
+			anchors.bottomMargin: root.implicitHeight / 3
+			anchors.right: parent.right
+			anchors.top: parent.top
+			anchors.topMargin: root.implicitHeight / 3
+			bottomLeftRadius: root.implicitHeight / 15
+			color: DynamicColors.tPalette.m3surfaceContainer
+			implicitWidth: root.implicitWidth - root.handle.x - root.handle.implicitWidth - root.implicitHeight
+			radius: 1000
+			topLeftRadius: root.implicitHeight / 15
+		}
+	}
+	handle: CustomRect {
+		anchors.verticalCenter: parent.verticalCenter
+		color: DynamicColors.palette.m3primary
+		implicitHeight: 15
+		implicitWidth: 5
+		radius: 1000
+		x: root.visualPosition * root.availableWidth - implicitWidth / 2
+
+		MouseArea {
+			acceptedButtons: Qt.NoButton
+			anchors.fill: parent
+			cursorShape: Qt.PointingHandCursor
+		}
+	}
+}

Greeter/Components/CustomBusyIndicator.qml

@@ -0,0 +1,69 @@
+import QtQuick
+import QtQuick.Controls.Basic
+
+BusyIndicator {
+	id: control
+
+	property int busySize: 64
+	property color color: delegate.color
+
+	contentItem: Item {
+		implicitHeight: control.busySize
+		implicitWidth: control.busySize
+
+		Item {
+			id: item
+
+			height: control.busySize
+			opacity: control.running ? 1 : 0
+			width: control.busySize
+			x: parent.width / 2 - (control.busySize / 2)
+			y: parent.height / 2 - (control.busySize / 2)
+
+			Behavior on opacity {
+				OpacityAnimator {
+					duration: 250
+				}
+			}
+
+			RotationAnimator {
+				duration: 1250
+				from: 0
+				loops: Animation.Infinite
+				running: control.visible && control.running
+				target: item
+				to: 360
+			}
+
+			Repeater {
+				id: repeater
+
+				model: 6
+
+				CustomRect {
+					id: delegate
+
+					required property int index
+
+					color: control.color
+					implicitHeight: 10
+					implicitWidth: 10
+					radius: 5
+					x: item.width / 2 - width / 2
+					y: item.height / 2 - height / 2
+
+					transform: [
+						Translate {
+							y: -Math.min(item.width, item.height) * 0.5 + 5
+						},
+						Rotation {
+							angle: delegate.index / repeater.count * 360
+							origin.x: 5
+							origin.y: 5
+						}
+					]
+				}
+			}
+		}
+	}
+}

Greeter/Components/CustomButton.qml

@@ -0,0 +1,32 @@
+import QtQuick
+import QtQuick.Controls
+import qs.Config
+
+Button {
+	id: control
+
+	property color bgColor: DynamicColors.palette.m3primary
+	property int radius: 4
+	property color textColor: DynamicColors.palette.m3onPrimary
+
+	background: CustomRect {
+		color: control.bgColor
+		opacity: control.enabled ? 1.0 : 0.5
+		radius: control.radius
+	}
+	contentItem: CustomText {
+		color: control.textColor
+		horizontalAlignment: Text.AlignHCenter
+		opacity: control.enabled ? 1.0 : 0.5
+		text: control.text
+		verticalAlignment: Text.AlignVCenter
+	}
+
+	StateLayer {
+		function onClicked(): void {
+			control.clicked();
+		}
+
+		radius: control.radius
+	}
+}

Greeter/Components/CustomCheckbox.qml

@@ -0,0 +1,37 @@
+import QtQuick
+import QtQuick.Controls
+import qs.Config
+
+CheckBox {
+	id: control
+
+	property int checkHeight: 20
+	property int checkWidth: 20
+
+	contentItem: CustomText {
+		anchors.left: parent.left
+		anchors.leftMargin: control.checkWidth + control.leftPadding + 8
+		anchors.verticalCenter: parent.verticalCenter
+		font.pointSize: control.font.pointSize
+		text: control.text
+	}
+	indicator: CustomRect {
+		// x: control.leftPadding
+		// y: parent.implicitHeight / 2 - implicitHeight / 2
+		border.color: control.checked ? DynamicColors.palette.m3primary : "transparent"
+		color: DynamicColors.palette.m3surfaceVariant
+		implicitHeight: control.checkHeight
+		implicitWidth: control.checkWidth
+		radius: 4
+
+		CustomRect {
+			color: DynamicColors.palette.m3primary
+			implicitHeight: control.checkHeight - (y * 2)
+			implicitWidth: control.checkWidth - (x * 2)
+			radius: 3
+			visible: control.checked
+			x: 4
+			y: 4
+		}
+	}
+}

Greeter/Components/CustomClippingRect.qml

@@ -0,0 +1,13 @@
+import Quickshell.Widgets
+import QtQuick
+
+ClippingRectangle {
+	id: root
+
+	color: "transparent"
+
+	Behavior on color {
+		CAnim {
+		}
+	}
+}

Greeter/Components/CustomComboBox.qml

@@ -0,0 +1,169 @@
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import QtQuick.Layouts
+import QtQuick.Controls
+import qs.Config
+
+ComboBox {
+	id: root
+
+	property int cornerRadius: Appearance.rounding.normal
+	property int fieldHeight: 42
+	property bool filled: true
+	property real focusRingOpacity: 0.70
+	property int hPadding: 16
+	property int menuCornerRadius: 16
+	property int menuRowHeight: 46
+	property int menuVisibleRows: 7
+	property bool preferPopupWindow: false
+
+	hoverEnabled: true
+	implicitHeight: fieldHeight
+	implicitWidth: 240
+	spacing: 8
+
+	// ---------- Field background (filled/outlined + state layers + focus ring) ----------
+	background: Item {
+		anchors.fill: parent
+
+		CustomRect {
+			id: container
+
+			anchors.fill: parent
+			color: DynamicColors.palette.m3surfaceVariant
+			radius: root.cornerRadius
+
+			StateLayer {
+			}
+		}
+	}
+
+	// ---------- Content ----------
+	contentItem: RowLayout {
+		anchors.fill: parent
+		anchors.leftMargin: root.hPadding
+		anchors.rightMargin: root.hPadding
+		spacing: 12
+
+		// Display text
+		CustomText {
+			Layout.fillWidth: true
+			color: root.enabled ? DynamicColors.palette.m3onSurface : DynamicColors.palette.m3onSurfaceVariant
+			elide: Text.ElideRight
+			font.pixelSize: 16
+			font.weight: Font.Medium
+			text: root.currentText
+			verticalAlignment: Text.AlignVCenter
+		}
+
+		// Indicator chevron (simple, replace with your icon system)
+		CustomText {
+			color: root.enabled ? DynamicColors.palette.m3onSurfaceVariant : DynamicColors.palette.m3onSurfaceVariant
+			rotation: root.popup.visible ? 180 : 0
+			text: "▾"
+			transformOrigin: Item.Center
+			verticalAlignment: Text.AlignVCenter
+
+			Behavior on rotation {
+				NumberAnimation {
+					duration: 140
+					easing.type: Easing.OutCubic
+				}
+			}
+		}
+	}
+	popup: Popup {
+		id: p
+
+		implicitHeight: list.contentItem.height + Appearance.padding.small * 2
+		implicitWidth: root.width
+		modal: true
+		popupType: root.preferPopupWindow ? Popup.Window : Popup.Item
+		y: -list.currentIndex * (root.menuRowHeight + Appearance.spacing.small) - Appearance.padding.small
+
+		background: CustomRect {
+			color: DynamicColors.palette.m3surface
+			radius: root.menuCornerRadius
+		}
+		contentItem: ListView {
+			id: list
+
+			anchors.bottomMargin: Appearance.padding.small
+			anchors.fill: parent
+			anchors.topMargin: Appearance.padding.small
+			clip: true
+			currentIndex: root.currentIndex
+			model: root.delegateModel
+			spacing: Appearance.spacing.small
+
+			delegate: CustomRect {
+				required property int index
+				required property var modelData
+
+				anchors.horizontalCenter: parent.horizontalCenter
+				color: (index === root.currentIndex) ? DynamicColors.palette.m3primary : "transparent"
+				implicitHeight: root.menuRowHeight
+				implicitWidth: p.implicitWidth - Appearance.padding.small * 2
+				radius: Appearance.rounding.normal - Appearance.padding.small
+
+				RowLayout {
+					anchors.fill: parent
+					spacing: 10
+
+					CustomText {
+						Layout.fillWidth: true
+						color: DynamicColors.palette.m3onSurface
+						elide: Text.ElideRight
+						font.pixelSize: 15
+						text: modelData
+						verticalAlignment: Text.AlignVCenter
+					}
+
+					CustomText {
+						color: DynamicColors.palette.m3onSurfaceVariant
+						text: "✓"
+						verticalAlignment: Text.AlignVCenter
+						visible: index === root.currentIndex
+					}
+				}
+
+				StateLayer {
+					onClicked: {
+						root.currentIndex = index;
+						p.close();
+					}
+				}
+			}
+		}
+
+		// Expressive-ish open/close motion: subtle scale+fade (tune to taste). :contentReference[oaicite:5]{index=5}
+		enter: Transition {
+			Anim {
+				from: 0
+				property: "opacity"
+				to: 1
+			}
+
+			Anim {
+				from: 0.98
+				property: "scale"
+				to: 1.0
+			}
+		}
+		exit: Transition {
+			Anim {
+				from: 1
+				property: "opacity"
+				to: 0
+			}
+		}
+
+		Elevation {
+			anchors.fill: parent
+			level: 2
+			radius: root.menuCornerRadius
+			z: -1
+		}
+	}
+}

Greeter/Components/CustomFlickable.qml

@@ -0,0 +1,13 @@
+import QtQuick
+
+Flickable {
+	id: root
+
+	maximumFlickVelocity: 3000
+
+	rebound: Transition {
+		Anim {
+			properties: "x,y"
+		}
+	}
+}

Greeter/Components/CustomIcon.qml

@@ -0,0 +1,10 @@
+pragma ComponentBehavior: Bound
+
+import Quickshell.Widgets
+import QtQuick
+
+IconImage {
+	id: root
+
+	asynchronous: true
+}

Greeter/Components/CustomListView.qml

@@ -0,0 +1,13 @@
+import QtQuick
+
+ListView {
+	id: root
+
+	maximumFlickVelocity: 3000
+
+	rebound: Transition {
+		Anim {
+			properties: "x,y"
+		}
+	}
+}

Greeter/Components/CustomMouseArea.qml

@@ -0,0 +1,19 @@
+import QtQuick
+
+MouseArea {
+	property int scrollAccumulatedY: 0
+
+	function onWheel(event: WheelEvent): void {
+	}
+
+	onWheel: event => {
+		if (Math.sign(event.angleDelta.y) !== Math.sign(scrollAccumulatedY))
+			scrollAccumulatedY = 0;
+		scrollAccumulatedY += event.angleDelta.y;
+
+		if (Math.abs(scrollAccumulatedY) >= 120) {
+			onWheel(event);
+			scrollAccumulatedY = 0;
+		}
+	}
+}

Greeter/Components/CustomRadioButton.qml

@@ -0,0 +1,53 @@
+import QtQuick
+import QtQuick.Templates
+import qs.Config
+
+RadioButton {
+	id: root
+
+	font.pointSize: Appearance.font.size.normal
+	implicitHeight: Math.max(implicitIndicatorHeight, implicitContentHeight)
+	implicitWidth: implicitIndicatorWidth + implicitContentWidth + contentItem.anchors.leftMargin
+
+	contentItem: CustomText {
+		anchors.left: outerCircle.right
+		anchors.leftMargin: 10
+		anchors.verticalCenter: parent.verticalCenter
+		font.pointSize: root.font.pointSize
+		text: root.text
+	}
+	indicator: Rectangle {
+		id: outerCircle
+
+		anchors.verticalCenter: parent.verticalCenter
+		border.color: root.checked ? DynamicColors.palette.m3primary : DynamicColors.palette.m3onSurfaceVariant
+		border.width: 2
+		color: "transparent"
+		implicitHeight: 16
+		implicitWidth: 16
+		radius: 1000
+
+		Behavior on border.color {
+			CAnim {
+			}
+		}
+
+		StateLayer {
+			function onClicked(): void {
+				root.click();
+			}
+
+			anchors.margins: -7
+			color: root.checked ? DynamicColors.palette.m3onSurface : DynamicColors.palette.m3primary
+			z: -1
+		}
+
+		CustomRect {
+			anchors.centerIn: parent
+			color: Qt.alpha(DynamicColors.palette.m3primary, root.checked ? 1 : 0)
+			implicitHeight: 8
+			implicitWidth: 8
+			radius: 1000
+		}
+	}
+}

Greeter/Components/CustomRect.qml

@@ -0,0 +1,12 @@
+import QtQuick
+
+Rectangle {
+	id: root
+
+	color: "transparent"
+
+	Behavior on color {
+		CAnim {
+		}
+	}
+}

Greeter/Components/CustomScrollBar.qml

@@ -0,0 +1,189 @@
+import qs.Config
+import QtQuick
+import QtQuick.Templates
+
+ScrollBar {
+	id: root
+
+	property bool _updatingFromFlickable: false
+	property bool _updatingFromUser: false
+	property bool animating
+	required property Flickable flickable
+	property real nonAnimPosition
+	property bool shouldBeActive
+
+	implicitWidth: 8
+
+	contentItem: CustomRect {
+		anchors.left: parent.left
+		anchors.right: parent.right
+		color: DynamicColors.palette.m3secondary
+		opacity: {
+			if (root.size === 1)
+				return 0;
+			if (fullMouse.pressed)
+				return 1;
+			if (mouse.containsMouse)
+				return 0.8;
+			if (root.policy === ScrollBar.AlwaysOn || root.shouldBeActive)
+				return 0.6;
+			return 0;
+		}
+		radius: 1000
+
+		Behavior on opacity {
+			Anim {
+			}
+		}
+
+		MouseArea {
+			id: mouse
+
+			acceptedButtons: Qt.NoButton
+			anchors.fill: parent
+			cursorShape: Qt.PointingHandCursor
+			hoverEnabled: true
+		}
+	}
+	Behavior on position {
+		enabled: !fullMouse.pressed
+
+		Anim {
+		}
+	}
+
+	Component.onCompleted: {
+		if (flickable) {
+			const contentHeight = flickable.contentHeight;
+			const height = flickable.height;
+			if (contentHeight > height) {
+				nonAnimPosition = Math.max(0, Math.min(1, flickable.contentY / (contentHeight - height)));
+			}
+		}
+	}
+	onHoveredChanged: {
+		if (hovered)
+			shouldBeActive = true;
+		else
+			shouldBeActive = flickable.moving;
+	}
+
+	// Sync nonAnimPosition with Qt's automatic position binding
+	onPositionChanged: {
+		if (_updatingFromUser) {
+			_updatingFromUser = false;
+			return;
+		}
+		if (position === nonAnimPosition) {
+			animating = false;
+			return;
+		}
+		if (!animating && !_updatingFromFlickable && !fullMouse.pressed) {
+			nonAnimPosition = position;
+		}
+	}
+
+	// Sync nonAnimPosition with flickable when not animating
+	Connections {
+		function onContentYChanged() {
+			if (!animating && !fullMouse.pressed) {
+				_updatingFromFlickable = true;
+				const contentHeight = flickable.contentHeight;
+				const height = flickable.height;
+				if (contentHeight > height) {
+					nonAnimPosition = Math.max(0, Math.min(1, flickable.contentY / (contentHeight - height)));
+				} else {
+					nonAnimPosition = 0;
+				}
+				_updatingFromFlickable = false;
+			}
+		}
+
+		target: flickable
+	}
+
+	Connections {
+		function onMovingChanged(): void {
+			if (root.flickable.moving)
+				root.shouldBeActive = true;
+			else
+				hideDelay.restart();
+		}
+
+		target: root.flickable
+	}
+
+	Timer {
+		id: hideDelay
+
+		interval: 600
+
+		onTriggered: root.shouldBeActive = root.flickable.moving || root.hovered
+	}
+
+	CustomMouseArea {
+		id: fullMouse
+
+		function onWheel(event: WheelEvent): void {
+			root.animating = true;
+			root._updatingFromUser = true;
+			let newPos = root.nonAnimPosition;
+			if (event.angleDelta.y > 0)
+				newPos = Math.max(0, root.nonAnimPosition - 0.1);
+			else if (event.angleDelta.y < 0)
+				newPos = Math.min(1 - root.size, root.nonAnimPosition + 0.1);
+			root.nonAnimPosition = newPos;
+			// Update flickable position
+			// Map scrollbar position [0, 1-size] to contentY [0, maxContentY]
+			if (root.flickable) {
+				const contentHeight = root.flickable.contentHeight;
+				const height = root.flickable.height;
+				if (contentHeight > height) {
+					const maxContentY = contentHeight - height;
+					const maxPos = 1 - root.size;
+					const contentY = maxPos > 0 ? (newPos / maxPos) * maxContentY : 0;
+					root.flickable.contentY = Math.max(0, Math.min(maxContentY, contentY));
+				}
+			}
+		}
+
+		anchors.fill: parent
+		preventStealing: true
+
+		onPositionChanged: event => {
+			root._updatingFromUser = true;
+			const newPos = Math.max(0, Math.min(1 - root.size, event.y / root.height - root.size / 2));
+			root.nonAnimPosition = newPos;
+			// Update flickable position
+			// Map scrollbar position [0, 1-size] to contentY [0, maxContentY]
+			if (root.flickable) {
+				const contentHeight = root.flickable.contentHeight;
+				const height = root.flickable.height;
+				if (contentHeight > height) {
+					const maxContentY = contentHeight - height;
+					const maxPos = 1 - root.size;
+					const contentY = maxPos > 0 ? (newPos / maxPos) * maxContentY : 0;
+					root.flickable.contentY = Math.max(0, Math.min(maxContentY, contentY));
+				}
+			}
+		}
+		onPressed: event => {
+			root.animating = true;
+			root._updatingFromUser = true;
+			const newPos = Math.max(0, Math.min(1 - root.size, event.y / root.height - root.size / 2));
+			root.nonAnimPosition = newPos;
+			// Update flickable position
+			// Map scrollbar position [0, 1-size] to contentY [0, maxContentY]
+			if (root.flickable) {
+				const contentHeight = root.flickable.contentHeight;
+				const height = root.flickable.height;
+				if (contentHeight > height) {
+					const maxContentY = contentHeight - height;
+					const maxPos = 1 - root.size;
+					const contentY = maxPos > 0 ? (newPos / maxPos) * maxContentY : 0;
+					root.flickable.contentY = Math.max(0, Math.min(maxContentY, contentY));
+				}
+			}
+		}
+	}
+}

Greeter/Components/CustomShortcut.qml

@@ -0,0 +1,5 @@
+import Quickshell.Hyprland
+
+GlobalShortcut {
+	appid: "zshell"
+}

Greeter/Components/CustomSlider.qml

@@ -0,0 +1,45 @@
+import QtQuick
+import QtQuick.Templates
+import qs.Config
+
+Slider {
+	id: root
+
+	background: Item {
+		CustomRect {
+			anchors.bottom: parent.bottom
+			anchors.left: parent.left
+			anchors.top: parent.top
+			bottomRightRadius: root.implicitHeight / 6
+			color: DynamicColors.palette.m3primary
+			implicitWidth: root.handle.x - root.implicitHeight / 2
+			radius: 1000
+			topRightRadius: root.implicitHeight / 6
+		}
+
+		CustomRect {
+			anchors.bottom: parent.bottom
+			anchors.right: parent.right
+			anchors.top: parent.top
+			bottomLeftRadius: root.implicitHeight / 6
+			color: DynamicColors.tPalette.m3surfaceContainer
+			implicitWidth: parent.width - root.handle.x - root.handle.implicitWidth - root.implicitHeight / 2
+			radius: 1000
+			topLeftRadius: root.implicitHeight / 6
+		}
+	}
+	handle: CustomRect {
+		anchors.verticalCenter: parent.verticalCenter
+		color: DynamicColors.palette.m3primary
+		implicitHeight: 15
+		implicitWidth: 5
+		radius: 1000
+		x: root.visualPosition * root.availableWidth - implicitWidth / 2
+
+		MouseArea {
+			acceptedButtons: Qt.NoButton
+			anchors.fill: parent
+			cursorShape: Qt.PointingHandCursor
+		}
+	}
+}

Greeter/Components/CustomSpinBox.qml

@@ -0,0 +1,169 @@
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import QtQuick.Layouts
+import qs.Config
+
+RowLayout {
+	id: root
+
+	property string displayText: root.value.toString()
+	property bool isEditing: false
+	property real max: Infinity
+	property real min: -Infinity
+	property alias repeatRate: timer.interval
+	property real step: 1
+	property real value
+
+	signal valueModified(value: real)
+
+	spacing: Appearance.spacing.small
+
+	onValueChanged: {
+		if (!root.isEditing) {
+			root.displayText = root.value.toString();
+		}
+	}
+
+	CustomTextField {
+		id: textField
+
+		implicitHeight: upButton.implicitHeight
+		inputMethodHints: Qt.ImhFormattedNumbersOnly
+		leftPadding: Appearance.padding.normal
+		padding: Appearance.padding.small
+		rightPadding: Appearance.padding.normal
+		text: root.isEditing ? text : root.displayText
+
+		background: CustomRect {
+			color: DynamicColors.tPalette.m3surfaceContainerHigh
+			implicitWidth: 100
+			radius: Appearance.rounding.full
+		}
+		validator: DoubleValidator {
+			bottom: root.min
+			decimals: root.step < 1 ? Math.max(1, Math.ceil(-Math.log10(root.step))) : 0
+			top: root.max
+		}
+
+		onAccepted: {
+			const numValue = parseFloat(text);
+			if (!isNaN(numValue)) {
+				const clampedValue = Math.max(root.min, Math.min(root.max, numValue));
+				root.value = clampedValue;
+				root.displayText = clampedValue.toString();
+				root.valueModified(clampedValue);
+			} else {
+				text = root.displayText;
+			}
+			root.isEditing = false;
+		}
+		onActiveFocusChanged: {
+			if (activeFocus) {
+				root.isEditing = true;
+			} else {
+				root.isEditing = false;
+				root.displayText = root.value.toString();
+			}
+		}
+		onEditingFinished: {
+			if (text !== root.displayText) {
+				const numValue = parseFloat(text);
+				if (!isNaN(numValue)) {
+					const clampedValue = Math.max(root.min, Math.min(root.max, numValue));
+					root.value = clampedValue;
+					root.displayText = clampedValue.toString();
+					root.valueModified(clampedValue);
+				} else {
+					text = root.displayText;
+				}
+			}
+			root.isEditing = false;
+		}
+	}
+
+	CustomRect {
+		id: upButton
+
+		color: DynamicColors.palette.m3primary
+		implicitHeight: upIcon.implicitHeight + Appearance.padding.small * 2
+		implicitWidth: implicitHeight
+		radius: Appearance.rounding.full
+
+		StateLayer {
+			id: upState
+
+			function onClicked(): void {
+				let newValue = Math.min(root.max, root.value + root.step);
+				// Round to avoid floating point precision errors
+				const decimals = root.step < 1 ? Math.max(1, Math.ceil(-Math.log10(root.step))) : 0;
+				newValue = Math.round(newValue * Math.pow(10, decimals)) / Math.pow(10, decimals);
+				root.value = newValue;
+				root.displayText = newValue.toString();
+				root.valueModified(newValue);
+			}
+
+			color: DynamicColors.palette.m3onPrimary
+
+			onPressAndHold: timer.start()
+			onReleased: timer.stop()
+		}
+
+		MaterialIcon {
+			id: upIcon
+
+			anchors.centerIn: parent
+			color: DynamicColors.palette.m3onPrimary
+			text: "keyboard_arrow_up"
+		}
+	}
+
+	CustomRect {
+		color: DynamicColors.palette.m3primary
+		implicitHeight: downIcon.implicitHeight + Appearance.padding.small * 2
+		implicitWidth: implicitHeight
+		radius: Appearance.rounding.full
+
+		StateLayer {
+			id: downState
+
+			function onClicked(): void {
+				let newValue = Math.max(root.min, root.value - root.step);
+				// Round to avoid floating point precision errors
+				const decimals = root.step < 1 ? Math.max(1, Math.ceil(-Math.log10(root.step))) : 0;
+				newValue = Math.round(newValue * Math.pow(10, decimals)) / Math.pow(10, decimals);
+				root.value = newValue;
+				root.displayText = newValue.toString();
+				root.valueModified(newValue);
+			}
+
+			color: DynamicColors.palette.m3onPrimary
+
+			onPressAndHold: timer.start()
+			onReleased: timer.stop()
+		}
+
+		MaterialIcon {
+			id: downIcon
+
+			anchors.centerIn: parent
+			color: DynamicColors.palette.m3onPrimary
+			text: "keyboard_arrow_down"
+		}
+	}
+
+	Timer {
+		id: timer
+
+		interval: 100
+		repeat: true
+		triggeredOnStart: true
+
+		onTriggered: {
+			if (upState.pressed)
+				upState.onClicked();
+			else if (downState.pressed)
+				downState.onClicked();
+		}
+	}
+}

Greeter/Components/CustomSplitButton.qml

@@ -0,0 +1,181 @@
+import QtQuick
+import QtQuick.Layouts
+import qs.Config
+import qs.Helpers
+
+Row {
+	id: root
+
+	enum Type {
+		Filled,
+		Tonal
+	}
+
+	property alias active: menu.active
+	property color color: type == CustomSplitButton.Filled ? DynamicColors.palette.m3primary : DynamicColors.palette.m3secondaryContainer
+	property bool disabled
+	property color disabledColor: Qt.alpha(DynamicColors.palette.m3onSurface, 0.1)
+	property color disabledTextColor: Qt.alpha(DynamicColors.palette.m3onSurface, 0.38)
+	property alias expanded: menu.expanded
+	property string fallbackIcon
+	property string fallbackText
+	property real horizontalPadding: Appearance.padding.normal
+	property alias iconLabel: iconLabel
+	property alias label: label
+	property alias menu: menu
+	property alias menuItems: menu.items
+	property bool menuOnTop
+	property alias stateLayer: stateLayer
+	property color textColor: type == CustomSplitButton.Filled ? DynamicColors.palette.m3onPrimary : DynamicColors.palette.m3onSecondaryContainer
+	property int type: CustomSplitButton.Filled
+	property real verticalPadding: Appearance.padding.smaller
+
+	function closeDropdown(): void {
+		SettingsDropdowns.close(menu);
+	}
+
+	function openDropdown(): void {
+		if (root.disabled)
+			return;
+		SettingsDropdowns.open(menu, root);
+	}
+
+	function toggleDropdown(): void {
+		if (root.disabled)
+			return;
+		SettingsDropdowns.toggle(menu, root);
+	}
+
+	spacing: Math.floor(Appearance.spacing.small / 2)
+
+	onExpandedChanged: {
+		if (!expanded)
+			SettingsDropdowns.forget(menu);
+	}
+
+	CustomRect {
+		bottomRightRadius: Appearance.rounding.small / 2
+		color: root.disabled ? root.disabledColor : root.color
+		implicitHeight: expandBtn.implicitHeight
+		implicitWidth: textRow.implicitWidth + root.horizontalPadding * 2
+		radius: implicitHeight / 2 * Math.min(1, Appearance.rounding.scale)
+		topRightRadius: Appearance.rounding.small / 2
+
+		StateLayer {
+			id: stateLayer
+
+			function onClicked(): void {
+				root.active?.clicked();
+			}
+
+			color: root.textColor
+			disabled: root.disabled
+			rect.bottomRightRadius: parent.bottomRightRadius
+			rect.topRightRadius: parent.topRightRadius
+		}
+
+		RowLayout {
+			id: textRow
+
+			anchors.centerIn: parent
+			anchors.horizontalCenterOffset: Math.floor(root.verticalPadding / 4)
+			spacing: Appearance.spacing.small
+
+			MaterialIcon {
+				id: iconLabel
+
+				Layout.alignment: Qt.AlignVCenter
+				animate: true
+				color: root.disabled ? root.disabledTextColor : root.textColor
+				fill: 1
+				text: root.active?.activeIcon ?? root.fallbackIcon
+			}
+
+			CustomText {
+				id: label
+
+				Layout.alignment: Qt.AlignVCenter
+				Layout.preferredWidth: implicitWidth
+				animate: true
+				clip: true
+				color: root.disabled ? root.disabledTextColor : root.textColor
+				text: root.active?.activeText ?? root.fallbackText
+
+				Behavior on Layout.preferredWidth {
+					Anim {
+						easing.bezierCurve: Appearance.anim.curves.emphasized
+					}
+				}
+			}
+		}
+	}
+
+	CustomRect {
+		id: expandBtn
+
+		property real rad: root.expanded ? implicitHeight / 2 * Math.min(1, Appearance.rounding.scale) : Appearance.rounding.small / 2
+
+		bottomLeftRadius: rad
+		color: root.disabled ? root.disabledColor : root.color
+		implicitHeight: expandIcon.implicitHeight + root.verticalPadding * 2
+		implicitWidth: implicitHeight
+		radius: implicitHeight / 2 * Math.min(1, Appearance.rounding.scale)
+		topLeftRadius: rad
+
+		Behavior on rad {
+			Anim {
+			}
+		}
+
+		StateLayer {
+			id: expandStateLayer
+
+			function onClicked(): void {
+				root.toggleDropdown();
+			}
+
+			color: root.textColor
+			disabled: root.disabled
+			rect.bottomLeftRadius: parent.bottomLeftRadius
+			rect.topLeftRadius: parent.topLeftRadius
+		}
+
+		MaterialIcon {
+			id: expandIcon
+
+			anchors.centerIn: parent
+			anchors.horizontalCenterOffset: root.expanded ? 0 : -Math.floor(root.verticalPadding / 4)
+			color: root.disabled ? root.disabledTextColor : root.textColor
+			rotation: root.expanded ? 180 : 0
+			text: "expand_more"
+
+			Behavior on anchors.horizontalCenterOffset {
+				Anim {
+				}
+			}
+			Behavior on rotation {
+				Anim {
+				}
+			}
+		}
+
+		Menu {
+			id: menu
+
+			anchors.bottomMargin: Appearance.spacing.small
+			anchors.right: parent.right
+			anchors.top: parent.bottom
+			anchors.topMargin: Appearance.spacing.small
+
+			states: State {
+				when: root.menuOnTop
+
+				AnchorChanges {
+					anchors.bottom: expandBtn.top
+					anchors.top: undefined
+					target: menu
+				}
+			}
+		}
+	}
+}

Greeter/Components/CustomSplitButtonRow.qml

@@ -0,0 +1,58 @@
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import QtQuick.Layouts
+import qs.Config
+
+Item {
+	id: root
+
+	property alias active: splitButton.active
+	property bool enabled: true
+	property alias expanded: splitButton.expanded
+	property int expandedZ: 100
+	required property string label
+	property alias menuItems: splitButton.menuItems
+	property alias type: splitButton.type
+
+	signal selected(item: MenuItem)
+
+	Layout.fillWidth: true
+	Layout.preferredHeight: row.implicitHeight + Appearance.padding.smaller * 2
+	clip: false
+	z: root.expanded ? expandedZ : -1
+
+	RowLayout {
+		id: row
+
+		anchors.left: parent.left
+		anchors.margins: Appearance.padding.small
+		anchors.right: parent.right
+		anchors.verticalCenter: parent.verticalCenter
+		spacing: Appearance.spacing.normal
+
+		CustomText {
+			Layout.fillWidth: true
+			color: root.enabled ? DynamicColors.palette.m3onSurface : DynamicColors.palette.m3onSurfaceVariant
+			font.pointSize: Appearance.font.size.larger
+			text: root.label
+			z: root.expanded ? root.expandedZ : -1
+		}
+
+		CustomSplitButton {
+			id: splitButton
+
+			enabled: root.enabled
+			type: CustomSplitButton.Filled
+			z: root.expanded ? root.expandedZ : -1
+
+			menu.onItemSelected: item => {
+				root.selected(item);
+				splitButton.closeDropdown();
+			}
+			stateLayer.onClicked: {
+				splitButton.toggleDropdown();
+			}
+		}
+	}
+}

Greeter/Components/CustomSwitch.qml

@@ -0,0 +1,155 @@
+import QtQuick
+import QtQuick.Templates
+import QtQuick.Shapes
+import qs.Config
+
+Switch {
+	id: root
+
+	property int cLayer: 1
+
+	implicitHeight: implicitIndicatorHeight
+	implicitWidth: implicitIndicatorWidth
+
+	indicator: CustomRect {
+		color: root.checked ? DynamicColors.palette.m3primary : DynamicColors.layer(DynamicColors.palette.m3surfaceContainerHighest, root.cLayer)
+		implicitHeight: 13 + 7 * 2
+		implicitWidth: implicitHeight * 1.7
+		radius: 1000
+
+		CustomRect {
+			readonly property real nonAnimWidth: root.pressed ? implicitHeight * 1.3 : implicitHeight
+
+			anchors.verticalCenter: parent.verticalCenter
+			color: root.checked ? DynamicColors.palette.m3onPrimary : DynamicColors.layer(DynamicColors.palette.m3outline, root.cLayer + 1)
+			implicitHeight: parent.implicitHeight - 10
+			implicitWidth: nonAnimWidth
+			radius: 1000
+			x: root.checked ? parent.implicitWidth - nonAnimWidth - 10 / 2 : 10 / 2
+
+			Behavior on implicitWidth {
+				Anim {
+				}
+			}
+			Behavior on x {
+				Anim {
+				}
+			}
+
+			CustomRect {
+				anchors.fill: parent
+				color: root.checked ? DynamicColors.palette.m3primary : DynamicColors.palette.m3onSurface
+				opacity: root.pressed ? 0.1 : root.hovered ? 0.08 : 0
+				radius: parent.radius
+
+				Behavior on opacity {
+					Anim {
+					}
+				}
+			}
+
+			Shape {
+				id: icon
+
+				property point end1: {
+					if (root.pressed) {
+						if (root.checked)
+							return Qt.point(width * 0.4, height / 2);
+						return Qt.point(width * 0.8, height / 2);
+					}
+					if (root.checked)
+						return Qt.point(width * 0.4, height * 0.7);
+					return Qt.point(width * 0.85, height * 0.85);
+				}
+				property point end2: {
+					if (root.pressed)
+						return Qt.point(width, height / 2);
+					if (root.checked)
+						return Qt.point(width * 0.85, height * 0.2);
+					return Qt.point(width * 0.85, height * 0.15);
+				}
+				property point start1: {
+					if (root.pressed)
+						return Qt.point(width * 0.1, height / 2);
+					if (root.checked)
+						return Qt.point(width * 0.15, height / 2);
+					return Qt.point(width * 0.15, height * 0.15);
+				}
+				property point start2: {
+					if (root.pressed) {
+						if (root.checked)
+							return Qt.point(width * 0.4, height / 2);
+						return Qt.point(width * 0.2, height / 2);
+					}
+					if (root.checked)
+						return Qt.point(width * 0.4, height * 0.7);
+					return Qt.point(width * 0.15, height * 0.85);
+				}
+
+				anchors.centerIn: parent
+				asynchronous: true
+				height: parent.implicitHeight - Appearance.padding.small * 2
+				preferredRendererType: Shape.CurveRenderer
+				width: height
+
+				Behavior on end1 {
+					PropAnim {
+					}
+				}
+				Behavior on end2 {
+					PropAnim {
+					}
+				}
+				Behavior on start1 {
+					PropAnim {
+					}
+				}
+				Behavior on start2 {
+					PropAnim {
+					}
+				}
+
+				ShapePath {
+					capStyle: Appearance.rounding.scale === 0 ? ShapePath.SquareCap : ShapePath.RoundCap
+					fillColor: "transparent"
+					startX: icon.start1.x
+					startY: icon.start1.y
+					strokeColor: root.checked ? DynamicColors.palette.m3primary : DynamicColors.palette.m3surfaceContainerHighest
+					strokeWidth: Appearance.font.size.larger * 0.15
+
+					Behavior on strokeColor {
+						CAnim {
+						}
+					}
+
+					PathLine {
+						x: icon.end1.x
+						y: icon.end1.y
+					}
+
+					PathMove {
+						x: icon.start2.x
+						y: icon.start2.y
+					}
+
+					PathLine {
+						x: icon.end2.x
+						y: icon.end2.y
+					}
+				}
+			}
+		}
+	}
+
+	MouseArea {
+		anchors.fill: parent
+		cursorShape: Qt.PointingHandCursor
+		enabled: false
+	}
+
+	component PropAnim: PropertyAnimation {
+		duration: MaterialEasing.expressiveEffectsTime
+		easing.bezierCurve: MaterialEasing.expressiveEffects
+		easing.type: Easing.BezierSpline
+	}
+}

Greeter/Components/CustomText.qml

@@ -0,0 +1,51 @@
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import qs.Config
+
+Text {
+	id: root
+
+	property bool animate: false
+	property int animateDuration: 400
+	property real animateFrom: 0
+	property string animateProp: "scale"
+	property real animateTo: 1
+
+	color: DynamicColors.palette.m3onSurface
+	font.family: Appearance.font.family.sans
+	font.pointSize: Appearance.font.size.normal
+	renderType: Text.NativeRendering
+	textFormat: Text.PlainText
+
+	Behavior on color {
+		CAnim {
+		}
+	}
+	Behavior on text {
+		enabled: root.animate
+
+		SequentialAnimation {
+			Anim {
+				easing.bezierCurve: MaterialEasing.standardAccel
+				to: root.animateFrom
+			}
+
+			PropertyAction {
+			}
+
+			Anim {
+				easing.bezierCurve: MaterialEasing.standardDecel
+				to: root.animateTo
+			}
+		}
+	}
+
+	component Anim: NumberAnimation {
+		duration: root.animateDuration / 2
+		easing.type: Easing.BezierSpline
+		properties: root.animateProp.split(",").length > 1 ? root.animateProp : ""
+		property: root.animateProp.split(",").length === 1 ? root.animateProp : ""
+		target: root
+	}
+}

Greeter/Components/CustomTextField.qml

@@ -0,0 +1,75 @@
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import QtQuick.Controls
+import qs.Config
+
+TextField {
+	id: root
+
+	background: null
+	color: DynamicColors.palette.m3onSurface
+	cursorVisible: !readOnly
+	font.family: Appearance.font.family.sans
+	font.pointSize: Appearance.font.size.smaller
+	placeholderTextColor: DynamicColors.palette.m3outline
+	renderType: echoMode === TextField.Password ? TextField.QtRendering : TextField.NativeRendering
+
+	Behavior on color {
+		CAnim {
+		}
+	}
+	cursorDelegate: CustomRect {
+		id: cursor
+
+		property bool disableBlink
+
+		color: DynamicColors.palette.m3primary
+		implicitWidth: 2
+		radius: Appearance.rounding.normal
+
+		Behavior on opacity {
+			Anim {
+				duration: Appearance.anim.durations.small
+			}
+		}
+
+		Connections {
+			function onCursorPositionChanged(): void {
+				if (root.activeFocus && root.cursorVisible) {
+					cursor.opacity = 1;
+					cursor.disableBlink = true;
+					enableBlink.restart();
+				}
+			}
+
+			target: root
+		}
+
+		Timer {
+			id: enableBlink
+
+			interval: 100
+
+			onTriggered: cursor.disableBlink = false
+		}
+
+		Timer {
+			interval: 500
+			repeat: true
+			running: root.activeFocus && root.cursorVisible && !cursor.disableBlink
+			triggeredOnStart: true
+
+			onTriggered: parent.opacity = parent.opacity === 1 ? 0 : 1
+		}
+
+		Binding {
+			cursor.opacity: 0
+			when: !root.activeFocus || !root.cursorVisible
+		}
+	}
+	Behavior on placeholderTextColor {
+		CAnim {
+		}
+	}
+}

Greeter/Components/CustomTextInput.qml

@@ -0,0 +1,15 @@
+import QtQuick
+import QtQuick.Controls
+import qs.Config
+
+TextInput {
+	renderType: Text.NativeRendering
+	selectedTextColor: DynamicColors.palette.m3onSecondaryContainer
+	selectionColor: DynamicColors.tPalette.colSecondaryContainer
+
+	font {
+		family: Appearance?.font.family.sans ?? "sans-serif"
+		hintingPreference: Font.PreferFullHinting
+		pixelSize: Appearance?.font.size.normal ?? 15
+	}
+}

Greeter/Components/CustomTooltip.qml

@@ -0,0 +1,25 @@
+import QtQuick
+import QtQuick.Controls
+import qs.Components
+
+ToolTip {
+	id: root
+
+	property bool alternativeVisibleCondition: false
+	property bool extraVisibleCondition: true
+	readonly property bool internalVisibleCondition: (extraVisibleCondition && (parent.hovered === undefined || parent?.hovered)) || alternativeVisibleCondition
+
+	background: null
+	horizontalPadding: 10
+	verticalPadding: 5
+	visible: internalVisibleCondition
+
+	contentItem: CustomTooltipContent {
+		id: contentItem
+
+		horizontalPadding: root.horizontalPadding
+		shown: root.internalVisibleCondition
+		text: root.text
+		verticalPadding: root.verticalPadding
+	}
+}

Greeter/Components/CustomTooltipContent.qml

@@ -0,0 +1,54 @@
+import QtQuick
+import qs.Components
+import qs.Config
+
+Item {
+	id: root
+
+	property real horizontalPadding: 10
+	property bool isVisible: backgroundRectangle.implicitHeight > 0
+	property bool shown: false
+	required property string text
+	property real verticalPadding: 5
+
+	implicitHeight: tooltipTextObject.implicitHeight + 2 * root.verticalPadding
+	implicitWidth: tooltipTextObject.implicitWidth + 2 * root.horizontalPadding
+
+	Rectangle {
+		id: backgroundRectangle
+
+		clip: true
+		color: DynamicColors.tPalette.m3inverseSurface ?? "#3C4043"
+		implicitHeight: shown ? (tooltipTextObject.implicitHeight + 2 * root.verticalPadding) : 0
+		implicitWidth: shown ? (tooltipTextObject.implicitWidth + 2 * root.horizontalPadding) : 0
+		opacity: shown ? 1 : 0
+		radius: 8
+
+		Behavior on implicitHeight {
+			Anim {
+			}
+		}
+		Behavior on implicitWidth {
+			Anim {
+			}
+		}
+		Behavior on opacity {
+			Anim {
+			}
+		}
+
+		anchors {
+			bottom: root.bottom
+			horizontalCenter: root.horizontalCenter
+		}
+
+		CustomText {
+			id: tooltipTextObject
+
+			anchors.centerIn: parent
+			color: DynamicColors.palette.m3inverseOnSurface ?? "#FFFFFF"
+			text: root.text
+			wrapMode: Text.Wrap
+		}
+	}
+}

Greeter/Components/CustomWindow.qml

@@ -0,0 +1,9 @@
+import Quickshell
+import Quickshell.Wayland
+
+PanelWindow {
+	required property string name
+
+	WlrLayershell.namespace: `ZShell-${name}`
+	color: "transparent"
+}

Greeter/Components/Elevation.qml

@@ -0,0 +1,18 @@
+import qs.Config
+import QtQuick
+import QtQuick.Effects
+
+RectangularShadow {
+	property real dp: [0, 1, 3, 6, 8, 12][level]
+	property int level
+
+	blur: (dp * 5) ** 0.7
+	color: Qt.alpha(DynamicColors.palette.m3shadow, 0.7)
+	offset.y: dp / 2
+	spread: -dp * 0.3 + (dp * 0.1) ** 2
+
+	Behavior on dp {
+		Anim {
+		}
+	}
+}

Greeter/Components/ExtraIndicator.qml

@@ -0,0 +1,44 @@
+import qs.Config
+import QtQuick
+
+CustomRect {
+	required property int extra
+
+	anchors.margins: 8
+	anchors.right: parent.right
+	color: DynamicColors.palette.m3tertiary
+	implicitHeight: count.implicitHeight + 4 * 2
+	implicitWidth: count.implicitWidth + 8 * 2
+	opacity: extra > 0 ? 1 : 0
+	radius: 8
+	scale: extra > 0 ? 1 : 0.5
+
+	Behavior on opacity {
+		Anim {
+			duration: MaterialEasing.expressiveEffectsTime
+		}
+	}
+	Behavior on scale {
+		Anim {
+			duration: MaterialEasing.expressiveEffectsTime
+			easing.bezierCurve: MaterialEasing.expressiveEffects
+		}
+	}
+
+	Elevation {
+		anchors.fill: parent
+		level: 2
+		opacity: parent.opacity
+		radius: parent.radius
+		z: -1
+	}
+
+	CustomText {
+		id: count
+
+		anchors.centerIn: parent
+		animate: parent.opacity > 0
+		color: DynamicColors.palette.m3onTertiary
+		text: qsTr("+%1").arg(parent.extra)
+	}
+}

Greeter/Components/FilledSlider.qml

@@ -0,0 +1,29 @@
+import QtQuick
+import qs.Config
+
+BaseStyledSlider {
+	id: root
+
+	trackContent: Component {
+		Item {
+			property var groove
+			readonly property real handleHeight: handleItem ? handleItem.height : 0
+			property var handleItem
+			readonly property real handleWidth: handleItem ? handleItem.width : 0
+
+			// Set by BaseStyledSlider's Loader
+			property var rootSlider
+
+			anchors.fill: parent
+
+			CustomRect {
+				color: rootSlider?.color
+				height: rootSlider?.isVertical ? handleHeight + (1 - rootSlider?.visualPosition) * (groove?.height - handleHeight) : groove?.height
+				radius: groove?.radius
+				width: rootSlider?.isHorizontal ? handleWidth + rootSlider?.visualPosition * (groove?.width - handleWidth) : groove?.width
+				x: rootSlider?.isHorizontal ? (rootSlider?.mirrored ? groove?.width - width : 0) : 0
+				y: rootSlider?.isVertical ? groove?.height - height : 0
+			}
+		}
+	}
+}

Greeter/Components/GradientSlider.qml

@@ -0,0 +1,47 @@
+import QtQuick
+import qs.Config
+
+BaseStyledSlider {
+	id: root
+
+	property real alpha: 1.0
+	property real brightness: 1.0
+	property string channel: "saturation"
+	readonly property color currentColor: Qt.hsva(hue, channel === "saturation" ? value : saturation, channel === "brightness" ? value : brightness, alpha)
+	property real hue: 0.0
+	property real saturation: 1.0
+
+	from: 0
+	to: 1
+
+	trackContent: Component {
+		Item {
+			property var groove
+			property var handleItem
+			property var rootSlider
+
+			anchors.fill: parent
+
+			Rectangle {
+				anchors.fill: parent
+				antialiasing: true
+				color: "transparent"
+				radius: groove?.radius ?? 0
+
+				gradient: Gradient {
+					orientation: rootSlider?.isHorizontal ? Gradient.Horizontal : Gradient.Vertical
+
+					GradientStop {
+						color: root.channel === "saturation" ? Qt.hsva(root.hue, 0.0, root.brightness, root.alpha) : Qt.hsva(root.hue, root.saturation, 0.0, root.alpha)
+						position: 0.0
+					}
+
+					GradientStop {
+						color: root.channel === "saturation" ? Qt.hsva(root.hue, 1.0, root.brightness, root.alpha) : Qt.hsva(root.hue, root.saturation, 1.0, root.alpha)
+						position: 1.0
+					}
+				}
+			}
+		}
+	}
+}

Greeter/Components/IconButton.qml

@@ -0,0 +1,80 @@
+import qs.Config
+import QtQuick
+
+CustomRect {
+	id: root
+
+	enum Type {
+		Filled,
+		Tonal,
+		Text
+	}
+
+	property color activeColour: type === IconButton.Filled ? DynamicColors.palette.m3primary : DynamicColors.palette.m3secondary
+	property color activeOnColour: type === IconButton.Filled ? DynamicColors.palette.m3onPrimary : type === IconButton.Tonal ? DynamicColors.palette.m3onSecondary : DynamicColors.palette.m3primary
+	property bool checked
+	property bool disabled
+	property color disabledColour: Qt.alpha(DynamicColors.palette.m3onSurface, 0.1)
+	property color disabledOnColour: Qt.alpha(DynamicColors.palette.m3onSurface, 0.38)
+	property alias font: label.font
+	property alias icon: label.text
+	property color inactiveColour: {
+		if (!toggle && type === IconButton.Filled)
+			return DynamicColors.palette.m3primary;
+		return type === IconButton.Filled ? DynamicColors.tPalette.m3surfaceContainer : DynamicColors.palette.m3secondaryContainer;
+	}
+	property color inactiveOnColour: {
+		if (!toggle && type === IconButton.Filled)
+			return DynamicColors.palette.m3onPrimary;
+		return type === IconButton.Tonal ? DynamicColors.palette.m3onSecondaryContainer : DynamicColors.palette.m3onSurfaceVariant;
+	}
+	property bool internalChecked
+	property alias label: label
+	property real padding: type === IconButton.Text ? 10 / 2 : 7
+	property alias radiusAnim: radiusAnim
+	property alias stateLayer: stateLayer
+	property bool toggle
+	property int type: IconButton.Filled
+
+	signal clicked
+
+	color: type === IconButton.Text ? "transparent" : disabled ? disabledColour : internalChecked ? activeColour : inactiveColour
+	implicitHeight: label.implicitHeight + padding * 2
+	implicitWidth: implicitHeight
+	radius: internalChecked ? 6 : implicitHeight / 2 * Math.min(1, 1)
+
+	Behavior on radius {
+		Anim {
+			id: radiusAnim
+
+		}
+	}
+
+	onCheckedChanged: internalChecked = checked
+
+	StateLayer {
+		id: stateLayer
+
+		function onClicked(): void {
+			if (root.toggle)
+				root.internalChecked = !root.internalChecked;
+			root.clicked();
+		}
+
+		color: root.internalChecked ? root.activeOnColour : root.inactiveOnColour
+		disabled: root.disabled
+	}
+
+	MaterialIcon {
+		id: label
+
+		anchors.centerIn: parent
+		color: root.disabled ? root.disabledOnColour : root.internalChecked ? root.activeOnColour : root.inactiveOnColour
+		fill: !root.toggle || root.internalChecked ? 1 : 0
+
+		Behavior on fill {
+			Anim {
+			}
+		}
+	}
+}

Greeter/Components/MarqueeText.qml

@@ -0,0 +1,221 @@
+import QtQuick
+import qs.Config
+
+Item {
+	id: root
+
+	property alias anim: marqueeAnim
+	property bool animate: false
+	property color color: DynamicColors.palette.m3onSurface
+	property int fadeStrengthAnimMs: 180
+	property real fadeStrengthIdle: 0.0
+	property real fadeStrengthMoving: 1.0
+	property alias font: elideText.font
+	property int gap: 40
+	property alias horizontalAlignment: elideText.horizontalAlignment
+	property bool leftFadeEnabled: false
+	property real leftFadeStrength: overflowing && leftFadeEnabled ? fadeStrengthMoving : fadeStrengthIdle
+	property int leftFadeWidth: 28
+	property bool marqueeEnabled: true
+	readonly property bool overflowing: metrics.width > root.width
+	property int pauseMs: 1200
+	property real pixelsPerSecond: 40
+	property real rightFadeStrength: overflowing ? fadeStrengthMoving : fadeStrengthIdle
+	property int rightFadeWidth: 28
+	property bool sliding: false
+	property alias text: elideText.text
+
+	function durationForDistance(px): int {
+		return Math.max(1, Math.round(Math.abs(px) / root.pixelsPerSecond * 1000));
+	}
+
+	function resetMarquee() {
+		marqueeAnim.stop();
+		strip.x = 0;
+		root.sliding = false;
+		root.leftFadeEnabled = false;
+
+		if (root.marqueeEnabled && root.overflowing && root.visible) {
+			marqueeAnim.restart();
+		}
+	}
+
+	clip: true
+	implicitHeight: elideText.implicitHeight
+
+	Behavior on leftFadeStrength {
+		Anim {
+		}
+	}
+	Behavior on rightFadeStrength {
+		Anim {
+		}
+	}
+
+	onTextChanged: resetMarquee()
+	onVisibleChanged: if (!visible)
+		resetMarquee()
+	onWidthChanged: resetMarquee()
+
+	TextMetrics {
+		id: metrics
+
+		font: elideText.font
+		text: elideText.text
+	}
+
+	CustomText {
+		id: elideText
+
+		anchors.verticalCenter: parent.verticalCenter
+		animate: root.animate
+		animateProp: "scale,opacity"
+		color: root.color
+		elide: Text.ElideNone
+		visible: !root.overflowing
+		width: root.width
+	}
+
+	Item {
+		id: marqueeViewport
+
+		anchors.fill: parent
+		clip: true
+		layer.enabled: true
+		visible: root.overflowing
+
+		layer.effect: OpacityMask {
+			maskSource: rightFadeMask
+		}
+
+		Item {
+			id: strip
+
+			anchors.verticalCenter: parent.verticalCenter
+			height: t1.implicitHeight
+			width: t1.width + root.gap + t2.width
+			x: 0
+
+			CustomText {
+				id: t1
+
+				animate: root.animate
+				animateProp: "opacity"
+				color: root.color
+				text: elideText.text
+			}
+
+			CustomText {
+				id: t2
+
+				animate: root.animate
+				animateProp: "opacity"
+				color: root.color
+				text: t1.text
+				x: t1.width + root.gap
+			}
+		}
+
+		SequentialAnimation {
+			id: marqueeAnim
+
+			running: false
+
+			onFinished: pauseTimer.restart()
+
+			ScriptAction {
+				script: {
+					root.sliding = true;
+					root.leftFadeEnabled = true;
+				}
+			}
+
+			Anim {
+				duration: root.durationForDistance(t1.width)
+				easing.bezierCurve: Easing.Linear
+				easing.type: Easing.Linear
+				from: 0
+				property: "x"
+				target: strip
+				to: -t1.width
+			}
+
+			ScriptAction {
+				script: {
+					root.leftFadeEnabled = false;
+				}
+			}
+
+			Anim {
+				duration: root.durationForDistance(root.gap)
+				easing.bezierCurve: Easing.Linear
+				easing.type: Easing.Linear
+				from: -t1.width
+				property: "x"
+				target: strip
+				to: -(t1.width + root.gap)
+			}
+
+			ScriptAction {
+				script: {
+					root.sliding = false;
+					strip.x = 0;
+				}
+			}
+		}
+
+		Timer {
+			id: pauseTimer
+
+			interval: root.pauseMs
+			repeat: false
+			running: true
+
+			onTriggered: {
+				if (root.marqueeEnabled)
+					marqueeAnim.start();
+			}
+		}
+	}
+
+	Rectangle {
+		id: rightFadeMask
+
+		readonly property real fadeStartPos: {
+			const w = Math.max(1, width);
+			return Math.max(0, Math.min(1, (w - root.rightFadeWidth) / w));
+		}
+		readonly property real leftFadeEndPos: {
+			const w = Math.max(1, width);
+			return Math.max(0, Math.min(1, root.leftFadeWidth / w));
+		}
+
+		anchors.fill: marqueeViewport
+		layer.enabled: true
+		visible: false
+
+		gradient: Gradient {
+			orientation: Gradient.Horizontal
+
+			GradientStop {
+				color: Qt.rgba(1, 1, 1, 1.0 - root.leftFadeStrength)
+				position: 0.0
+			}
+
+			GradientStop {
+				color: Qt.rgba(1, 1, 1, 1.0)
+				position: rightFadeMask.leftFadeEndPos
+			}
+
+			GradientStop {
+				color: Qt.rgba(1, 1, 1, 1.0)
+				position: rightFadeMask.fadeStartPos
+			}
+
+			GradientStop {
+				color: Qt.rgba(1, 1, 1, 1.0 - root.rightFadeStrength)
+				position: 1.0
+			}
+		}
+	}
+}

Greeter/Components/MaterialIcon.qml

@@ -0,0 +1,15 @@
+import qs.Config
+
+CustomText {
+	property real fill
+	property int grade: DynamicColors.light ? 0 : -25
+
+	font.family: "Material Symbols Rounded"
+	font.pointSize: Appearance.font.size.larger
+	font.variableAxes: ({
+			FILL: fill.toFixed(1),
+			GRAD: grade,
+			opsz: fontInfo.pixelSize,
+			wght: fontInfo.weight
+		})
+}

Greeter/Components/Menu.qml

@@ -0,0 +1,115 @@
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import QtQuick.Layouts
+import qs.Config
+
+Elevation {
+	id: root
+
+	property MenuItem active: items[0] ?? null
+	property bool expanded
+	property list<MenuItem> items
+
+	signal itemSelected(item: MenuItem)
+
+	implicitHeight: root.expanded ? column.implicitHeight + Appearance.padding.small * 2 : 0
+	implicitWidth: Math.max(200, column.implicitWidth)
+	level: 2
+	opacity: root.expanded ? 1 : 0
+	radius: Appearance.rounding.normal
+
+	Behavior on implicitHeight {
+		Anim {
+			duration: Appearance.anim.durations.expressiveDefaultSpatial
+			easing.bezierCurve: Appearance.anim.curves.expressiveDefaultSpatial
+		}
+	}
+	Behavior on opacity {
+		Anim {
+			duration: Appearance.anim.durations.expressiveDefaultSpatial
+		}
+	}
+
+	CustomClippingRect {
+		anchors.fill: parent
+		color: DynamicColors.palette.m3surfaceContainer
+		radius: parent.radius
+
+		ColumnLayout {
+			id: column
+
+			anchors.left: parent.left
+			anchors.right: parent.right
+			anchors.verticalCenter: parent.verticalCenter
+			spacing: 5
+
+			Repeater {
+				model: root.items
+
+				CustomRect {
+					id: item
+
+					readonly property bool active: modelData === root.active
+					required property int index
+					required property MenuItem modelData
+
+					Layout.fillWidth: true
+					implicitHeight: menuOptionRow.implicitHeight + Appearance.padding.normal * 2
+					implicitWidth: menuOptionRow.implicitWidth + Appearance.padding.normal * 2
+
+					CustomRect {
+						anchors.fill: parent
+						anchors.leftMargin: Appearance.padding.small
+						anchors.rightMargin: Appearance.padding.small
+						color: Qt.alpha(DynamicColors.palette.m3secondaryContainer, active ? 1 : 0)
+						radius: Appearance.rounding.normal - Appearance.padding.small
+
+						StateLayer {
+							function onClicked(): void {
+								root.itemSelected(item.modelData);
+								root.active = item.modelData;
+								root.expanded = false;
+							}
+
+							color: item.active ? DynamicColors.palette.m3onSecondaryContainer : DynamicColors.palette.m3onSurface
+							disabled: !root.expanded
+						}
+					}
+
+					RowLayout {
+						id: menuOptionRow
+
+						anchors.fill: parent
+						anchors.margins: Appearance.padding.normal
+						spacing: Appearance.spacing.small
+
+						MaterialIcon {
+							Layout.alignment: Qt.AlignVCenter
+							color: item.active ? DynamicColors.palette.m3onSecondaryContainer : DynamicColors.palette.m3onSurfaceVariant
+							text: item.modelData.icon
+						}
+
+						CustomText {
+							Layout.alignment: Qt.AlignVCenter
+							Layout.fillWidth: true
+							color: item.active ? DynamicColors.palette.m3onSecondaryContainer : DynamicColors.palette.m3onSurface
+							text: item.modelData.text
+						}
+
+						Loader {
+							Layout.alignment: Qt.AlignVCenter
+							active: item.modelData.trailingIcon.length > 0
+							visible: active
+
+							sourceComponent: MaterialIcon {
+								color: item.active ? DynamicColors.palette.m3onSecondaryContainer : DynamicColors.palette.m3onSurface
+								text: item.modelData.trailingIcon
+							}
+						}
+					}
+				}
+			}
+		}
+	}
+}

Greeter/Components/MenuItem.qml

@@ -0,0 +1,12 @@
+import QtQuick
+
+QtObject {
+	property string activeIcon: icon
+	property string activeText: text
+	property string icon
+	required property string text
+	property string trailingIcon
+	property var value
+
+	signal clicked
+}

Greeter/Components/OpacityMask.qml

@@ -0,0 +1,9 @@
+import Quickshell
+import QtQuick
+
+ShaderEffect {
+	required property Item maskSource
+	required property Item source
+
+	fragmentShader: Qt.resolvedUrl(`${Quickshell.shellDir}/assets/shaders/opacitymask.frag.qsb`)
+}

Greeter/Components/PathMenu.qml

@@ -0,0 +1,76 @@
+import QtQuick
+
+Path {
+	id: root
+
+	required property real viewHeight
+	required property real viewWidth
+
+	startX: root.viewWidth / 2
+	startY: 0
+
+	PathAttribute {
+		name: "itemOpacity"
+		value: 0.25
+	}
+
+	PathLine {
+		x: root.viewWidth / 2
+		y: root.viewHeight * (1 / 6)
+	}
+
+	PathAttribute {
+		name: "itemOpacity"
+		value: 0.45
+	}
+
+	PathLine {
+		x: root.viewWidth / 2
+		y: root.viewHeight * (2 / 6)
+	}
+
+	PathAttribute {
+		name: "itemOpacity"
+		value: 0.70
+	}
+
+	PathLine {
+		x: root.viewWidth / 2
+		y: root.viewHeight * (3 / 6)
+	}
+
+	PathAttribute {
+		name: "itemOpacity"
+		value: 1.00
+	}
+
+	PathLine {
+		x: root.viewWidth / 2
+		y: root.viewHeight * (4 / 6)
+	}
+
+	PathAttribute {
+		name: "itemOpacity"
+		value: 0.70
+	}
+
+	PathLine {
+		x: root.viewWidth / 2
+		y: root.viewHeight * (5 / 6)
+	}
+
+	PathAttribute {
+		name: "itemOpacity"
+		value: 0.45
+	}
+
+	PathLine {
+		x: root.viewWidth / 2
+		y: root.viewHeight
+	}
+
+	PathAttribute {
+		name: "itemOpacity"
+		value: 0.25
+	}
+}

Greeter/Components/PathViewMenu.qml

@@ -0,0 +1,178 @@
+import QtQuick
+import QtQuick.Effects
+import qs.Config
+
+Elevation {
+	id: root
+
+	required property int currentIndex
+	property bool expanded
+	required property int from
+	property color insideTextColor: DynamicColors.palette.m3onPrimary
+	property int itemHeight
+	property int listHeight: 200
+	property color outsideTextColor: DynamicColors.palette.m3onSurfaceVariant
+	readonly property var spinnerModel: root.range(root.from, root.to)
+	required property int to
+	property Item triggerItem
+
+	signal itemSelected(item: int)
+
+	function range(first, last) {
+		let out = [];
+		for (let i = first; i <= last; ++i)
+			out.push(i);
+		return out;
+	}
+
+	implicitHeight: root.expanded ? view.implicitHeight : 0
+	level: root.expanded ? 2 : 0
+	radius: itemHeight / 2
+	visible: implicitHeight > 0
+
+	Behavior on implicitHeight {
+		Anim {
+		}
+	}
+
+	onExpandedChanged: {
+		if (!root.expanded)
+			root.itemSelected(view.currentIndex + 1);
+	}
+
+	Component {
+		id: spinnerDelegate
+
+		Item {
+			id: wrapper
+
+			readonly property color delegateTextColor: wrapper.PathView.view ? wrapper.PathView.view.delegateTextColor : "white"
+			required property var modelData
+
+			height: root.itemHeight
+			opacity: wrapper.PathView.itemOpacity
+			visible: wrapper.PathView.onPath
+			width: wrapper.PathView.view ? wrapper.PathView.view.width : 0
+			z: wrapper.PathView.isCurrentItem ? 100 : Math.round(wrapper.PathView.itemScale * 100)
+
+			CustomText {
+				anchors.centerIn: parent
+				color: wrapper.delegateTextColor
+				font.pointSize: Appearance.font.size.large
+				text: wrapper.modelData
+			}
+		}
+	}
+
+	CustomClippingRect {
+		anchors.fill: parent
+		color: DynamicColors.palette.m3surfaceContainer
+		radius: parent.radius
+
+		// Main visible spinner: normal/outside text color
+		PathView {
+			id: view
+
+			property color delegateTextColor: root.outsideTextColor
+
+			anchors.left: parent.left
+			anchors.right: parent.right
+			anchors.verticalCenter: parent.verticalCenter
+			clip: true
+			currentIndex: root.currentIndex - 1
+			delegate: spinnerDelegate
+			dragMargin: width
+			highlightRangeMode: PathView.StrictlyEnforceRange
+			implicitHeight: root.listHeight
+			model: root.spinnerModel
+			pathItemCount: 7
+			preferredHighlightBegin: 0.5
+			preferredHighlightEnd: 0.5
+			snapMode: PathView.SnapToItem
+
+			path: PathMenu {
+				viewHeight: view.height
+				viewWidth: view.width
+			}
+		}
+
+		// The selection rectangle itself
+		CustomRect {
+			id: selectionRect
+
+			anchors.verticalCenter: parent.verticalCenter
+			color: DynamicColors.palette.m3primary
+			height: root.itemHeight
+			radius: root.itemHeight / 2
+			width: parent.width
+			z: 2
+		}
+
+		// Hidden source: same PathView, but with the "inside selection" text color
+		Item {
+			id: selectedTextSource
+
+			anchors.fill: parent
+			layer.enabled: true
+			visible: false
+
+			PathView {
+				id: selectedTextView
+
+				property color delegateTextColor: root.insideTextColor
+
+				anchors.left: parent.left
+				anchors.right: parent.right
+				anchors.verticalCenter: parent.verticalCenter
+				clip: true
+				currentIndex: view.currentIndex
+				delegate: spinnerDelegate
+				dragMargin: view.dragMargin
+				highlightRangeMode: view.highlightRangeMode
+				implicitHeight: root.listHeight
+				interactive: false
+				model: view.model
+
+				// Keep this PathView visually locked to the real one
+				offset: view.offset
+				pathItemCount: view.pathItemCount
+				preferredHighlightBegin: view.preferredHighlightBegin
+				preferredHighlightEnd: view.preferredHighlightEnd
+				snapMode: view.snapMode
+
+				path: PathMenu {
+					viewHeight: selectedTextView.height
+					viewWidth: selectedTextView.width
+				}
+			}
+		}
+
+		// Mask matching the selection rectangle
+		Item {
+			id: selectionMask
+
+			anchors.fill: parent
+			layer.enabled: true
+			visible: false
+
+			CustomRect {
+				color: "white"
+				height: selectionRect.height
+				radius: selectionRect.radius
+				width: selectionRect.width
+				x: selectionRect.x
+				y: selectionRect.y
+			}
+		}
+
+		// Only show the "inside selection" text where the mask exists
+		MultiEffect {
+			anchors.fill: selectedTextSource
+			maskEnabled: true
+			maskInverted: false
+			maskSource: selectionMask
+			source: selectedTextSource
+			z: 3
+		}
+	}
+}

Greeter/Components/Ref.qml

@@ -0,0 +1,8 @@
+import QtQuick
+
+QtObject {
+	required property var service
+
+	Component.onCompleted: service.refCount++
+	Component.onDestruction: service.refCount--
+}

Greeter/Components/SpinBoxRow.qml

@@ -0,0 +1,50 @@
+import QtQuick
+import QtQuick.Layouts
+import qs.Config
+
+CustomRect {
+	id: root
+
+	required property string label
+	required property real max
+	required property real min
+	property var onValueModified: function (value) {}
+	property real step: 1
+	required property real value
+
+	Layout.fillWidth: true
+	color: DynamicColors.layer(DynamicColors.palette.m3surfaceContainer, 2)
+	implicitHeight: row.implicitHeight + Appearance.padding.large * 2
+	radius: Appearance.rounding.normal
+
+	Behavior on implicitHeight {
+		Anim {
+		}
+	}
+
+	RowLayout {
+		id: row
+
+		anchors.left: parent.left
+		anchors.margins: Appearance.padding.large
+		anchors.right: parent.right
+		anchors.verticalCenter: parent.verticalCenter
+		spacing: Appearance.spacing.normal
+
+		CustomText {
+			Layout.fillWidth: true
+			text: root.label
+		}
+
+		CustomSpinBox {
+			max: root.max
+			min: root.min
+			step: root.step
+			value: root.value
+
+			onValueModified: value => {
+				root.onValueModified(value);
+			}
+		}
+	}
+}

Greeter/Components/StateLayer.qml

@@ -0,0 +1,96 @@
+import qs.Config
+import QtQuick
+
+MouseArea {
+	id: root
+
+	property color color: DynamicColors.palette.m3onSurface
+	property bool disabled
+	property real radius: parent?.radius ?? 0
+	property alias rect: hoverLayer
+
+	function onClicked(): void {
+	}
+
+	anchors.fill: parent
+	cursorShape: disabled ? undefined : Qt.PointingHandCursor
+	enabled: !disabled
+	hoverEnabled: true
+
+	onClicked: event => !disabled && onClicked(event)
+	onPressed: event => {
+		if (disabled)
+			return;
+
+		rippleAnim.x = event.x;
+		rippleAnim.y = event.y;
+
+		const dist = (ox, oy) => ox * ox + oy * oy;
+		rippleAnim.radius = Math.sqrt(Math.max(dist(event.x, event.y), dist(event.x, height - event.y), dist(width - event.x, event.y), dist(width - event.x, height - event.y)));
+
+		rippleAnim.restart();
+	}
+
+	SequentialAnimation {
+		id: rippleAnim
+
+		property real radius
+		property real x
+		property real y
+
+		PropertyAction {
+			property: "x"
+			target: ripple
+			value: rippleAnim.x
+		}
+
+		PropertyAction {
+			property: "y"
+			target: ripple
+			value: rippleAnim.y
+		}
+
+		PropertyAction {
+			property: "opacity"
+			target: ripple
+			value: 0.08
+		}
+
+		Anim {
+			easing.bezierCurve: MaterialEasing.standardDecel
+			from: 0
+			properties: "implicitWidth,implicitHeight"
+			target: ripple
+			to: rippleAnim.radius * 2
+		}
+
+		Anim {
+			property: "opacity"
+			target: ripple
+			to: 0
+		}
+	}
+
+	CustomClippingRect {
+		id: hoverLayer
+
+		anchors.fill: parent
+		border.pixelAligned: false
+		color: Qt.alpha(root.color, root.disabled ? 0 : root.pressed ? 0.1 : root.containsMouse ? 0.08 : 0)
+		radius: root.radius
+
+		CustomRect {
+			id: ripple
+
+			border.pixelAligned: false
+			color: root.color
+			opacity: 0
+			radius: 1000
+
+			transform: Translate {
+				x: -ripple.width / 2
+				y: -ripple.height / 2
+			}
+		}
+	}
+}

Greeter/Components/Toast/ToastItem.qml

@@ -0,0 +1,131 @@
+import ZShell
+import QtQuick
+import QtQuick.Layouts
+import qs.Components
+import qs.Config
+
+CustomRect {
+	id: root
+
+	required property Toast modelData
+
+	anchors.left: parent.left
+	anchors.right: parent.right
+	border.color: {
+		let colour = DynamicColors.palette.m3outlineVariant;
+		if (root.modelData.type === Toast.Success)
+			colour = DynamicColors.palette.m3success;
+		if (root.modelData.type === Toast.Warning)
+			colour = DynamicColors.palette.m3secondaryContainer;
+		if (root.modelData.type === Toast.Error)
+			colour = DynamicColors.palette.m3error;
+		return Qt.alpha(colour, 0.3);
+	}
+	border.width: 1
+	color: {
+		if (root.modelData.type === Toast.Success)
+			return DynamicColors.palette.m3successContainer;
+		if (root.modelData.type === Toast.Warning)
+			return DynamicColors.palette.m3secondary;
+		if (root.modelData.type === Toast.Error)
+			return DynamicColors.palette.m3errorContainer;
+		return DynamicColors.palette.m3surface;
+	}
+	implicitHeight: layout.implicitHeight + Appearance.padding.smaller * 2
+	radius: Appearance.rounding.normal
+
+	Behavior on border.color {
+		CAnim {
+		}
+	}
+
+	Elevation {
+		anchors.fill: parent
+		level: 3
+		opacity: parent.opacity
+		radius: parent.radius
+		z: -1
+	}
+
+	RowLayout {
+		id: layout
+
+		anchors.fill: parent
+		anchors.leftMargin: Appearance.padding.normal
+		anchors.margins: Appearance.padding.smaller
+		anchors.rightMargin: Appearance.padding.normal
+		spacing: Appearance.spacing.normal
+
+		CustomRect {
+			color: {
+				if (root.modelData.type === Toast.Success)
+					return DynamicColors.palette.m3success;
+				if (root.modelData.type === Toast.Warning)
+					return DynamicColors.palette.m3secondaryContainer;
+				if (root.modelData.type === Toast.Error)
+					return DynamicColors.palette.m3error;
+				return DynamicColors.palette.m3surfaceContainerHigh;
+			}
+			implicitHeight: icon.implicitHeight + Appearance.padding.smaller * 2
+			implicitWidth: implicitHeight
+			radius: Appearance.rounding.normal
+
+			MaterialIcon {
+				id: icon
+
+				anchors.centerIn: parent
+				color: {
+					if (root.modelData.type === Toast.Success)
+						return DynamicColors.palette.m3onSuccess;
+					if (root.modelData.type === Toast.Warning)
+						return DynamicColors.palette.m3onSecondaryContainer;
+					if (root.modelData.type === Toast.Error)
+						return DynamicColors.palette.m3onError;
+					return DynamicColors.palette.m3onSurfaceVariant;
+				}
+				font.pointSize: Math.round(Appearance.font.size.large * 1.2)
+				text: root.modelData.icon
+			}
+		}
+
+		ColumnLayout {
+			Layout.fillWidth: true
+			spacing: 0
+
+			CustomText {
+				id: title
+
+				Layout.fillWidth: true
+				color: {
+					if (root.modelData.type === Toast.Success)
+						return DynamicColors.palette.m3onSuccessContainer;
+					if (root.modelData.type === Toast.Warning)
+						return DynamicColors.palette.m3onSecondary;
+					if (root.modelData.type === Toast.Error)
+						return DynamicColors.palette.m3onErrorContainer;
+					return DynamicColors.palette.m3onSurface;
+				}
+				elide: Text.ElideRight
+				font.pointSize: Appearance.font.size.normal
+				text: root.modelData.title
+			}
+
+			CustomText {
+				Layout.fillWidth: true
+				color: {
+					if (root.modelData.type === Toast.Success)
+						return DynamicColors.palette.m3onSuccessContainer;
+					if (root.modelData.type === Toast.Warning)
+						return DynamicColors.palette.m3onSecondary;
+					if (root.modelData.type === Toast.Error)
+						return DynamicColors.palette.m3onErrorContainer;
+					return DynamicColors.palette.m3onSurface;
+				}
+				elide: Text.ElideRight
+				opacity: 0.8
+				text: root.modelData.message
+				textFormat: Text.StyledText
+			}
+		}
+	}
+}

Greeter/Components/Toast/Toasts.qml

@@ -0,0 +1,142 @@
+pragma ComponentBehavior: Bound
+
+import ZShell
+import Quickshell
+import QtQuick
+import qs.Components
+import qs.Config
+
+Item {
+	id: root
+
+	property bool flag
+	readonly property int spacing: Appearance.spacing.small
+
+	implicitHeight: {
+		let h = -spacing;
+		for (let i = 0; i < repeater.count; i++) {
+			const item = repeater.itemAt(i) as ToastWrapper;
+			if (!item.modelData.closed && !item.previewHidden)
+				h += item.implicitHeight + spacing;
+		}
+		return h;
+	}
+	implicitWidth: Config.utilities.sizes.toastWidth - Appearance.padding.normal * 2
+
+	Repeater {
+		id: repeater
+
+		model: ScriptModel {
+			values: {
+				const toasts = [];
+				let count = 0;
+				for (const toast of Toaster.toasts) {
+					toasts.push(toast);
+					if (!toast.closed) {
+						count++;
+						if (count > Config.utilities.maxToasts)
+							break;
+					}
+				}
+				return toasts;
+			}
+
+			onValuesChanged: root.flagChanged()
+		}
+
+		ToastWrapper {
+		}
+	}
+
+	component ToastWrapper: MouseArea {
+		id: toast
+
+		required property int index
+		required property Toast modelData
+		readonly property bool previewHidden: {
+			let extraHidden = 0;
+			for (let i = 0; i < index; i++)
+				if (Toaster.toasts[i].closed)
+					extraHidden++;
+			return index >= Config.utilities.maxToasts + extraHidden;
+		}
+
+		acceptedButtons: Qt.LeftButton | Qt.MiddleButton | Qt.RightButton
+		anchors.bottom: parent.bottom
+		anchors.bottomMargin: {
+			root.flag; // Force update
+			let y = 0;
+			for (let i = 0; i < index; i++) {
+				const item = repeater.itemAt(i) as ToastWrapper;
+				if (item && !item.modelData.closed && !item.previewHidden)
+					y += item.implicitHeight + root.spacing;
+			}
+			return y;
+		}
+		anchors.left: parent.left
+		anchors.right: parent.right
+		implicitHeight: toastInner.implicitHeight
+		opacity: modelData.closed || previewHidden ? 0 : 1
+		scale: modelData.closed || previewHidden ? 0.7 : 1
+
+		Behavior on anchors.bottomMargin {
+			Anim {
+				duration: Appearance.anim.durations.expressiveDefaultSpatial
+				easing.bezierCurve: Appearance.anim.curves.expressiveDefaultSpatial
+			}
+		}
+		Behavior on opacity {
+			Anim {
+			}
+		}
+		Behavior on scale {
+			Anim {
+			}
+		}
+
+		Component.onCompleted: modelData.lock(this)
+		onClicked: modelData.close()
+		onPreviewHiddenChanged: {
+			if (initAnim.running && previewHidden)
+				initAnim.stop();
+		}
+
+		Anim {
+			id: initAnim
+
+			duration: Appearance.anim.durations.expressiveDefaultSpatial
+			easing.bezierCurve: Appearance.anim.curves.expressiveDefaultSpatial
+			from: 0
+			properties: "opacity,scale"
+			target: toast
+			to: 1
+
+			Component.onCompleted: running = !toast.previewHidden
+		}
+
+		ParallelAnimation {
+			running: toast.modelData.closed
+
+			onFinished: toast.modelData.unlock(toast)
+			onStarted: toast.anchors.bottomMargin = toast.anchors.bottomMargin
+
+			Anim {
+				property: "opacity"
+				target: toast
+				to: 0
+			}
+
+			Anim {
+				property: "scale"
+				target: toast
+				to: 0.7
+			}
+		}
+
+		ToastItem {
+			id: toastInner
+
+			modelData: toast.modelData
+		}
+	}
+}