import Quickshell
import Quickshell.Widgets
import QtQuick
import qs.Modules.Launcher.Services
import qs.Components
import qs.Helpers
import ZShell.Config
import qs.Modules
import qs.Services

Item {
	id: root

	required property DesktopEntry modelData
	required property PersistentProperties visibilities

	anchors.left: parent?.left
	anchors.right: parent?.right
	implicitHeight: Config.launcher.sizes.itemHeight

	StateLayer {
		radius: Tokens.rounding.small

		onClicked: {
			Apps.launch(root.modelData);
			root.visibilities.launcher = false;
		}
	}

	Item {
		anchors.fill: parent
		anchors.leftMargin: Tokens.padding.medium
		anchors.margins: Tokens.padding.small
		anchors.rightMargin: Tokens.padding.medium

		IconImage {
			id: icon

			anchors.verticalCenter: parent.verticalCenter
			implicitSize: parent.height
			source: Quickshell.iconPath(root.modelData?.icon, "image-missing")
		}

		Item {
			anchors.left: icon.right
			anchors.leftMargin: Tokens.spacing.medium
			anchors.verticalCenter: icon.verticalCenter
			implicitHeight: name.implicitHeight + comment.implicitHeight
			implicitWidth: parent.width - icon.width

			CustomText {
				id: name

				font.pointSize: Tokens.font.size.normal
				text: root.modelData?.name ?? ""
			}

			CustomText {
				id: comment

				anchors.top: name.bottom
				color: Colors.palette.m3outline
				elide: Text.ElideRight
				font.pointSize: Tokens.font.size.small
				text: (root.modelData?.comment || root.modelData?.genericName || root.modelData?.name) ?? ""
				width: root.width - icon.width - Tokens.rounding.medium - Tokens.padding.medium * 2
			}
		}

		Loader {
			id: favoriteIcon

			active: root.modelData && Strings.testRegexList(Config.launcher.favoriteApps, root.modelData.id)
			anchors.right: parent.right
			anchors.verticalCenter: parent.verticalCenter
			asynchronous: true

			sourceComponent: MaterialIcon {
				color: Colors.palette.m3primary
				fill: 1
				text: "favorite"
			}
		}
	}
}