update hypr toplevels

Helpers/Hypr.qml

@@ -0,0 +1,130 @@
+pragma Singleton
+
+import ZShell
+import ZShell.Internal
+import Quickshell
+import Quickshell.Hyprland
+import Quickshell.Io
+import QtQuick
+
+Singleton {
+    id: root
+
+    readonly property var toplevels: Hyprland.toplevels
+    readonly property var workspaces: Hyprland.workspaces
+    readonly property var monitors: Hyprland.monitors
+
+    readonly property HyprlandToplevel activeToplevel: Hyprland.activeToplevel?.wayland?.activated ? Hyprland.activeToplevel : null
+    readonly property HyprlandWorkspace focusedWorkspace: Hyprland.focusedWorkspace
+    readonly property HyprlandMonitor focusedMonitor: Hyprland.focusedMonitor
+    readonly property int activeWsId: focusedWorkspace?.id ?? 1
+
+    readonly property HyprKeyboard keyboard: extras.devices.keyboards.find(kb => kb.main) ?? null
+    readonly property bool capsLock: keyboard?.capsLock ?? false
+    readonly property bool numLock: keyboard?.numLock ?? false
+    readonly property string defaultKbLayout: keyboard?.layout.split(",")[0] ?? "??"
+    readonly property string kbLayoutFull: keyboard?.activeKeymap ?? "Unknown"
+    readonly property string kbLayout: kbMap.get(kbLayoutFull) ?? "??"
+    readonly property var kbMap: new Map()
+
+    readonly property alias extras: extras
+    readonly property alias options: extras.options
+    readonly property alias devices: extras.devices
+
+    property bool hadKeyboard
+
+    signal configReloaded
+
+    function dispatch(request: string): void {
+        Hyprland.dispatch(request);
+    }
+
+    function monitorFor(screen: ShellScreen): HyprlandMonitor {
+        return Hyprland.monitorFor(screen);
+    }
+
+    function reloadDynamicConfs(): void {
+        extras.batchMessage(["keyword bindlni ,Caps_Lock,global,caelestia:refreshDevices", "keyword bindlni ,Num_Lock,global,caelestia:refreshDevices"]);
+    }
+
+    Component.onCompleted: reloadDynamicConfs()
+
+    Connections {
+        target: Hyprland
+
+        function onRawEvent(event: HyprlandEvent): void {
+            const n = event.name;
+            if (n.endsWith("v2"))
+                return;
+
+            if (n === "configreloaded") {
+                root.configReloaded();
+                root.reloadDynamicConfs();
+            } else if (["workspace", "moveworkspace", "activespecial", "focusedmon"].includes(n)) {
+                Hyprland.refreshWorkspaces();
+                Hyprland.refreshMonitors();
+            } else if (["openwindow", "closewindow", "movewindow"].includes(n)) {
+                Hyprland.refreshToplevels();
+                Hyprland.refreshWorkspaces();
+            } else if (n.includes("mon")) {
+                Hyprland.refreshMonitors();
+            } else if (n.includes("workspace")) {
+                Hyprland.refreshWorkspaces();
+            } else if (n.includes("window") || n.includes("group") || ["pin", "fullscreen", "changefloatingmode", "minimize"].includes(n)) {
+                Hyprland.refreshToplevels();
+            }
+        }
+    }
+
+    FileView {
+        id: kbLayoutFile
+
+        path: Quickshell.env("CAELESTIA_XKB_RULES_PATH") || "/usr/share/X11/xkb/rules/base.lst"
+        onLoaded: {
+            const layoutMatch = text().match(/! layout\n([\s\S]*?)\n\n/);
+            if (layoutMatch) {
+                const lines = layoutMatch[1].split("\n");
+                for (const line of lines) {
+                    if (!line.trim() || line.trim().startsWith("!"))
+                        continue;
+
+                    const match = line.match(/^\s*([a-z]{2,})\s+([a-zA-Z() ]+)$/);
+                    if (match)
+                        root.kbMap.set(match[2], match[1]);
+                }
+            }
+
+            const variantMatch = text().match(/! variant\n([\s\S]*?)\n\n/);
+            if (variantMatch) {
+                const lines = variantMatch[1].split("\n");
+                for (const line of lines) {
+                    if (!line.trim() || line.trim().startsWith("!"))
+                        continue;
+
+                    const match = line.match(/^\s*([a-zA-Z0-9_-]+)\s+([a-z]{2,}): (.+)$/);
+                    if (match)
+                        root.kbMap.set(match[3], match[2]);
+                }
+            }
+        }
+    }
+
+    IpcHandler {
+        target: "hypr"
+
+        function refreshDevices(): void {
+            extras.refreshDevices();
+        }
+    }
+
+    GlobalShortcut {
+        name: "refreshDevices"
+        appid: "ZShell"
+        onPressed: extras.refreshDevices()
+        onReleased: extras.refreshDevices()
+    }
+
+    HyprExtras {
+        id: extras
+    }
+}

Helpers/Picker.qml

@@ -3,11 +3,11 @@ pragma ComponentBehavior: Bound
 import ZShell
 import Quickshell
 import Quickshell.Wayland
-import Quickshell.Hyprland
 import QtQuick
 import QtQuick.Effects
 import qs.Modules
 import qs.Config
+import qs.Helpers
 
 MouseArea {
     id: root
@@ -17,8 +17,8 @@ MouseArea {
 
     property bool onClient
 
-    property real realRounding: 6
-    property real realBorderWidth: 1
+    property real realBorderWidth: onClient ? (Hypr.options["general:border_size"] ?? 1) : 2
+    property real realRounding: onClient ? (Hypr.options["decoration:rounding"] ?? 0) : 0
 
     property real ssx
     property real ssy
@@ -34,14 +34,14 @@ MouseArea {
     property real sh: Math.abs(sy - ey)
 
     property list<var> clients: {
-        const mon = Hyprland.monitorFor(screen);
+        const mon = Hypr.monitorFor(screen);
         if (!mon)
             return [];
 
         const special = mon.lastIpcObject.specialWorkspace;
         const wsId = special.name ? special.id : mon.activeWorkspace.id;
 
-        return Hyprland.toplevels.values.filter(c => c.workspace?.id === wsId).sort((a, b) => {
+        return Hypr.toplevels.values.filter(c => c.workspace?.id === wsId).sort((a, b) => {
             const ac = a.lastIpcObject;
             const bc = b.lastIpcObject;
             return (bc.pinned - ac.pinned) || ((bc.fullscreen !== 0) - (ac.fullscreen !== 0)) || (bc.floating - ac.floating);
@@ -84,6 +84,7 @@ MouseArea {
     cursorShape: Qt.CrossCursor
 
     Component.onCompleted: {
+        Hypr.extras.refreshOptions();
         if (loader.freeze)
             clients = clients;