z-bar-qt/Greeter/SessionDock.qml

pragma ComponentBehavior: Bound

import QtQuick
import QtQuick.Layouts
import ZShell.Config
import qs.Components
import qs.Services

ColumnLayout {
	id: root

	required property var greeter

	anchors.fill: parent
	anchors.margins: Tokens.padding.large
	spacing: Tokens.spacing.small

	CustomText {
		Layout.fillWidth: true
		color: Colors.palette.m3outline
		elide: Text.ElideRight
		font.family: Config.appearance.font.family.mono
		font.weight: 500
		text: root.greeter.sessions.length > 0 ? qsTr("%1 session%2").arg(root.greeter.sessions.length).arg(root.greeter.sessions.length === 1 ? "" : "s") : qsTr("Sessions")
	}

	CustomClippingRect {
		Layout.fillHeight: true
		Layout.fillWidth: true
		color: "transparent"
		radius: Tokens.rounding.small

		Loader {
			active: opacity > 0
			anchors.centerIn: parent
			opacity: root.greeter.sessions.length > 0 ? 0 : 1

			Behavior on opacity {
				Anim {
					duration: Tokens.anim.durations.extraLarge
				}
			}
			sourceComponent: ColumnLayout {
				spacing: Tokens.spacing.largeIncreased

				MaterialIcon {
					Layout.alignment: Qt.AlignHCenter
					color: Colors.palette.m3outlineVariant
					font.pointSize: Tokens.font.size.extraLarge * 2
					text: "desktop_windows"
				}

				CustomText {
					Layout.alignment: Qt.AlignHCenter
					color: Colors.palette.m3outlineVariant
					font.family: Config.appearance.font.family.mono
					font.pointSize: Tokens.font.size.large
					font.weight: 500
					text: qsTr("No Sessions Found")
				}
			}
		}

		ListView {
			id: sessions

			anchors.fill: parent
			clip: true
			currentIndex: root.greeter.sessionIndex
			highlightFollowsCurrentItem: false
			model: root.greeter.sessions
			spacing: Tokens.spacing.small

			delegate: CustomRect {
				id: session

				required property int index
				required property var modelData

				anchors.left: parent?.left
				anchors.right: parent?.right
				implicitHeight: row.implicitHeight + Tokens.padding.small * 2
				radius: Tokens.rounding.medium - Tokens.padding.small

				StateLayer {
					onClicked: {
						root.greeter.sessionIndex = index;
					}
				}

				RowLayout {
					id: row

					anchors.fill: parent
					anchors.margins: Tokens.padding.small
					spacing: Tokens.spacing.medium

					MaterialIcon {
						color: session.index === sessions.currentIndex ? Colors.palette.m3onPrimary : Colors.palette.m3onSurfaceVariant
						font.pointSize: Tokens.font.size.extraLarge
						text: modelData.kind === "x11" ? "tv" : "desktop_windows"
					}

					ColumnLayout {
						Layout.fillWidth: true
						spacing: Tokens.spacing.small / 2

						CustomText {
							Layout.fillWidth: true
							color: session.index === sessions.currentIndex ? Colors.palette.m3onPrimary : Colors.palette.m3onSurface
							elide: Text.ElideRight
							font.pointSize: Tokens.font.size.normal
							font.weight: 600
							text: modelData.name
						}

						CustomText {
							Layout.fillWidth: true
							color: session.index === sessions.currentIndex ? Colors.palette.m3onPrimaryFixedVariant : Colors.palette.m3onSurfaceVariant
							elide: Text.ElideRight
							font.family: Config.appearance.font.family.mono
							font.pointSize: Tokens.font.size.small
							text: modelData.kind
						}
					}
				}
			}
			highlight: CustomRect {
				color: Colors.palette.m3primary
				implicitHeight: sessions.currentItem?.implicitHeight ?? 0
				implicitWidth: sessions.width
				radius: Tokens.rounding.medium - Tokens.padding.small
				y: sessions.currentItem?.y ?? 0

				Behavior on y {
					Anim {
						duration: Tokens.anim.durations.small
						easing: Tokens.anim.expressiveDefaultEffects
					}
				}
			}
		}
	}
}