z-bar-qt/Modules/Launcher/Items/VariantItem.qml

import QtQuick
import qs.Components
import qs.Modules.Launcher.Services
import ZShell.Config
import qs.Services

Item {
	id: root

	required property var list
	required property SchemeVariants.Variant modelData

	anchors.left: parent?.left
	anchors.right: parent?.right
	implicitHeight: Config.launcher.sizes.itemHeight

	StateLayer {
		radius: Tokens.rounding.small

		onClicked: {
			root.modelData?.onClicked(root.list);
		}
	}

	Item {
		anchors.fill: parent
		anchors.leftMargin: Tokens.padding.small
		anchors.margins: Tokens.padding.small
		anchors.rightMargin: Tokens.padding.small

		MaterialIcon {
			id: icon

			anchors.verticalCenter: parent.verticalCenter
			font.pointSize: Tokens.font.size.extraLarge
			text: root.modelData?.icon ?? ""
		}

		Column {
			anchors.left: icon.right
			anchors.leftMargin: Tokens.spacing.large
			anchors.verticalCenter: icon.verticalCenter
			spacing: 0
			width: parent.width - icon.width - anchors.leftMargin - (current.active ? current.width + Tokens.spacing.medium : 0)

			CustomText {
				font.pointSize: Tokens.font.size.normal
				text: root.modelData?.name ?? ""
			}

			CustomText {
				anchors.left: parent.left
				anchors.right: parent.right
				color: Colors.palette.m3outline
				elide: Text.ElideRight
				font.pointSize: Tokens.font.size.small
				text: root.modelData?.description ?? ""
			}
		}

		Loader {
			id: current

			active: root.modelData?.variant === Config.colors.schemeType
			anchors.right: parent.right
			anchors.verticalCenter: parent.verticalCenter

			sourceComponent: MaterialIcon {
				color: Colors.palette.m3onSurfaceVariant
				font.pointSize: Tokens.font.size.large
				text: "check"
			}
		}
	}
}