Merge branch 'main' into module/wifi

Components/ButtonBase.qml

@@ -15,7 +15,7 @@ CustomRect {
 	property color activeOnColor
 	property bool checked
 	property real checkedRadius: Tokens.rounding.medium
-	property real defaultRadius: Tokens.rounding.large
+	property real defaultRadius: Math.min(width, height) / 2
 	property color disabledColor: Qt.alpha(Colors.palette.m3onSurface, 0.1)
 	property color disabledOnColor: Qt.alpha(Colors.palette.m3onSurface, 0.38)
 	property bool fillWidth

Components/CircularIndicator.qml

@@ -34,6 +34,7 @@ BusyIndicator {
 		anchors.fill: parent
 		bgColor: root.bgColor
 		fgColor: root.fgColor
+		hasEndIndicator: false
 		padding: root.padding
 		rotation: manager.rotation
 		startAngle: manager.startFraction * 360
@@ -53,6 +54,7 @@ BusyIndicator {
 		Anim {
 			duration: manager.completeEndDuration * Tokens.anim.durations.scale
 			properties: "opacity,internalStrokeWidth"
+			type: Anim.DefaultEffects
 		}
 	}
 

Components/CustomTextField.qml

@@ -23,6 +23,7 @@ TextFieldBase {
 	property string leadingIcon
 	readonly property int leadingOffset: leadingIcon ? leadingIconLoader.width + leadingIconLoader.anchors.leftMargin : 0
 	property int radius: Tokens.rounding.small
+	property alias sLayer: stateLayer
 	readonly property real smallFontScale: smallFontSize / font.pointSize
 	property int smallFontSize: Tokens.font.size.small
 	property string supportingText
@@ -145,6 +146,7 @@ TextFieldBase {
 
 			sourceComponent: MaterialIcon {
 				color: Colors.palette.m3onSurfaceVariant
+				font.pointSize: Tokens.font.size.larger
 				text: root.leadingIcon
 			}
 		}

Drawers/Interactions.qml

@@ -216,7 +216,7 @@ Item {
 				}
 			}
 
-			if (Config.dock.enable && Config.dock.hoverToReveal && !root.visibilities.dock && !root.visibilities.launcher && root.inBottomPanel(root.panels.dock, x, y))
+			if (Config.dock.enabled && Config.dock.hoverToReveal && !root.visibilities.dock && !root.visibilities.launcher && root.inBottomPanel(root.panels.dock, x, y))
 				root.visibilities.dock = true;
 
 			if (y < root.bar.implicitHeight)

Drawers/Windows.qml

@@ -8,6 +8,7 @@ import Quickshell.Io
 import Quickshell.Wayland
 import Quickshell.Hyprland
 import ZShell.Blobs
+import qs.Modules.SysTray.Popouts.Network as N
 import qs.Daemons
 import qs.Components
 import qs.Modules.Bar
@@ -129,7 +130,17 @@ CustomWindow {
 	HyprlandFocusGrab {
 		id: focusGrab
 
-		active: visibilities.dock || visibilities.resources || visibilities.launcher || visibilities.sidebar || visibilities.dashboard || visibilities.settings || visibilities.clipboard || (panels.popouts.hasCurrent && panels.popouts.currentName.startsWith("traymenu") && (!Config.bar.tray.showOnHover || (panels.popouts.current as StackView)?.depth > 1))
+		active: {
+			const v = visibilities;
+			const conf = Config;
+			if (!N.PopupManager.closed && panels.popouts.hasCurrent)
+				return true;
+			if ((v.launcher && conf.launcher.enabled) || (v.sidebar && conf.sidebar.enabled) || (v.resources && conf.dashboard.performance.enabled) || (v.dashboard && conf.dashboard.enabled) || v.settings || (v.clipboard && conf.clipboard.enabled) || (v.dock && conf.dock.enabled))
+				return true;
+			if (panels.popouts.hasCurrent && panels.popouts.currentName.startsWith("traymenu") && (!conf.bar.tray.showOnHover || (panels.popouts.current as StackView)?.depth > 1))
+				return true;
+			return false;
+		}
 		windows: [root]
 
 		onCleared: {

Helpers/Icons.qml

@@ -3,7 +3,6 @@ pragma Singleton
 import ZShell.Config
 import Quickshell
 import Quickshell.Services.Notifications
-import QtQuick
 
 Singleton {
 	id: root
@@ -78,16 +77,6 @@ Singleton {
 			"99": "thunderstorm"
 		})
 
-	function getAppCategoryIcon(name: string, fallback: string): string {
-		const categories = DesktopEntries.heuristicLookup(name)?.categories;
-
-		if (categories)
-			for (const [key, value] of Object.entries(categoryIcons))
-				if (categories.includes(key))
-					return value;
-		return fallback;
-	}
-
 	function getAppIcon(name: string, fallback: string): string {
 		const icon = DesktopEntries.heuristicLookup(name)?.icon;
 		if (fallback !== "undefined")
@@ -95,6 +84,15 @@ Singleton {
 		return Quickshell.iconPath(icon);
 	}
 
+	function getBatteryIcon(percentage: real, charging = false): string {
+		if (percentage === 1)
+			return charging ? "battery_charging_full" : "battery_full";
+		let level = Math.floor(percentage * 7);
+		if (charging && (level === 4 || level === 1))
+			level--;
+		return charging ? `battery_charging_${(level + 3) * 10}` : `battery_${level}_bar`;
+	}
+
 	function getBluetoothIcon(icon: string): string {
 		if (icon.includes("headset") || icon.includes("headphones"))
 			return "headphones";

Helpers/Network.qml

@@ -0,0 +1,114 @@
+pragma Singleton
+
+import Quickshell
+import Quickshell.Networking
+import QtQuick
+
+Singleton {
+	id: root
+
+	property bool active: false
+	readonly property list<Network> connectedNetworks: networks.filter(n => n.connected)
+	property Network connectingNetwork
+	readonly property list<NetworkDevice> devices: Networking.devices.values
+	property Network failedNetwork
+	readonly property list<Network> knownNetworks: networks.filter(n => n.known && !n.connected)
+	readonly property list<Network> networks: {
+		const list = [];
+		for (const d of wifiDevices) {
+			for (const n of d.networks.values) {
+				if (!list.includes(n))
+					list.push(n);
+			}
+		}
+		return list;
+	}
+	property bool scanning: false
+	readonly property list<Network> unknownNetworks: networks.filter(n => !n.known)
+	readonly property list<WifiDevice> wifiDevices: devices.filter(d => wifiDevice(d))
+	readonly property bool wifiEnabled: Networking.wifiEnabled
+
+	signal networkConnected
+
+	function isSecure(security): bool {
+		return (security === WifiSecurityType.WpaPsk || security === WifiSecurityType.Wpa2Psk || security === WifiSecurityType.Sae);
+	}
+
+	function requestConnect(network: Network, secret = undefined): void {
+		connectingNetwork = network;
+		if (secret === undefined || secret === "") {
+			network.connect();
+		} else {
+			(network as WifiNetwork).connectWithPsk(secret);
+		}
+	}
+
+	function setScan(value: bool): void {
+		for (const d of wifiDevices) {
+			d.scannerEnabled = value;
+		}
+	}
+
+	function setWifi(value: bool): void {
+		Networking.wifiEnabled = value;
+	}
+
+	function wifiDevice(dev): bool {
+		return dev.type === DeviceType.Wifi;
+	}
+
+	onActiveChanged: {
+		for (const d of wifiDevices)
+			d.scannerEnabled = active;
+	}
+
+	Timer {
+		id: flushFailed
+
+		interval: 5000
+		running: root.failedNetwork
+
+		onTriggered: {
+			root.failedNetwork = null;
+		}
+	}
+
+	Timer {
+		id: checkConnection
+
+		interval: 500
+		repeat: true
+		running: root.connectingNetwork
+
+		onTriggered: {
+			var completedNetwork;
+
+			switch (root.connectingNetwork.state) {
+			case ConnectionState.Connecting:
+				break;
+			case ConnectionState.Connected:
+				completedNetwork = root.connectingNetwork;
+				root.networkConnected();
+				break;
+			case ConnectionState.Disconnected:
+				root.failedNetwork = root.connectingNetwork;
+				completedNetwork = root.connectingNetwork;
+				break;
+			}
+
+			if (completedNetwork) {
+				root.connectingNetwork = null;
+			}
+		}
+	}
+
+	Timer {
+		interval: 10000
+		running: checkConnection.running
+
+		onTriggered: {
+			root.failedNetwork = root.connectingNetwork;
+			root.connectingNetwork = null;
+		}
+	}
+}

Modules/Bar/Bar.qml

@@ -6,7 +6,6 @@ import QtQuick.Layouts
 import qs.Modules
 import ZShell.Config
 import qs.Modules.SysTray
-import qs.Modules.Network
 import qs.Modules.Updates
 
 RowLayout {
@@ -187,15 +186,6 @@ RowLayout {
 				}
 			}
 
-			DelegateChoice {
-				roleValue: "network"
-
-				delegate: EntryWrapper {
-					NetworkWidget {
-					}
-				}
-			}
-
 			DelegateChoice {
 				roleValue: "media"
 

Modules/Bar/BarLoader.qml

@@ -10,7 +10,6 @@ import ZShell.Config
 import qs.Helpers
 import qs.Modules.SysTray
 import qs.Modules.SysTray.Widgets
-import qs.Modules.Network
 
 Item {
 	id: root

Modules/Content.qml

@@ -6,7 +6,6 @@ import QtQuick
 import ZShell.Config
 import qs.Components
 import qs.Modules.WSOverview
-import qs.Modules.Network
 import qs.Modules.SysTray.Popouts
 import qs.Modules.Updates
 
@@ -84,6 +83,13 @@ Item {
 			}
 		}
 
+		Popout {
+			name: "bluetooth"
+
+			sourceComponent: BluetoothPopout {
+			}
+		}
+
 		Popout {
 			name: "updates"
 

Modules/Dock/Wrapper.qml

@@ -12,7 +12,7 @@ Item {
 	property real offsetScale: shouldBeActive ? 0 : 1
 	required property var panels
 	required property ShellScreen screen
-	readonly property bool shouldBeActive: visibilities.dock && Config.dock.enable
+	readonly property bool shouldBeActive: visibilities.dock && Config.dock.enabled
 	required property PersistentProperties visibilities
 
 	anchors.bottomMargin: (-implicitHeight - 5) * offsetScale

Modules/Network/NetworkPopout.qml

@@ -1,36 +0,0 @@
-pragma ComponentBehavior: Bound
-
-import Quickshell
-import Quickshell.Networking
-import QtQuick
-import QtQuick.Layouts
-import qs.Components
-import ZShell.Config
-import qs.Modules
-import qs.Helpers as Helpers
-
-Item {
-	id: root
-
-	required property var wrapper
-
-	ColumnLayout {
-		id: layout
-
-		spacing: 8
-
-		Repeater {
-			model: Helpers.Network.devices
-
-			CustomRadioButton {
-				id: network
-
-				required property NetworkDevice modelData
-
-				checked: Helpers.Network.activeDevice?.name === modelData.name
-				text: modelData.description
-				visible: modelData.name !== "lo"
-			}
-		}
-	}
-}

Modules/Network/NetworkWidget.qml

@@ -1,25 +0,0 @@
-import Quickshell
-import QtQuick
-import QtQuick.Layouts
-import qs.Components
-import qs.Modules
-
-Item {
-	id: root
-
-	anchors.bottom: parent.bottom
-	anchors.top: parent.top
-	implicitWidth: layout.implicitWidth
-
-	RowLayout {
-		id: layout
-
-		anchors.bottom: parent.bottom
-		anchors.top: parent.top
-
-		MaterialIcon {
-			Layout.alignment: Qt.AlignVCenter
-			text: "android_wifi_4_bar"
-		}
-	}
-}

Modules/Settings/Pages/NetworkPage.qml

@@ -0,0 +1,239 @@
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import QtQuick.Layouts
+import Quickshell
+import qs.Modules.Settings.Common
+import qs.Modules.SysTray.Popouts.Network
+import qs.Components
+import qs.Config
+import qs.Helpers
+
+PageBase {
+	id: root
+
+	title: qsTr("Network")
+
+	ColumnLayout {
+		id: networkContent
+
+		anchors.horizontalCenter: parent.horizontalCenter
+		anchors.top: parent.top
+		spacing: Appearance.spacing.extraSmall / 2
+		width: root.cappedWidth
+
+		Toggle {
+			Layout.preferredHeight: visible ? implicitHeight : 0
+			checked: Network.wifiEnabled
+			first: true
+			last: connected.count === 0
+			subtext: qsTr("Toggle WiFi device state")
+			text: checked ? qsTr("Enabled") : qsTr("Disabled")
+
+			onToggled: Network.setWifi(checked)
+		}
+
+		Repeater {
+			id: connected
+
+			visible: Network.connectedNetworks.length > 0
+
+			model: ScriptModel {
+				values: [...Network.connectedNetworks].sort((a, b) => {
+					return b.signalStrength - a.signalStrength;
+				})
+			}
+
+			NetworkItem {
+				first: false
+				known: true
+				repeater: connected
+			}
+		}
+	}
+
+	component NetworkItem: ConnectedRect {
+		id: networkItem
+
+		readonly property bool connecting: Network.connectingNetwork === modelData
+		property int horizontalPadding: Appearance.padding.largeIncreased
+		required property int index
+		readonly property bool isSecure: Network.isSecure(modelData.security)
+		required property bool known
+		required property var modelData
+		required property Repeater repeater
+
+		Layout.fillWidth: true
+		Layout.preferredHeight: visible ? rowLayout.implicitHeight + Appearance.padding.smaller * 2 : 0
+		first: index === 0
+		last: index === (repeater.count - 1)
+		radius: Appearance.rounding.small
+
+		RowLayout {
+			id: rowLayout
+
+			anchors.fill: parent
+			anchors.leftMargin: networkItem.horizontalPadding
+			anchors.rightMargin: networkItem.horizontalPadding
+
+			Column {
+				id: column
+
+				Layout.fillWidth: true
+
+				CustomText {
+					Layout.fillWidth: true
+					Layout.leftMargin: Appearance.spacing.extraSmall
+					Layout.rightMargin: Appearance.spacing.extraSmall
+					color: networkItem.modelData.active ? DynamicColors.palette.m3primary : DynamicColors.palette.m3onSurface
+					elide: Text.ElideRight
+					text: networkItem.modelData.name
+				}
+
+				CustomText {
+					id: subtext
+
+					anchors.left: parent.left
+					anchors.right: parent.right
+					color: DynamicColors.palette.m3outline
+					elide: Text.ElideRight
+					font.pointSize: Appearance.font.size.small
+					text: qsTr("%1 strength").arg(Math.round(networkItem.modelData.signalStrength * 100) + "%")
+				}
+			}
+
+			Item {
+				Layout.alignment: Qt.AlignRight
+				implicitHeight: icon.height
+				implicitWidth: icon.width
+
+				MaterialIcon {
+					id: icon
+
+					color: networkItem.modelData.active ? DynamicColors.palette.m3primary : DynamicColors.palette.m3onSurfaceVariant
+					font.pointSize: Appearance.font.size.large
+					opacity: networkItem.connecting ? 0 : 1
+					text: Icons.getNetworkIcon(networkItem.modelData.signalStrength * 100, networkItem.isSecure)
+
+					Behavior on opacity {
+						Anim {
+						}
+					}
+				}
+
+				Loader {
+					active: opacity > 0
+					anchors.fill: parent
+					opacity: networkItem.connecting ? 1 : 0
+
+					Behavior on opacity {
+						Anim {
+						}
+					}
+					sourceComponent: CircularIndicator {
+						bgColor: "transparent"
+						running: true
+					}
+				}
+			}
+		}
+
+		StateLayer {
+			color: networkItem.modelData.active ? DynamicColors.palette.m3onPrimary : DynamicColors.palette.m3onSurface
+
+			onClicked: {
+				if (networkItem.isSecure && !networkItem.known) {
+					PopupManager.requestOpen(Qt.resolvedUrl("Network/PSKOverlay.qml"), {
+						network: networkItem.modelData
+					});
+				} else {
+					Network.requestConnect(networkItem.modelData);
+				}
+			}
+		}
+	}
+	component Spacer: Item {
+		id: spacer
+
+		required property Repeater repeater
+
+		Layout.preferredHeight: repeater.count > 0 ? Appearance.spacing.extraSmall : 0
+	}
+	component Toggle: CustomSwitch {
+		id: toggleItem
+
+		readonly property alias bg: bg
+		property alias first: bg.first
+		property alias last: bg.last
+		property string subtext
+
+		Layout.fillWidth: true
+		cLayer: 2
+		horizontalPadding: Appearance.padding.largeIncreased
+		implicitHeight: Math.max(implicitContentHeight, implicitIndicatorHeight) + verticalPadding * 2
+		implicitWidth: implicitContentWidth + implicitIndicatorWidth + horizontalPadding * 2
+		indicator.anchors.right: right
+		indicator.anchors.rightMargin: toggleItem.horizontalPadding
+		indicator.anchors.verticalCenter: verticalCenter
+		verticalPadding: Appearance.padding.normal
+
+		background: ConnectedRect {
+			id: bg
+
+			StateLayer {
+				id: stateLayer
+
+				manualPressOverride: toggleItem.pressed
+			}
+		}
+		contentItem: Item {
+			anchors.left: parent.left
+			anchors.leftMargin: toggleItem.horizontalPadding
+			anchors.right: toggleItem.indicator.left
+			anchors.rightMargin: Appearance.spacing.normal
+			implicitHeight: column.implicitHeight
+			implicitWidth: column.implicitWidth
+
+			Column {
+				id: column
+
+				anchors.left: parent.left
+				anchors.right: parent.right
+				anchors.verticalCenter: parent.verticalCenter
+				spacing: 0
+
+				CustomText {
+					id: label
+
+					anchors.left: parent.left
+					anchors.right: parent.right
+					elide: Text.ElideRight
+					font: {
+						const f = Qt.font(label.font);
+						f.pointSize = Appearance.font.size.smaller;
+						return f;
+					}
+					text: toggleItem.text
+				}
+
+				CustomText {
+					id: subtext
+
+					anchors.left: parent.left
+					anchors.right: parent.right
+					color: DynamicColors.palette.m3outline
+					elide: Text.ElideRight
+					font: {
+						const f = Qt.font(subtext.font);
+						f.pointSize = Appearance.font.size.small;
+						return f;
+					}
+					text: toggleItem.subtext
+					visible: toggleItem.subtext
+				}
+			}
+		}
+
+		onPressed: stateLayer.press(stateLayer.mouseX, stateLayer.mouseY)
+	}
+}

Modules/Settings/Pages/Panels/Bar/BarStatusIcons.qml

@@ -8,7 +8,9 @@ PageBase {
 	readonly property var builtinIcons: ({
 			audio: qsTr("Speakers"),
 			microphone: qsTr("Microphone"),
-			power: qsTr("Battery")
+			power: qsTr("Battery"),
+			network: qsTr("Network"),
+			bluetooth: qsTr("Bluetooth")
 		})
 
 	isSubPage: true
@@ -91,5 +93,15 @@ PageBase {
 
 			onToggled: Config.bar.popouts.statusIcons = checked
 		}
+
+		ToggleRow {
+			checked: Config.bar.popouts.network
+			last: true
+			settingAnchor: "bar-status-network-popout"
+			subtext: qsTr("Show a details popout when hovering the network icon")
+			text: qsTr("Network popout on hover")
+
+			onToggled: Config.bar.popouts.network = checked
+		}
 	}
 }

Modules/SysTray/Popouts/BluetoothPopout.qml

@@ -0,0 +1,388 @@
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import QtQuick.Layouts
+import QtQml.Models
+import Quickshell
+import Quickshell.Bluetooth
+import ZShell.Components
+import ZShell.Config
+import qs.Services
+import qs.Components
+import qs.Helpers
+
+CustomClippingRect {
+	id: root
+
+	implicitHeight: layout.implicitHeight + layout.anchors.margins * 2
+	implicitWidth: 500
+
+	ColumnLayout {
+		id: layout
+
+		anchors.fill: parent
+		anchors.margins: Tokens.padding.larger
+		spacing: Tokens.spacing.extraSmall / 2
+
+		CustomText {
+			Layout.rightMargin: Tokens.padding.extraSmall
+			Layout.topMargin: Tokens.padding.normal
+			font.pointSize: Tokens.font.size.large
+			text: qsTr("Bluetooth")
+		}
+
+		Toggle {
+			checked: Bluetooth.defaultAdapter?.enabled ?? false // qmllint disable unresolved-type
+			first: true
+			subtext: qsTr("Toggle bluetooth device state")
+			text: checked ? qsTr("Enabled") : qsTr("Disabled")
+
+			onToggled: {
+				const adapter = Bluetooth.defaultAdapter; // qmllint disable unresolved-type
+				if (adapter)
+					adapter.enabled = checked;
+			}
+		}
+
+		Toggle {
+			checked: Bluetooth.defaultAdapter?.discovering ?? false // qmllint disable unresolved-type
+			last: rows.sortedConnected.length === 0
+			subtext: qsTr("Enable scanning for new devices")
+			text: qsTr("Discover")
+
+			onToggled: {
+				const adapter = Bluetooth.defaultAdapter; // qmllint disable unresolved-type
+				if (adapter)
+					adapter.discovering = checked;
+			}
+		}
+
+		ListView {
+			id: rows
+
+			readonly property var sortedConnected: {
+				const byName = (a, b) => a.name.localeCompare(b.name);
+				return [...Bluetooth.devices.values].filter(d => d.connected).sort(byName).slice(0, 5);
+			}
+
+			Layout.fillWidth: true
+			Layout.preferredHeight: contentHeight
+			interactive: false
+			section.property: "connected"
+			spacing: Tokens.spacing.extraSmall / 2
+
+			add: Transition {
+				Anim {
+					from: 0
+					property: "opacity"
+					to: 1
+				}
+			}
+			delegate: DelegateChooser {
+				role: "isDivider"
+
+				DelegateChoice {
+					roleValue: true
+
+					delegate: StatusDivider {
+					}
+				}
+
+				DelegateChoice {
+					delegate: BluetoothItem {
+						list: rows
+						width: rows.width
+					}
+				}
+			}
+			displaced: Transition {
+				Anim {
+					easing.type: Easing.OutCubic
+					property: "y"
+				}
+			}
+			model: ScriptModel {
+				objectProp: "address"
+				values: {
+					const byName = (a, b) => a.name.localeCompare(b.name);
+					return [...[...Bluetooth.devices.values].filter(d => d.connected).sort(byName).slice(0, 5),
+						{
+							isDivider: true
+						},
+						...[...Bluetooth.devices.values].filter(d => !d.connected).sort(byName).slice(0, 5)];
+				}
+			}
+			move: Transition {
+				Anim {
+					easing.type: Easing.OutCubic
+					property: "y"
+				}
+			}
+			remove: Transition {
+				Anim {
+					property: "opacity"
+					to: 0
+				}
+			}
+			section.delegate: Rectangle {
+				required property string section
+
+				color: "transparent"
+				height: childrenRect.height
+				width: ListView.view.width
+
+				CustomText {
+					text: parent.section
+				}
+			}
+		}
+	}
+
+	component BluetoothItem: ConnectedRect {
+		id: btItem
+
+		readonly property int connectedCount: rows.sortedConnected.length
+		readonly property bool connecting: Network.connectingNetwork === modelData
+		property int horizontalPadding: Tokens.padding.largeIncreased
+		readonly property bool inConnectedGroup: index < connectedCount
+		required property int index
+		required property ListView list
+		readonly property bool loading: modelData.state === BluetoothDeviceState.Connecting || modelData.state === BluetoothDeviceState.Disconnecting // qmllint disable unresolved-type
+
+		required property BluetoothDevice modelData
+		property int verticalPadding: Tokens.padding.smaller
+
+		first: !inConnectedGroup && index === connectedCount + 1
+		implicitHeight: rowLayout.implicitHeight + verticalPadding * 2
+		last: inConnectedGroup ? index === connectedCount - 1 : index === list.count - 1
+		radius: Tokens.rounding.small
+
+		Timer {
+			interval: 50
+			running: btItem.ListView.delayRemove
+
+			onTriggered: btItem.ListView.delayRemove = false
+		}
+
+		Connections {
+			function onConnectedChanged(): void {
+				if (!btItem.modelData.connected)
+					btItem.ListView.delayRemove = true;
+			}
+
+			function onPairedChanged(): void {
+				if (btItem.modelData.paired)
+					btItem.modelData.connect();
+			}
+
+			target: btItem.modelData
+		}
+
+		RowLayout {
+			id: rowLayout
+
+			anchors.fill: parent
+			anchors.leftMargin: btItem.horizontalPadding
+			anchors.rightMargin: btItem.horizontalPadding
+
+			Column {
+				id: column
+
+				Layout.fillWidth: true
+
+				CustomText {
+					Layout.fillWidth: true
+					Layout.leftMargin: Tokens.spacing.extraSmall
+					Layout.rightMargin: Tokens.spacing.extraSmall
+					elide: Text.ElideRight
+					text: btItem.modelData.name
+				}
+
+				CustomText {
+					id: subtext
+
+					anchors.left: parent.left
+					anchors.right: parent.right
+					color: Colors.palette.m3outline
+					elide: Text.ElideRight
+					font.pointSize: Tokens.font.size.small
+					text: btItem.modelData.connected ? (btItem.modelData.batteryAvailable ? qsTr("%1 battery left").arg(Math.round(btItem.modelData.battery * 100) + "%") : qsTr("Battery status unknown")) : btItem.modelData.address
+				}
+			}
+
+			Item {
+				Layout.alignment: Qt.AlignRight
+				implicitHeight: icon.height
+				implicitWidth: icon.width
+
+				MaterialIcon {
+					id: icon
+
+					font.pointSize: Tokens.font.size.large
+					opacity: btItem.connecting ? 0 : 1
+					text: btItem.modelData.batteryAvailable ? Icons.getBatteryIcon(btItem.modelData.battery) : "battery_unknown"
+					visible: btItem.modelData.state === BluetoothDeviceState.Connected  // qmllint disable unresolved-type
+
+					Behavior on opacity {
+						Anim {
+						}
+					}
+				}
+
+				Loader {
+					active: opacity > 0
+					anchors.fill: parent
+					opacity: btItem.connecting ? 1 : 0
+
+					Behavior on opacity {
+						Anim {
+						}
+					}
+					sourceComponent: CircularIndicator {
+						bgColor: "transparent"
+						running: true
+					}
+				}
+			}
+
+			ButtonRow {
+				spacing: Tokens.spacing.small
+
+				IconTextButton {
+					font.pointSize: Tokens.font.size.small
+					icon: btItem.modelData.connected ? "link_off" : btItem.modelData.paired ? "link" : "add_link"
+					text: btItem.modelData.connected ? qsTr("Disconnect") : btItem.modelData.paired ? qsTr("Connect") : qsTr("Pair")
+
+					onClicked: {
+						if (btItem.modelData.connected)
+							btItem.modelData.disconnect();
+						else if (btItem.modelData.paired)
+							btItem.modelData.connect();
+						else if (!btItem.modelData.paired)
+							btItem.modelData.pair();
+						else if (btItem.modelData.pairing)
+							btItem.modelData.cancelPair();
+					}
+				}
+			}
+		}
+	}
+	component ConnectedRect: CustomRect {
+		id: bg
+
+		property bool first
+		property bool last
+
+		bottomLeftRadius: last ? Tokens.rounding.large : Tokens.rounding.extraSmall
+		bottomRightRadius: last ? Tokens.rounding.large : Tokens.rounding.extraSmall
+		color: Colors.tPalette.m3surfaceContainer
+		topLeftRadius: first ? Tokens.rounding.large : Tokens.rounding.extraSmall
+		topRightRadius: first ? Tokens.rounding.large : Tokens.rounding.extraSmall
+
+		Behavior on bottomLeftRadius {
+			Anim {
+			}
+		}
+		Behavior on bottomRightRadius {
+			Anim {
+			}
+		}
+		Behavior on topLeftRadius {
+			Anim {
+			}
+		}
+		Behavior on topRightRadius {
+			Anim {
+			}
+		}
+	}
+	component StatusDivider: CustomText {
+		bottomPadding: Tokens.spacing.extraSmall
+		color: Colors.palette.m3onSurfaceVariant
+		font.pointSize: Tokens.font.size.smaller
+		text: {
+			const devices = Bluetooth.devices.values; // qmllint disable unresolved-type
+			const connectedCount = devices.filter(d => d.connected).length;
+			let available = qsTr("%1 device%2 available").arg(devices.length - connectedCount).arg(devices.length === 1 ? "" : "s");
+			return available;
+		}
+		topPadding: Tokens.spacing.small
+	}
+	component Toggle: CustomSwitch {
+		id: toggleItem
+
+		readonly property alias bg: bg
+		property alias first: bg.first
+		property alias last: bg.last
+		property string subtext
+
+		Layout.fillWidth: true
+		cLayer: 2
+		horizontalPadding: Tokens.padding.largeIncreased
+		implicitHeight: Math.max(implicitContentHeight, implicitIndicatorHeight) + verticalPadding * 2
+		implicitWidth: implicitContentWidth + implicitIndicatorWidth + horizontalPadding * 2
+		indicator.anchors.right: right
+		indicator.anchors.rightMargin: toggleItem.horizontalPadding
+		indicator.anchors.verticalCenter: verticalCenter
+		verticalPadding: Tokens.padding.normal
+
+		background: ConnectedRect {
+			id: bg
+
+			StateLayer {
+				id: stateLayer
+
+				manualPressOverride: toggleItem.pressed
+			}
+		}
+		contentItem: Item {
+			anchors.left: parent.left
+			anchors.leftMargin: toggleItem.horizontalPadding
+			anchors.right: toggleItem.indicator.left
+			anchors.rightMargin: Tokens.spacing.normal
+			implicitHeight: column.implicitHeight
+			implicitWidth: column.implicitWidth
+
+			Column {
+				id: column
+
+				anchors.left: parent.left
+				anchors.right: parent.right
+				anchors.verticalCenter: parent.verticalCenter
+				spacing: 0
+
+				CustomText {
+					id: label
+
+					anchors.left: parent.left
+					anchors.right: parent.right
+					elide: Text.ElideRight
+					font: {
+						const f = Qt.font(label.font);
+						f.pointSize = Tokens.font.size.smaller;
+						return f;
+					}
+					text: toggleItem.text
+				}
+
+				CustomText {
+					id: subtext
+
+					anchors.left: parent.left
+					anchors.right: parent.right
+					color: Colors.palette.m3outline
+					elide: Text.ElideRight
+					font: {
+						const f = Qt.font(subtext.font);
+						f.pointSize = Tokens.font.size.small;
+						return f;
+					}
+					text: toggleItem.subtext
+					visible: toggleItem.subtext
+				}
+			}
+		}
+
+		onPressed: stateLayer.press(stateLayer.mouseX, stateLayer.mouseY)
+	}
+}

Modules/SysTray/Popouts/Network/NetworkOverlay.qml

@@ -0,0 +1,71 @@
+import QtQuick
+import ZShell.Config
+import qs.Services
+import qs.Helpers
+import qs.Components
+
+CustomRect {
+	id: root
+
+	readonly property bool closing: PopupManager.closed
+	readonly property url currentPopup: PopupManager.currentPopup
+	property bool shouldBeVisible: loader.status === Loader.Ready
+
+	color: Qt.alpha(Colors.palette.m3shadow, 0.3)
+	opacity: shouldBeVisible && !closing ? 1 : 0
+	visible: opacity > 0
+
+	Behavior on opacity {
+		Anim {
+		}
+	}
+
+	onVisibleChanged: {
+		if (!visible) {
+			PopupManager.requestClose();
+			PopupManager.currentPopup = "";
+		}
+	}
+
+	CustomMouseArea {
+		anchors.fill: parent
+		hoverEnabled: true
+		preventStealing: true
+		propagateComposedEvents: false
+
+		onClicked: {
+			const insideItemWidth = mouseX < loader.x + loader.item.width && mouseX > loader.x;
+			const insideItemHeight = mouseY < loader.y + loader.item.height && mouseY > loader.y;
+			if (insideItemHeight && insideItemWidth)
+				return;
+
+			PopupManager.requestClose();
+		}
+	}
+
+	Loader {
+		id: loader
+
+		anchors.centerIn: parent
+
+		Connections {
+			function onCurrentPopupChanged(): void {
+				if (PopupManager.currentPopup) {
+					loader.setSource(PopupManager.currentPopup, PopupManager.currentPopupProps);
+				} else {
+					loader.source = null;
+				}
+			}
+
+			target: PopupManager
+		}
+	}
+
+	Connections {
+		function onNetworkConnected(): void {
+			PopupManager.requestClose();
+		}
+
+		target: Network
+	}
+}

Modules/SysTray/Popouts/Network/PSKOverlay.qml

@@ -0,0 +1,103 @@
+import Quickshell
+import QtQuick
+import QtQuick.Layouts
+import ZShell.Components
+import ZShell.Config
+import qs.Services
+import qs.Components
+import qs.Helpers
+
+CustomClippingRect {
+	id: root
+
+	required property var network
+
+	color: Colors.palette.m3surfaceContainer
+	implicitHeight: layout.implicitHeight + layout.anchors.margins * 2
+	implicitWidth: layout.implicitWidth + layout.anchors.margins * 2
+	radius: Tokens.rounding.large
+
+	ColumnLayout {
+		id: layout
+
+		anchors.fill: parent
+		anchors.margins: Tokens.padding.extraLarge
+		spacing: Tokens.spacing.normal
+
+		MaterialIcon {
+			Layout.alignment: Qt.AlignHCenter
+			font.pointSize: Tokens.font.size.extraLarge * 2
+			text: "lock"
+		}
+
+		CustomText {
+			Layout.alignment: Qt.AlignHCenter
+			color: Colors.palette.m3onSurfaceVariant
+			text: qsTr("Connect to %1").arg(root.network.name)
+		}
+
+		CustomTextField {
+			id: passwordField
+
+			Layout.fillWidth: true
+			Layout.preferredWidth: 400
+			echoMode: CustomTextField.Password
+			errorText: qsTr("Failed to connect with given password")
+			isError: Network.failedNetwork
+			leadingIcon: "lock"
+			passwordMaskDelay: 5000
+			placeholderText: qsTr("Input password")
+		}
+
+		ButtonRow {
+			id: buttonRow
+
+			Layout.fillWidth: true
+			spacing: Tokens.spacing.smaller
+
+			IconTextButton {
+				fillWidth: true
+				font.pointSize: Tokens.font.size.normal
+				icon: "close"
+				inactiveColor: Colors.layer(Colors.palette.m3surfaceContainerHighest, 2)
+				inactiveOnColor: Colors.palette.m3onSurfaceVariant
+				isRound: true
+				isToggle: false
+				shapeMorph: true
+				text: "Cancel"
+
+				onClicked: PopupManager.requestClose()
+			}
+
+			IconTextButton {
+				fillWidth: true
+				font.pointSize: Tokens.font.size.normal
+				icon: Network.connectingNetwork ? "" : "check"
+				inactiveColor: Network.connectingNetwork ? Colors.palette.m3primaryContainer : Network.failedNetwork ? Colors.palette.m3error : Colors.palette.m3primary
+				inactiveOnColor: Network.connectingNetwork ? Colors.palette.m3onPrimaryContainer : Network.failedNetwork ? Colors.palette.m3onError : Colors.palette.m3onPrimary
+				isRound: true
+				isToggle: false
+				shapeMorph: true
+				text: Network.connectingNetwork ? "" : "Apply"
+
+				onClicked: Network.requestConnect(root.network, passwordField.text)
+
+				Loader {
+					active: opacity > 0
+					anchors.centerIn: parent
+					opacity: Network.connectingNetwork ? 1 : 0
+
+					Behavior on opacity {
+						Anim {
+						}
+					}
+					sourceComponent: CircularIndicator {
+						bgColor: "transparent"
+						implicitSize: buttonRow.height - Tokens.padding.normal
+						running: true
+					}
+				}
+			}
+		}
+	}
+}

Modules/SysTray/Popouts/Network/PopupManager.qml

@@ -0,0 +1,22 @@
+pragma Singleton
+
+import Quickshell
+import QtQuick
+
+Singleton {
+	id: root
+
+	property bool closed: true
+	property url currentPopup: ""
+	property var currentPopupProps: ({})
+
+	function requestClose(): void {
+		closed = true;
+	}
+
+	function requestOpen(source: url, properties = {}): void {
+		currentPopupProps = properties;
+		currentPopup = source;
+		closed = false;
+	}
+}

Modules/SysTray/Popouts/NetworkPopout.qml

@@ -0,0 +1,342 @@
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import QtQuick.Layouts
+import Quickshell
+import ZShell.Config
+import qs.Services
+import qs.Modules.SysTray.Popouts.Network
+import qs.Components
+import qs.Helpers
+
+CustomClippingRect {
+	id: root
+
+	required property var wrapper
+
+	anchors.horizontalCenter: parent.horizontalCenter
+	implicitHeight: networkPopContent.height + networks.implicitHeight + networkPopContent.anchors.margins + networks.anchors.margins * 2
+	implicitWidth: 500 + 8 * 2
+	radius: (20 - Tokens.padding.small) * Tokens.rounding.scale
+
+	Component.onCompleted: Network.active = true
+	Component.onDestruction: Network.active = false
+
+	ColumnLayout {
+		id: networkPopContent
+
+		anchors.left: parent.left
+		anchors.margins: Tokens.padding.large
+		anchors.right: parent.right
+		anchors.top: parent.top
+		spacing: Tokens.spacing.extraSmall / 2
+
+		CustomText {
+			Layout.preferredHeight: visible ? implicitHeight : 0
+			Layout.rightMargin: Tokens.padding.extraSmall
+			font.pointSize: Tokens.font.size.large
+			text: qsTr("Wifi")
+		}
+
+		Toggle {
+			Layout.preferredHeight: visible ? implicitHeight : 0
+			checked: Network.wifiEnabled
+			first: true
+			last: connected.count === 0
+			subtext: qsTr("Toggle WiFi device state")
+			text: checked ? qsTr("Enabled") : qsTr("Disabled")
+
+			onToggled: Network.setWifi(checked)
+		}
+
+		Repeater {
+			id: connected
+
+			visible: Network.connectedNetworks.length > 0
+
+			model: ScriptModel {
+				values: [...Network.connectedNetworks].sort((a, b) => {
+					return b.signalStrength - a.signalStrength;
+				})
+			}
+
+			NetworkItem {
+				first: false
+				known: true
+				repeater: connected
+			}
+		}
+	}
+
+	ColumnLayout {
+		id: networks
+
+		anchors.bottom: parent.bottom
+		anchors.left: parent.left
+		anchors.margins: Tokens.padding.large
+		anchors.right: parent.right
+		anchors.top: networkPopContent.bottom
+		spacing: Tokens.spacing.extraSmall / 2
+
+		Spacer {
+			repeater: known
+			visible: Network.connectedNetworks.length > 0
+		}
+
+		CustomText {
+			Layout.leftMargin: Tokens.padding.normal
+			Layout.preferredHeight: visible ? implicitHeight : 0
+			color: Colors.palette.m3onSurfaceVariant
+			font.pointSize: Tokens.font.size.small
+			text: Network.knownNetworks.length > 1 ? qsTr("%1 known networks available").arg(Network.knownNetworks.length) : qsTr("1 known network available") // qmllint disable missing-property
+			visible: Network.knownNetworks.length > 0
+		}
+
+		Repeater {
+			id: known
+
+			visible: Network.knownNetworks.length > 0
+
+			model: ScriptModel {
+				values: [...Network.knownNetworks].sort((a, b) => {
+					return b.signalStrength - a.signalStrength;
+				})
+			}
+
+			NetworkItem {
+				known: true
+				repeater: known
+			}
+		}
+
+		Spacer {
+			repeater: unknown
+			visible: Network.knownNetworks.length > 0
+		}
+
+		CustomText {
+			Layout.leftMargin: Tokens.padding.normal
+			Layout.preferredHeight: visible ? implicitHeight : 0
+			color: Colors.palette.m3onSurfaceVariant
+			font.pointSize: Tokens.font.size.small
+			text: Network.unknownNetworks.length > 1 ? qsTr("%1 networks available").arg(Network.unknownNetworks.length) : qsTr("1 network available") // qmllint disable missing-property
+			visible: Network.unknownNetworks.length > 0
+		}
+
+		Repeater {
+			id: unknown
+
+			model: ScriptModel {
+				values: [...Network.unknownNetworks].sort((a, b) => {
+					return b.signalStrength - a.signalStrength;
+				})
+			}
+
+			NetworkItem {
+				known: false
+				repeater: unknown
+			}
+		}
+	}
+
+	NetworkOverlay {
+		anchors.fill: parent
+	}
+
+	component ConnectedRect: CustomRect {
+		id: bg
+
+		property bool first
+		property bool last
+
+		bottomLeftRadius: last ? Tokens.rounding.large : Tokens.rounding.extraSmall
+		bottomRightRadius: last ? Tokens.rounding.large : Tokens.rounding.extraSmall
+		color: Colors.tPalette.m3surfaceContainer
+		topLeftRadius: first ? Tokens.rounding.large : Tokens.rounding.extraSmall
+		topRightRadius: first ? Tokens.rounding.large : Tokens.rounding.extraSmall
+	}
+	component NetworkItem: ConnectedRect {
+		id: networkItem
+
+		readonly property bool connecting: Network.connectingNetwork === modelData
+		property int horizontalPadding: Tokens.padding.largeIncreased
+		required property int index
+		readonly property bool isSecure: Network.isSecure(modelData.security)
+		required property bool known
+		required property var modelData
+		required property Repeater repeater
+
+		Layout.fillWidth: true
+		Layout.preferredHeight: visible ? rowLayout.implicitHeight + Tokens.padding.smaller * 2 : 0
+		first: index === 0
+		last: index === (repeater.count - 1)
+		radius: Tokens.rounding.small
+
+		RowLayout {
+			id: rowLayout
+
+			anchors.fill: parent
+			anchors.leftMargin: networkItem.horizontalPadding
+			anchors.rightMargin: networkItem.horizontalPadding
+
+			Column {
+				id: column
+
+				Layout.fillWidth: true
+
+				CustomText {
+					Layout.fillWidth: true
+					Layout.leftMargin: Tokens.spacing.extraSmall
+					Layout.rightMargin: Tokens.spacing.extraSmall
+					color: networkItem.modelData.active ? Colors.palette.m3primary : Colors.palette.m3onSurface
+					elide: Text.ElideRight
+					text: networkItem.modelData.name
+				}
+
+				CustomText {
+					id: subtext
+
+					anchors.left: parent.left
+					anchors.right: parent.right
+					color: Colors.palette.m3outline
+					elide: Text.ElideRight
+					font.pointSize: Tokens.font.size.small
+					text: qsTr("%1 strength").arg(Math.round(networkItem.modelData.signalStrength * 100) + "%")
+				}
+			}
+
+			Item {
+				Layout.alignment: Qt.AlignRight
+				implicitHeight: icon.height
+				implicitWidth: icon.width
+
+				MaterialIcon {
+					id: icon
+
+					color: networkItem.modelData.active ? Colors.palette.m3primary : Colors.palette.m3onSurfaceVariant
+					font.pointSize: Tokens.font.size.large
+					opacity: networkItem.connecting ? 0 : 1
+					text: Icons.getNetworkIcon(networkItem.modelData.signalStrength * 100, networkItem.isSecure)
+
+					Behavior on opacity {
+						Anim {
+						}
+					}
+				}
+
+				Loader {
+					active: opacity > 0
+					anchors.fill: parent
+					opacity: networkItem.connecting ? 1 : 0
+
+					Behavior on opacity {
+						Anim {
+						}
+					}
+					sourceComponent: CircularIndicator {
+						bgColor: "transparent"
+						running: true
+					}
+				}
+			}
+		}
+
+		StateLayer {
+			color: networkItem.modelData.active ? Colors.palette.m3onPrimary : Colors.palette.m3onSurface
+
+			onClicked: {
+				if (networkItem.isSecure && !networkItem.known) {
+					PopupManager.requestOpen(Qt.resolvedUrl("Network/PSKOverlay.qml"), {
+						network: networkItem.modelData
+					});
+				} else {
+					Network.requestConnect(networkItem.modelData);
+				}
+			}
+		}
+	}
+	component Spacer: Item {
+		id: spacer
+
+		required property Repeater repeater
+
+		Layout.preferredHeight: repeater.count > 0 ? Tokens.spacing.extraSmall : 0
+	}
+	component Toggle: CustomSwitch {
+		id: toggleItem
+
+		readonly property alias bg: bg
+		property alias first: bg.first
+		property alias last: bg.last
+		property string subtext
+
+		Layout.fillWidth: true
+		cLayer: 2
+		horizontalPadding: Tokens.padding.largeIncreased
+		implicitHeight: Math.max(implicitContentHeight, implicitIndicatorHeight) + verticalPadding * 2
+		implicitWidth: implicitContentWidth + implicitIndicatorWidth + horizontalPadding * 2
+		indicator.anchors.right: right
+		indicator.anchors.rightMargin: toggleItem.horizontalPadding
+		indicator.anchors.verticalCenter: verticalCenter
+		verticalPadding: Tokens.padding.normal
+
+		background: ConnectedRect {
+			id: bg
+
+			StateLayer {
+				id: stateLayer
+
+				manualPressOverride: toggleItem.pressed
+			}
+		}
+		contentItem: Item {
+			anchors.left: parent.left
+			anchors.leftMargin: toggleItem.horizontalPadding
+			anchors.right: toggleItem.indicator.left
+			anchors.rightMargin: Tokens.spacing.normal
+			implicitHeight: column.implicitHeight
+			implicitWidth: column.implicitWidth
+
+			Column {
+				id: column
+
+				anchors.left: parent.left
+				anchors.right: parent.right
+				anchors.verticalCenter: parent.verticalCenter
+				spacing: 0
+
+				CustomText {
+					id: label
+
+					anchors.left: parent.left
+					anchors.right: parent.right
+					elide: Text.ElideRight
+					font: {
+						const f = Qt.font(label.font);
+						f.pointSize = Tokens.font.size.smaller;
+						return f;
+					}
+					text: toggleItem.text
+				}
+
+				CustomText {
+					id: subtext
+
+					anchors.left: parent.left
+					anchors.right: parent.right
+					color: Colors.palette.m3outline
+					elide: Text.ElideRight
+					font: {
+						const f = Qt.font(subtext.font);
+						f.pointSize = Tokens.font.size.small;
+						return f;
+					}
+					text: toggleItem.subtext
+					visible: toggleItem.subtext
+				}
+			}
+		}
+
+		onPressed: stateLayer.press(stateLayer.mouseX, stateLayer.mouseY)
+	}
+}

Modules/SysTray/StatusIcons.qml

@@ -84,6 +84,28 @@ CustomClippingRect {
 					}
 				}
 
+				DelegateChoice {
+					roleValue: "bluetooth"
+
+					delegate: EntryWrapper {
+						name: "bluetooth"
+
+						BluetoothWidget {
+						}
+					}
+				}
+
+				DelegateChoice {
+					roleValue: "network"
+
+					delegate: EntryWrapper {
+						name: "network"
+
+						NetworkWidget {
+						}
+					}
+				}
+
 				DelegateChoice {
 					roleValue: "power"
 

Modules/SysTray/TrayWidget.qml

@@ -53,6 +53,11 @@ RowLayout {
 						id: "audio",
 						item: child
 					};
+				if (child.objectName === "networkWidget" && Config.bar.popouts.network)
+					return {
+						id: "network",
+						item: child
+					};
 				if (child.objectName === "microphone" && Config.bar.popouts.audio)
 					return {
 						id: "audio",
@@ -63,6 +68,11 @@ RowLayout {
 						id: "upower",
 						item: child
 					};
+				if (child.objectName === "bluetoothWidget")
+					return {
+						id: "bluetooth",
+						item: child
+					};
 			}
 		}
 

Modules/SysTray/Widgets/BluetoothWidget.qml

@@ -0,0 +1,14 @@
+import QtQuick
+import QtQuick.Layouts
+import ZShell.Config
+import qs.Services
+import qs.Components
+
+MaterialIcon {
+	Layout.alignment: Qt.AlignVCenter
+	animate: true
+	color: Colors.palette.m3onSurface // Network.connected ? root.textColor : Colors.palette.m3error
+	fill: 1
+	font.pointSize: Tokens.font.size.larger
+	text: "bluetooth"
+}

Modules/SysTray/Widgets/NetworkWidget.qml

@@ -0,0 +1,14 @@
+import QtQuick
+import QtQuick.Layouts
+import ZShell.Config
+import qs.Services
+import qs.Components
+
+MaterialIcon {
+	Layout.alignment: Qt.AlignVCenter
+	animate: true
+	color: Colors.palette.m3onSurface // Network.connected ? root.textColor : Colors.palette.m3error
+	fill: 1
+	font.pointSize: Tokens.font.size.larger
+	text: "android_wifi_4_bar"
+}