z-bar-qt/Modules/Settings/Common/ItemList.qml

pragma ComponentBehavior: Bound

import QtQuick
import QtQuick.Layouts
import qs.Components
import ZShell.Config
import qs.Services

ConnectedRect {
	id: root

	property alias delegate: list.delegate
	property int extraHeight
	readonly property alias list: list
	property alias model: list.model
	property string placeholderIcon
	property string placeholderText
	property bool showList

	Layout.fillWidth: true
	clip: true
	color: Colors.tPalette.m3surfaceContainer
	implicitHeight: (showList && list.count > 0 ? list.contentHeight : placeholder.implicitHeight + Tokens.padding.extraLarge * 2) + extraHeight

	Behavior on implicitHeight {
		Anim {}
	}

	Loader {
		id: placeholder

		active: opacity > 0
		anchors.centerIn: parent
		opacity: root.showList && list.count > 0 ? 0 : 1

		Behavior on opacity {
			Anim {
				type: Anim.DefaultEffects
			}
		}
		sourceComponent: ColumnLayout {
			spacing: Tokens.spacing.extraSmall

			MaterialIcon {
				Layout.alignment: Qt.AlignHCenter
				animate: true
				color: Colors.palette.m3outline
				fontStyle: Tokens.font.icon.large
				text: root.placeholderIcon
			}

			CustomText {
				Layout.alignment: Qt.AlignHCenter
				animate: true
				color: Colors.palette.m3outline
				font: Tokens.font.body.large
				text: root.placeholderText
			}
		}
	}

	ListView {
		id: list

		anchors.bottom: parent.bottom
		anchors.left: parent.left
		anchors.right: parent.right
		anchors.top: parent.top
		interactive: false
		opacity: root.showList ? 1 : 0
		spacing: 0

		add: Transition {
			Anim {
				from: 0
				property: "opacity"
				to: 1
				type: Anim.DefaultEffects
			}
		}
		displaced: Transition {
			Anim {
				property: "opacity"
				to: 1
				type: Anim.DefaultEffects
			}

			Anim {
				property: "y"
			}
		}
		move: Transition {
			Anim {
				property: "opacity"
				to: 1
				type: Anim.DefaultEffects
			}

			Anim {
				property: "y"
			}
		}
		Behavior on opacity {
			Anim {
				type: Anim.DefaultEffects
			}
		}
		remove: Transition {
			Anim {
				property: "opacity"
				to: 0
				type: Anim.DefaultEffects
			}
		}
	}
}