pragma ComponentBehavior: Bound

import QtQuick
import QtQuick.Layouts
import Quickshell.Services.SystemTray
import qs.Components
import qs.Config
import qs.Modules.SysTray.Widgets
import qs.Modules

CustomClippingRect {
	id: root

	readonly property alias items: repeater
	readonly property alias layout: sysRow
	required property RowLayout loader
	readonly property int padding: Appearance.padding.small
	required property Wrapper popouts

	bottomRightRadius: Appearance.rounding.smallest / 2
	color: DynamicColors.tPalette.m3surfaceContainer
	implicitHeight: Config.bar.height + Appearance.padding.smallest * 2
	implicitWidth: sysRow.implicitWidth + Appearance.padding.small * 2
	radius: Appearance.rounding.full
	topRightRadius: Appearance.rounding.smallest / 2

	RowLayout {
		id: sysRow

		anchors.centerIn: parent
		spacing: 0

		Repeater {
			id: repeater

			model: SystemTray.items

			TrayItem {
				id: trayItem

				required property int index
				required property SystemTrayItem modelData

				implicitHeight: 34
				implicitWidth: 34
				ind: index
				item: modelData
				loader: root.loader
				popouts: root.popouts
			}
		}
	}
}