144 lines
4.8 KiB
QML
144 lines
4.8 KiB
QML
pragma Singleton
|
|
|
|
import qs.components.misc
|
|
import qs.config
|
|
import Caelestia
|
|
import Caelestia.Internal
|
|
import Quickshell
|
|
import Quickshell.Hyprland
|
|
import Quickshell.Io
|
|
import QtQuick
|
|
|
|
Singleton {
|
|
id: root
|
|
|
|
readonly property var toplevels: Hyprland.toplevels
|
|
readonly property var workspaces: Hyprland.workspaces
|
|
readonly property var monitors: Hyprland.monitors
|
|
|
|
readonly property HyprlandToplevel activeToplevel: Hyprland.activeToplevel?.wayland?.activated ? Hyprland.activeToplevel : null
|
|
readonly property HyprlandWorkspace focusedWorkspace: Hyprland.focusedWorkspace
|
|
readonly property HyprlandMonitor focusedMonitor: Hyprland.focusedMonitor
|
|
readonly property int activeWsId: focusedWorkspace?.id ?? 1
|
|
|
|
readonly property HyprKeyboard keyboard: extras.devices.keyboards.find(kb => kb.main) ?? null
|
|
readonly property bool capsLock: keyboard?.capsLock ?? false
|
|
readonly property bool numLock: keyboard?.numLock ?? false
|
|
readonly property string defaultKbLayout: keyboard?.layout.split(",")[0] ?? "??"
|
|
readonly property string kbLayoutFull: keyboard?.activeKeymap ?? "Unknown"
|
|
readonly property string kbLayout: kbMap.get(kbLayoutFull) ?? "??"
|
|
readonly property var kbMap: new Map()
|
|
|
|
readonly property alias extras: extras
|
|
readonly property alias options: extras.options
|
|
readonly property alias devices: extras.devices
|
|
|
|
property bool hadKeyboard
|
|
|
|
signal configReloaded
|
|
|
|
function dispatch(request: string): void {
|
|
Hyprland.dispatch(request);
|
|
}
|
|
|
|
function monitorFor(screen: ShellScreen): HyprlandMonitor {
|
|
return Hyprland.monitorFor(screen);
|
|
}
|
|
|
|
function reloadDynamicConfs(): void {
|
|
extras.batchMessage(["keyword bindlni ,Caps_Lock,global,caelestia:refreshDevices", "keyword bindlni ,Num_Lock,global,caelestia:refreshDevices"]);
|
|
}
|
|
|
|
Component.onCompleted: reloadDynamicConfs()
|
|
|
|
onCapsLockChanged: {
|
|
if (!Config.utilities.toasts.capsLockChanged)
|
|
return;
|
|
|
|
if (capsLock)
|
|
Toaster.toast(qsTr("Caps lock enabled"), qsTr("Caps lock is currently enabled"), "keyboard_capslock_badge");
|
|
else
|
|
Toaster.toast(qsTr("Caps lock disabled"), qsTr("Caps lock is currently disabled"), "keyboard_capslock");
|
|
}
|
|
|
|
onNumLockChanged: {
|
|
if (!Config.utilities.toasts.numLockChanged)
|
|
return;
|
|
|
|
if (numLock)
|
|
Toaster.toast(qsTr("Num lock enabled"), qsTr("Num lock is currently enabled"), "looks_one");
|
|
else
|
|
Toaster.toast(qsTr("Num lock disabled"), qsTr("Num lock is currently disabled"), "timer_1");
|
|
}
|
|
|
|
onKbLayoutFullChanged: {
|
|
if (hadKeyboard && Config.utilities.toasts.kbLayoutChanged)
|
|
Toaster.toast(qsTr("Keyboard layout changed"), qsTr("Layout changed to: %1").arg(kbLayoutFull), "keyboard");
|
|
|
|
hadKeyboard = !!keyboard;
|
|
}
|
|
|
|
Connections {
|
|
target: Hyprland
|
|
|
|
function onRawEvent(event: HyprlandEvent): void {
|
|
const n = event.name;
|
|
if (n.endsWith("v2"))
|
|
return;
|
|
|
|
if (n === "configreloaded") {
|
|
root.configReloaded();
|
|
root.reloadDynamicConfs();
|
|
} else if (["workspace", "moveworkspace", "activespecial", "focusedmon"].includes(n)) {
|
|
Hyprland.refreshWorkspaces();
|
|
Hyprland.refreshMonitors();
|
|
} else if (["openwindow", "closewindow", "movewindow"].includes(n)) {
|
|
Hyprland.refreshToplevels();
|
|
Hyprland.refreshWorkspaces();
|
|
} else if (n.includes("mon")) {
|
|
Hyprland.refreshMonitors();
|
|
} else if (n.includes("workspace")) {
|
|
Hyprland.refreshWorkspaces();
|
|
} else if (n.includes("window") || n.includes("group") || ["pin", "fullscreen", "changefloatingmode", "minimize"].includes(n)) {
|
|
Hyprland.refreshToplevels();
|
|
}
|
|
}
|
|
}
|
|
|
|
FileView {
|
|
id: kbLayoutFile
|
|
|
|
path: Quickshell.env("CAELESTIA_XKB_RULES_PATH") || "/usr/share/X11/xkb/rules/base.lst"
|
|
onLoaded: {
|
|
const lines = text().match(/! layout\n([\s\S]*?)\n\n/)[1].split("\n");
|
|
for (const line of lines) {
|
|
if (!line.trim() || line.trim().startsWith("!"))
|
|
continue;
|
|
|
|
const match = line.match(/^\s*([a-z]{2,})\s+([a-zA-Z() ]+)$/);
|
|
if (match)
|
|
root.kbMap.set(match[2], match[1]);
|
|
}
|
|
}
|
|
}
|
|
|
|
IpcHandler {
|
|
target: "hypr"
|
|
|
|
function refreshDevices(): void {
|
|
extras.refreshDevices();
|
|
}
|
|
}
|
|
|
|
CustomShortcut {
|
|
name: "refreshDevices"
|
|
description: "Reload devices"
|
|
onPressed: extras.refreshDevices()
|
|
onReleased: extras.refreshDevices()
|
|
}
|
|
|
|
HyprExtras {
|
|
id: extras
|
|
}
|
|
}
|