better chat list view + anchor to bottom. sqlite db for chats + LIFO-ordered

2026-08-23 16:37:11 +02:00
parent 37c6a9986e
commit aae3757daf
36 changed files with 2653 additions and 1459 deletions
@@ -0,0 +1,87 @@
+import QtQuick
+import ZShell.Config
+import qs.Components
+import qs.Services
+
+TextFieldBase {
+	id: root
+
+	readonly property alias bg: bg
+	readonly property alias sendIcon: sendIcon
+
+	signal sendPressed
+
+	bottomPadding: Tokens.padding.large
+	leftPadding: Tokens.padding.extraLarge
+	rightPadding: sendIcon.width + sendIcon.anchors.rightMargin + Tokens.spacing.small
+	topPadding: Tokens.padding.large
+	wrapMode: TextFieldBase.Wrap
+
+	background: CustomRect {
+		id: bg
+
+		anchors.fill: parent
+		color: Colors.tPalette.m3surfaceContainer
+		radius: Tokens.rounding.extraLarge
+
+		StateLayer {
+			id: stateLayer
+
+			cursorShape: Qt.IBeamCursor
+			enabled: !root.activeFocus
+			manualPressOverride: tapHandler.pressed
+
+			onClicked: root.focus = true
+		}
+	}
+
+	onPressed: {
+		if (stateLayer.enabled)
+			stateLayer.press(stateLayer.mouseX, stateLayer.mouseY);
+	}
+
+	CustomText {
+		id: placeholder
+
+		anchors.left: parent.left
+		anchors.leftMargin: root.leftPadding
+		anchors.verticalCenter: parent.verticalCenter
+		color: root.placeholderTextColor
+		font: root.font
+		opacity: root.text ? 0 : 1
+		text: root.placeholderText
+
+		Behavior on opacity {
+			Anim {
+				type: Anim.DefaultEffects
+			}
+		}
+	}
+
+	IconButton {
+		id: sendIcon
+
+		anchors.right: parent.right
+		anchors.rightMargin: Tokens.padding.small
+		anchors.verticalCenter: parent.verticalCenter
+		enabled: root.text
+		icon: "upward_arrow"
+		opacity: root.text ? 1 : 0
+		radius: Tokens.rounding.full
+		radiusMorph: false
+		stateLayer.hoverEnabled: enabled
+		type: IconButton.Text
+
+		Behavior on opacity {
+			Anim {
+				type: Anim.DefaultEffects
+			}
+		}
+
+		onClicked: root.sendPressed()
+	}
+
+	TapHandler {
+		id: tapHandler
+	}
+}