z-bar-qt/Plugins/ZShell/Internal/shaders/wallpaper_trans_fade.frag

// Fade (crossfade) transition, from gl-transitions.com.
//
// Ported to ZShell's own GLSL ABI (same contract as wallpaper_trans_bowtie.frag):
// version/precision header is prepended by WallpaperService::shaderSource, the
// fullscreen triangle comes from shaders/wallpaper.vert, and getFromColor /
// getToColor sample with the crop + per-layer flip convention.
//
//   uniforms: samplers `from`/`to`, vec2 size, vec4 fromCrop, vec4 toCrop,
//             float fromFlip, float toFlip, float progress (0..1).

uniform sampler2D from;
uniform sampler2D to;
uniform vec2 size;
uniform vec4 fromCrop;
uniform vec4 toCrop;
uniform float fromFlip;
uniform float toFlip;
uniform float progress;

out vec4 outColor;

vec4 getFromColor(vec2 uv) {
	vec2 s = vec2(uv.x, fromFlip > 0.5 ? 1.0 - uv.y : uv.y);
	return texture(from, fromCrop.xy + s * fromCrop.zw);
}

vec4 getToColor(vec2 uv) {
	vec2 s = vec2(uv.x, toFlip > 0.5 ? 1.0 - uv.y : uv.y);
	return texture(to, toCrop.xy + s * toCrop.zw);
}

vec4 transition(vec2 uv) {
	return mix(getFromColor(uv), getToColor(uv), progress);
}

void main() {
	vec2 uv = gl_FragCoord.xy / size;
	outColor = transition(uv);
}