import QtQuick
import ZShell.Config
import qs.Services

ButtonBase {
	id: root

	property alias icon: label.text
	readonly property alias label: label

	activeColor: type === IconButton.Filled ? Colors.palette.m3primary : Colors.palette.m3secondary
	activeOnColor: type === IconButton.Filled ? Colors.palette.m3onPrimary : type === IconButton.Tonal ? Colors.palette.m3onSecondary : Colors.palette.m3primary
	implicitHeight: {
		const h = label.implicitHeight + padding * 2;
		if (h % 2 !== 0)
			return h + 1;
		return h;
	}
	implicitWidth: implicitHeight
	inactiveColor: {
		if (!isToggle && type === IconButton.Filled)
			return Colors.palette.m3primary;
		return type === IconButton.Filled ? Colors.tPalette.m3surfaceContainer : Colors.palette.m3secondaryContainer;
	}
	inactiveOnColor: {
		if (!isToggle && type === IconButton.Filled)
			return Colors.palette.m3onPrimary;
		return type === IconButton.Tonal ? Colors.palette.m3onSecondaryContainer : Colors.palette.m3onSurfaceVariant;
	}
	padding: type === IconButton.Text ? Tokens.padding.extraSmall / 2 : Tokens.padding.small

	MaterialIcon {
		id: label

		anchors.centerIn: parent
		anchors.verticalCenterOffset: 1
		color: root.onColor
		fill: !root.isToggle || root.internalChecked ? 1 : 0
		font.pointSize: root.font.pointSize

		Behavior on fill {
			Anim {
				type: Anim.DefaultEffects
			}
		}
	}
}