pkgname='zshell'
pkgver=0.1.0
pkgrel=1
pkgdesc='The cli for zshell'
arch=('any')
url='https://git.zach-dev.cc/zach/z-bar-qt'
license=('GPL-3.0-only')
depends=('python' 'python-pillow' 'python-materialyoucolor' 'libnotify' 'swappy' 'dart-sass'
	'app2unit' 'wl-clipboard' 'dconf' 'cliphist' 'python-typer')
makedepends=('python-build' 'python-installer' 'python-hatch' 'python-hatch-vcs' 'cargo' 'rust' 'cmake' 'ninja')
source=("$pkgname::git+$url.git#branch=main")
sha256sums=('SKIP')

build() {
	cd "${srcdir}/${pkgname}/cli"
	python -m build --wheel --no-isolation

	cd "${srcdir}/${pkgname}/zshell-img-tools"
	cargo build --release

	cd "${srcdir}/${pkgname}"
	cmake -B build -G Ninja -DCMAKE_BUILD_TYPE=RelWithDebInfo -DCMAKE_INSTALL_PREFIX=/
	cmake --build build
}

package() {
	cd "${srcdir}/${pkgname}/cli"
	python -m installer --destdir="$pkgdir" dist/*.whl

	cd "${srcdir}/${pkgname}"
	DESTDIR="$pkgdir" cmake --install build

	install -Dm755 \
		"${srcdir}/${pkgname}/zshell-img-tools/target/release/zshell-img-tools" \
		"${pkgdir}/usr/bin/zshell-img-tools"
}
