pragma ComponentBehavior: Bound

import QtQuick
import QtQuick.Layouts
import Quickshell.Services.SystemTray
import qs.Components
import ZShell.Config
import qs.Modules.SysTray.Widgets
import qs.Modules
import qs.Services

CustomClippingRect {
	id: root

	readonly property alias items: repeater
	readonly property alias layout: sysRow
	required property RowLayout loader
	readonly property int padding: Tokens.padding.small
	required property Wrapper popouts

	bottomRightRadius: Tokens.rounding.smallest / 2
	color: Colors.tPalette.m3surfaceContainer
	implicitHeight: Config.bar.height + Tokens.padding.smallest * 2
	implicitWidth: sysRow.implicitWidth + Tokens.padding.small * 2
	radius: Tokens.rounding.full
	topRightRadius: Tokens.rounding.smallest / 2

	RowLayout {
		id: sysRow

		anchors.centerIn: parent
		spacing: 0

		Repeater {
			id: repeater

			model: SystemTray.items

			TrayItem {
				id: trayItem

				required property int index
				required property SystemTrayItem modelData

				implicitHeight: 34
				implicitWidth: 34
				ind: index
				item: modelData
				loader: root.loader
				popouts: root.popouts
			}
		}
	}
}