z-bar-qt/Greeter/WeatherInfo.qml

pragma ComponentBehavior: Bound

import QtQuick
import QtQuick.Layouts
import ZShell.Config
import qs.Components
import qs.Helpers
import qs.Services

ColumnLayout {
	id: root

	required property int rootHeight

	anchors.left: parent.left
	anchors.margins: Tokens.padding.large * 2
	anchors.right: parent.right
	spacing: Tokens.spacing.small

	Loader {
		Layout.alignment: Qt.AlignHCenter
		Layout.bottomMargin: -Tokens.padding.large
		Layout.topMargin: Tokens.padding.large * 2
		active: root.rootHeight > 610
		visible: active

		sourceComponent: CustomText {
			color: Colors.palette.m3primary
			font.pointSize: Tokens.font.size.extraLarge
			font.weight: 500
			text: qsTr("Weather")
		}
	}

	RowLayout {
		Layout.fillWidth: true
		spacing: Tokens.spacing.largeIncreased

		MaterialIcon {
			animate: true
			color: Colors.palette.m3secondary
			font.pointSize: Tokens.font.size.extraLarge * 2.5
			text: Weather.icon
		}

		ColumnLayout {
			spacing: Tokens.spacing.small

			CustomText {
				Layout.fillWidth: true
				animate: true
				color: Colors.palette.m3secondary
				elide: Text.ElideRight
				font.pointSize: Tokens.font.size.large
				font.weight: 500
				text: Weather.description
			}

			CustomText {
				Layout.fillWidth: true
				animate: true
				color: Colors.palette.m3onSurfaceVariant
				elide: Text.ElideRight
				font.pointSize: Tokens.font.size.normal
				text: qsTr("Humidity: %1%").arg(Weather.humidity)
			}
		}

		Loader {
			Layout.rightMargin: Tokens.padding.small
			active: root.width > 400
			visible: active

			sourceComponent: ColumnLayout {
				spacing: Tokens.spacing.small

				CustomText {
					Layout.fillWidth: true
					animate: true
					color: Colors.palette.m3primary
					elide: Text.ElideLeft
					font.pointSize: Tokens.font.size.extraLarge
					font.weight: 500
					horizontalAlignment: Text.AlignRight
					text: Weather.temp
				}

				CustomText {
					Layout.fillWidth: true
					animate: true
					color: Colors.palette.m3outline
					elide: Text.ElideLeft
					font.pointSize: Tokens.font.size.smaller
					horizontalAlignment: Text.AlignRight
					text: qsTr("Feels like: %1").arg(Weather.feelsLike)
				}
			}
		}
	}

	Loader {
		id: forecastLoader

		Layout.bottomMargin: Tokens.padding.large * 2
		Layout.fillWidth: true
		Layout.topMargin: Tokens.spacing.small
		active: root.rootHeight > 820
		visible: active

		sourceComponent: RowLayout {
			spacing: Tokens.spacing.largeIncreased

			Repeater {
				model: {
					const forecast = Weather.hourlyForecast;
					const count = root.width < 320 ? 3 : root.width < 400 ? 4 : 5;
					if (!forecast)
						return Array.from({
							length: count
						}, () => null);

					return forecast.slice(0, count);
				}

				ColumnLayout {
					id: forecastHour

					required property var modelData

					Layout.fillWidth: true
					spacing: Tokens.spacing.small

					CustomText {
						Layout.fillWidth: true
						color: Colors.palette.m3outline
						font.pointSize: Tokens.font.size.larger
						horizontalAlignment: Text.AlignHCenter
						text: {
							const hour = forecastHour.modelData?.hour ?? 0;
							return hour > 12 ? `${(hour - 12).toString().padStart(2, "0")} PM` : `${hour.toString().padStart(2, "0")} AM`;
						}
					}

					MaterialIcon {
						Layout.alignment: Qt.AlignHCenter
						font.pointSize: Tokens.font.size.extraLarge * 1.5
						font.weight: 500
						text: forecastHour.modelData?.icon ?? "cloud_alert"
					}

					CustomText {
						Layout.alignment: Qt.AlignHCenter
						color: Colors.palette.m3secondary
						font.pointSize: Tokens.font.size.larger
						text: Config.services.useFahrenheit ? `${forecastHour.modelData?.tempF ?? 0}°F` : `${forecastHour.modelData?.tempC ?? 0}°C`
					}
				}
			}
		}
	}

	Timer {
		interval: 900000 // 15 minutes
		repeat: true
		running: true
		triggeredOnStart: true

		onTriggered: Weather.reload()
	}
}