z-bar-qt/Greeter/Components/CustomTextField.qml

pragma ComponentBehavior: Bound

import QtQuick
import QtQuick.Controls
import ZShell.Config
import qs.Services

TextField {
	id: root

	background: null
	color: Colors.palette.m3onSurface
	cursorVisible: !readOnly
	font.family: Config.appearance.font.family.sans
	font.pointSize: Tokens.font.size.smaller
	placeholderTextColor: Colors.palette.m3outline
	renderType: echoMode === TextField.Password ? TextField.QtRendering : TextField.NativeRendering

	Behavior on color {
		CAnim {
		}
	}
	cursorDelegate: CustomRect {
		id: cursor

		property bool disableBlink

		color: Colors.palette.m3primary
		implicitWidth: 2
		radius: Tokens.rounding.medium

		Behavior on opacity {
			Anim {
				duration: Tokens.anim.durations.small
			}
		}

		Connections {
			function onCursorPositionChanged(): void {
				if (root.activeFocus && root.cursorVisible) {
					cursor.opacity = 1;
					cursor.disableBlink = true;
					enableBlink.restart();
				}
			}

			target: root
		}

		Timer {
			id: enableBlink

			interval: 100

			onTriggered: cursor.disableBlink = false
		}

		Timer {
			interval: 500
			repeat: true
			running: root.activeFocus && root.cursorVisible && !cursor.disableBlink
			triggeredOnStart: true

			onTriggered: parent.opacity = parent.opacity === 1 ? 0 : 1
		}

		Binding {
			cursor.opacity: 0
			when: !root.activeFocus || !root.cursorVisible
		}
	}
	Behavior on placeholderTextColor {
		CAnim {
		}
	}
}