config fixes

Components/CustomText.qml

@@ -16,7 +16,7 @@ Text {
     renderType: Text.NativeRendering
     textFormat: Text.PlainText
     color: DynamicColors.palette.m3onSurface
-    font.family: Config.baseFont
+    font.family: Appearance.font.family.sans
     font.pointSize: 12
 
     Behavior on color {

Components/Toast/ToastItem.qml

@@ -0,0 +1,135 @@
+import ZShell
+import QtQuick
+import QtQuick.Layouts
+import qs.Modules
+import qs.Components
+import qs.Helpers
+import qs.Config
+
+CustomRect {
+    id: root
+
+    required property Toast modelData
+
+    anchors.left: parent.left
+    anchors.right: parent.right
+    implicitHeight: layout.implicitHeight + Appearance.padding.smaller * 2
+
+    radius: Appearance.rounding.normal
+    color: {
+        if (root.modelData.type === Toast.Success)
+            return DynamicColors.palette.m3successContainer;
+        if (root.modelData.type === Toast.Warning)
+            return DynamicColors.palette.m3secondary;
+        if (root.modelData.type === Toast.Error)
+            return DynamicColors.palette.m3errorContainer;
+        return DynamicColors.palette.m3surface;
+    }
+
+    border.width: 1
+    border.color: {
+        let colour = DynamicColors.palette.m3outlineVariant;
+        if (root.modelData.type === Toast.Success)
+            colour = DynamicColors.palette.m3success;
+        if (root.modelData.type === Toast.Warning)
+            colour = DynamicColors.palette.m3secondaryContainer;
+        if (root.modelData.type === Toast.Error)
+            colour = DynamicColors.palette.m3error;
+        return Qt.alpha(colour, 0.3);
+    }
+
+    Elevation {
+        anchors.fill: parent
+        radius: parent.radius
+        opacity: parent.opacity
+        z: -1
+        level: 3
+    }
+
+    RowLayout {
+        id: layout
+
+        anchors.fill: parent
+        anchors.margins: Appearance.padding.smaller
+        anchors.leftMargin: Appearance.padding.normal
+        anchors.rightMargin: Appearance.padding.normal
+        spacing: Appearance.spacing.normal
+
+        CustomRect {
+            radius: Appearance.rounding.normal
+            color: {
+                if (root.modelData.type === Toast.Success)
+                    return DynamicColors.palette.m3success;
+                if (root.modelData.type === Toast.Warning)
+                    return DynamicColors.palette.m3secondaryContainer;
+                if (root.modelData.type === Toast.Error)
+                    return DynamicColors.palette.m3error;
+                return DynamicColors.palette.m3surfaceContainerHigh;
+            }
+
+            implicitWidth: implicitHeight
+            implicitHeight: icon.implicitHeight + Appearance.padding.smaller * 2
+
+            MaterialIcon {
+                id: icon
+
+                anchors.centerIn: parent
+                text: root.modelData.icon
+                color: {
+                    if (root.modelData.type === Toast.Success)
+                        return DynamicColors.palette.m3onSuccess;
+                    if (root.modelData.type === Toast.Warning)
+                        return DynamicColors.palette.m3onSecondaryContainer;
+                    if (root.modelData.type === Toast.Error)
+                        return DynamicColors.palette.m3onError;
+                    return DynamicColors.palette.m3onSurfaceVariant;
+                }
+                font.pointSize: Math.round(Appearance.font.size.large * 1.2)
+            }
+        }
+
+        ColumnLayout {
+            Layout.fillWidth: true
+            spacing: 0
+
+            CustomText {
+                id: title
+
+                Layout.fillWidth: true
+                text: root.modelData.title
+                color: {
+                    if (root.modelData.type === Toast.Success)
+                        return DynamicColors.palette.m3onSuccessContainer;
+                    if (root.modelData.type === Toast.Warning)
+                        return DynamicColors.palette.m3onSecondary;
+                    if (root.modelData.type === Toast.Error)
+                        return DynamicColors.palette.m3onErrorContainer;
+                    return DynamicColors.palette.m3onSurface;
+                }
+                font.pointSize: Appearance.font.size.normal
+                elide: Text.ElideRight
+            }
+
+            CustomText {
+                Layout.fillWidth: true
+                textFormat: Text.StyledText
+                text: root.modelData.message
+                color: {
+                    if (root.modelData.type === Toast.Success)
+                        return DynamicColors.palette.m3onSuccessContainer;
+                    if (root.modelData.type === Toast.Warning)
+                        return DynamicColors.palette.m3onSecondary;
+                    if (root.modelData.type === Toast.Error)
+                        return DynamicColors.palette.m3onErrorContainer;
+                    return DynamicColors.palette.m3onSurface;
+                }
+                opacity: 0.8
+                elide: Text.ElideRight
+            }
+        }
+    }
+
+    Behavior on border.color {
+        CAnim {}
+    }
+}

Components/Toast/Toasts.qml

@@ -0,0 +1,144 @@
+pragma ComponentBehavior: Bound
+
+import qs.Components
+import qs.Config
+import qs.Modules
+import ZShell
+import Quickshell
+import QtQuick
+
+Item {
+    id: root
+
+    readonly property int spacing: Appearance.spacing.small
+    property bool flag
+
+    implicitWidth: Config.utilities.sizes.toastWidth - Appearance.padding.normal * 2
+    implicitHeight: {
+        let h = -spacing;
+        for (let i = 0; i < repeater.count; i++) {
+            const item = repeater.itemAt(i) as ToastWrapper;
+            if (!item.modelData.closed && !item.previewHidden)
+                h += item.implicitHeight + spacing;
+        }
+        return h;
+    }
+
+    Repeater {
+        id: repeater
+
+        model: ScriptModel {
+            values: {
+                const toasts = [];
+                let count = 0;
+                for (const toast of Toaster.toasts) {
+                    toasts.push(toast);
+                    if (!toast.closed) {
+                        count++;
+                        if (count > Config.utilities.maxToasts)
+                            break;
+                    }
+                }
+                return toasts;
+            }
+            onValuesChanged: root.flagChanged()
+        }
+
+        ToastWrapper {}
+    }
+
+    component ToastWrapper: MouseArea {
+        id: toast
+
+        required property int index
+        required property Toast modelData
+
+        readonly property bool previewHidden: {
+            let extraHidden = 0;
+            for (let i = 0; i < index; i++)
+                if (Toaster.toasts[i].closed)
+                    extraHidden++;
+            return index >= Config.utilities.maxToasts + extraHidden;
+        }
+
+        onPreviewHiddenChanged: {
+            if (initAnim.running && previewHidden)
+                initAnim.stop();
+        }
+
+        opacity: modelData.closed || previewHidden ? 0 : 1
+        scale: modelData.closed || previewHidden ? 0.7 : 1
+
+        anchors.bottomMargin: {
+            root.flag; // Force update
+            let y = 0;
+            for (let i = 0; i < index; i++) {
+                const item = repeater.itemAt(i) as ToastWrapper;
+                if (item && !item.modelData.closed && !item.previewHidden)
+                    y += item.implicitHeight + root.spacing;
+            }
+            return y;
+        }
+
+        anchors.left: parent.left
+        anchors.right: parent.right
+        anchors.bottom: parent.bottom
+        implicitHeight: toastInner.implicitHeight
+
+        acceptedButtons: Qt.LeftButton | Qt.MiddleButton | Qt.RightButton
+        onClicked: modelData.close()
+
+        Component.onCompleted: modelData.lock(this)
+
+        Anim {
+            id: initAnim
+
+            Component.onCompleted: running = !toast.previewHidden
+
+            target: toast
+            properties: "opacity,scale"
+            from: 0
+            to: 1
+            duration: Appearance.anim.durations.expressiveDefaultSpatial
+            easing.bezierCurve: Appearance.anim.curves.expressiveDefaultSpatial
+        }
+
+        ParallelAnimation {
+            running: toast.modelData.closed
+            onStarted: toast.anchors.bottomMargin = toast.anchors.bottomMargin
+            onFinished: toast.modelData.unlock(toast)
+
+            Anim {
+                target: toast
+                property: "opacity"
+                to: 0
+            }
+            Anim {
+                target: toast
+                property: "scale"
+                to: 0.7
+            }
+        }
+
+        ToastItem {
+            id: toastInner
+
+            modelData: toast.modelData
+        }
+
+        Behavior on opacity {
+            Anim {}
+        }
+
+        Behavior on scale {
+            Anim {}
+        }
+
+        Behavior on anchors.bottomMargin {
+            Anim {
+                duration: Appearance.anim.durations.expressiveDefaultSpatial
+                easing.bezierCurve: Appearance.anim.curves.expressiveDefaultSpatial
+            }
+        }
+    }
+}