pragma ComponentBehavior: Bound

import Quickshell
import QtQuick
import qs.Components
import qs.Config

Item {
	id: root

	readonly property PersistentProperties dashState: PersistentProperties {
		property date currentDate: new Date()
		property int currentTab

		reloadableId: "dashboardState"
	}
	required property bool horizontal
	readonly property real nonAnimHeight: state === "visible" ? (content.item?.nonAnimHeight ?? 0) : 0
	required property real offsetScale
	readonly property bool shouldBeActive: root.visibilities.dashboard && Config.dashboard.enabled
	required property PersistentProperties visibilities

	anchors.left: horizontal ? undefined : parent.left
	anchors.leftMargin: horizontal ? 0 : (-implicitWidth - 5) * offsetScale
	anchors.top: horizontal ? parent.top : undefined
	anchors.topMargin: horizontal ? (-implicitHeight - 5) * offsetScale : 0
	implicitHeight: content.implicitHeight
	implicitWidth: content.implicitWidth || 854
	opacity: 1 - offsetScale
	visible: offsetScale < 1

	Loader {
		id: content

		active: root.shouldBeActive || root.visible
		anchors.bottom: parent.bottom
		anchors.horizontalCenter: parent.horizontalCenter

		sourceComponent: Content {
			dashState: root.dashState
			visibilities: root.visibilities
		}
	}
}